Question

我希望将Windows命令行程序（例如powercfg -l）的输出写入使用Perl创建的文件中，然后在for循环中逐行读取文件并将其分配给字符串

Answer 1

你已经有了一些好的答案。此外，如果您只想处理命令的输出而不需要将该输出直接发送到文件，则可以在命令和Perl脚本之间建立管道。

use strict;
use warnings;

open(my $fh, '-|', 'powercfg -l') or die $!;
while (my $line = <$fh>) {
    # Do stuff with each $line.
}

Answer 2

system 'powercfg', '-l';

是推荐的方式。如果您不介意产生子壳，

system "powercfg -l";

也会奏效。如果你想把结果写成一个字符串：

my $str = `powercfg -l`;

Answer 3

my $output = qx(powercfg -l);

## You've got your output loaded into the $output variable. 
## Still want to write it to a file?
open my $OUTPUT, '>', 'output.txt' or die "Couldn't open output.txt: $!\n";
print $OUTPUT $output;
close $OUTPUT

## Now you can loop through each line and
##   parse the $line variable to extract the info you are looking for.
foreach my $line (split /[\r\n]+/, $output) {
  ## Regular expression magic to grab what you want
}

Answer 4

无需先将命令的输出保存在文件中：

my $output = `powercfg -l`;

请参阅Quote-Like Operators中的qx//。

但是，如果您确实希望先将输出保存在文件中，则可以使用：

my $output_file = 'output.txt';

system "powercfg -l > $output_file";

open my $fh, '<', $output_file 
    or die "Cannot open '$output_file' for reading: $!";

while ( my $line = <$fh> ) {
    # process lines
}

close $fh;

请参阅perldoc -f system。

Answer 5

由于OP正在运行powercfg，他/她可能正在捕获外部脚本的输出，因此他/她可能不会发现这个答案非常有用。这篇文章主要是为那些通过搜索找到答案的人写的。

这个答案描述了几种启动将在后台运行的命令的方法，而不会阻止进一步执行脚本。

看看perlport entry for system。您可以使用system( 1, 'command line to run');生成子进程并继续运行脚本。

这非常方便，但有一个严重的警告是不记录。如果在一次执行脚本时启动更多64个进程，则尝试运行其他程序将失败。

我已经验证了Windows XP和ActivePerl 5.6和5.8的情况。我没有使用Vista或Stawberry Perl或任何版本的5.10进行测试。

这是一个可以用来测试你的perl这个问题的衬里：

C:\>perl -e "for (1..100) { print qq'\n $_\n-------\n'; system( 1, 'echo worked' ), sleep 1 }

如果您的系统存在问题，并且您将启动许多程序，则可以使用Win32::Process模块来管理应用程序启动。

以下是使用Win32::Process：

的示例

use strict;
use warnings;

use Win32::Process;

if( my $pid = start_foo_bar_baz() ) {
    print "Started with $pid";
}
:w

sub start_foo_bar_baz {

    my $process_object;  # Call to Create will populate this value.
    my $command = 'C:/foo/bar/baz.exe';  # FULL PATH to executable.
    my $command_line = join ' ',
           'baz',   # Name of executable as would appear on command line
           'arg1',  # other args
           'arg2';

    # iflags - controls whether process will inherit parent handles, console, etc.
    my $inherit_flags = DETACHED_PROCESS;  

    # cflags - Process creation flags.
    my $creation_flags = NORMAL_PRIORITY_CLASS;

    # Path of process working directory
    my $working_directory = 'C:/Foo/Bar';

    my $ok = Win32::Process::Create(
       $process_object,
       $command,
       $command_line,
       $inherit_flags,
       $creation_flags, 
       $working_directory,
    );

    my $pid;
    if ( $ok ) {
        $pid = $wpc->GetProcessID;
    }
    else {
        warn "Unable to create process: "
             . Win32::FormatMessage( Win32::GetLastError() ) 
        ;
        return;
    }

    return $pid;
}

Answer 6

扩展思南的优秀答案并更明确地回答你的问题：

注意：反引号``告诉Perl执行命令并检索其输出：

#!/usr/bin/perl -w
use strict;


my @output = `powercfg -l`;
chomp(@output); # removes newlines

my $linecounter = 0;    
my $combined_line;

foreach my $line(@output){
    print $linecounter++.")";
    print $line."\n"; #prints line by line

    $combined_line .= $line; # build a single string with all lines
    # The line above is the same as writing:
    # $combined_line = $combined_line.$line;
}

print "\n";
print "This is all on one line:\n";
print ">".$combined_line."<";

您的输出（在我的系统上）将是：

0)
1)Existing Power Schemes (* Active)
2)-----------------------------------
3)Power Scheme GUID: 381b4222-f694-41f0-9685-ff5bb260df2e  (Balanced) *
4)Power Scheme GUID: 8c5e7fda-e8bf-4a96-9a85-a6e23a8c635c  (High performance)
5)Power Scheme GUID: a1841308-3541-4fab-bc81-f71556f20b4a  (Power saver)

This is all on one line:
>Existing Power Schemes (* Active)-----------------------------------Power Scheme GUID: 381b4222-f694-41f0-9685-ff5bb260df2e  (Balanced) *Power Scheme GUID: 8c5e7fda-e8bf-4a96-9a85-a6e23a8c635c  (High performance)Power Scheme GUID: a1841308-3541-4fab-bc81-f71556f20b4a  (Power saver)<

Perl让它变得简单！

Answer 7

尝试使用＆gt;运算符将输出转发到文件，如：

powercfg -l > output.txt

然后打开output.txt并处理它。

如何在Perl中获取外部命令的输出？

7 个答案: