Question

我的问题与other question I have asked about loading image from the URL有关。以下代码有效。但是，如果我试图获取图像（它假设在那里）我遇到了问题但是显然被删除了。应用程序不知道并返回错误。有没有办法通过捕获传入的错误来防止它。我将不胜感激任何建议。它发生在他的路线上：

 IdHTTP1.get('http://www.google.com/intl/en_ALL/images/logo.gif',MS);

谢谢，克里斯

uses
  GIFImg;

 procedure TForm1.btn1Click(Sender: TObject);
 var
   MS : TMemoryStream;
   GIf: TGIFImage;
 begin
     MS := TMemoryStream.Create;
    GIf := TGIFImage.Create;
   try
    IdHTTP1.get('http://www.google.com/intl/en_ALL/images/logo.gif',MS);
    Ms.Seek(0,soFromBeginning);       
   Gif.LoadFromStream(MS);
   img1.Picture.Assign(GIF);

  finally
   FreeAndNil(GIF);
   FreeAndNil(MS);
  end;
end;

Answer 1

如何捕获异常？捕获任何其他异常的方式相同。使用try - except阻止。

procedure TForm1.btn1Click(Sender: TObject);
var
  MS : TMemoryStream;
  Gif: TGIFImage;
begin
  MS := TMemoryStream.Create;
  try
    Gif := TGIFImage.Create;
    try
      try
        IdHTTP1.Get('http://www.google.com/intl/en_ALL/images/logo.gif', MS);
      except
        on e: EIdHTTPProtocolException do begin
          if e.ErrorCode = 404 then begin
            // not found
            exit;
          end else begin
            // some other reason for failure
            raise;
          end;
        end;
      end;
      MS.Position := 0;
      Gif.LoadFromStream(MS);
      img1.Picture.Assign(Gif);
    finally
      Gif.Free;
    end;
  finally
    MS.Free;
  end;
end;

当Indy得到不可接受的响应时，它会引发类型EIdHTTPProtocolException的异常。它不会针对每个可能的失败原因引发不同的异常类，因此请检查ErrorCode属性以获取数字响应。有关各种响应代码的含义，请参阅HTTP spec。

看起来Indy可以配置为通过AIgnoreReplies TIdCustomHTTP.DoRequest方法的MS方法忽略某些响应代码，但我已经追溯到我今天愿意去的那个参数，因此，如果您想了解更多相关信息，可以提出新问题，或者有人可以编辑此答案，用更完整的内容替换此段落。

在上面的例子中，我检查了404（未找到）并退出。如果Get引发异常，请确保不使用EIdHTTPProtocolException，因为它会包含不确定的内容，可能不是有效的GIF图像。对于任何其他服务器响应，我重新引发异常，以便调用者可以处理它。你可能想要改变它。任何不是{{1}}后代的异常都会自动重新引发。不要捕获您不知道如何解决的错误的异常。

Answer 2

每次尝试都有 catch
它是你应该对待你的例外的地方可能会创建一个空白图像，上面有一些文字图片不可用

从URL加载图像 - 如果图像不存在，如何捕获异常

2 个答案: