Question

好的，所以我最近一直试图在AS3中正确地绕过OOP。现在我有一个非常简单的场景，我有一个类，Paddle，它绘制一个矩形。在我的文档类中，我创建了Paddle类的两个实例，paddle1和paddle2。

我还为我的Paddle类创建了一个属性，我想改变它绘制的矩形的颜色。我希望能够从主类调整此属性。我知道我可以通过在实例化类时传入属性来实现这一点，但似乎属性是更好的方法，现在我想知道这是否是正确的思考方式。

主要课程：

    package
{
    import flash.display.Sprite;
    import flash.events.Event;

    public class Engine extends Sprite 
    {
        private var paddle1:Paddle = new Paddle();
        private var paddle2:Paddle = new Paddle();

        public function Engine() 
        {
            paddle1.x = 30;
            paddle1.color = 0xFF00FF;
            stage.addChild(paddle1);

            paddle2.x = stage.stageWidth - 45;
            paddle2.color = 0xFF0000;
            stage.addChild(paddle2);
        }

    }

}

桨类：

package
{
    import flash.display.MovieClip;
    import flash.display.Shape;
    import flash.display.Graphics;
    import flash.events.Event;

    public class Paddle extends MovieClip
    {
        public var color:uint = 0xFFFFFF;

        public function Paddle() 
        {
            var child:Shape = new Shape();
            child.graphics.beginFill(color);
            child.graphics.drawRect(0, 260, 15, 80);
            child.graphics.endFill();
            addChild(child);
        }

    }

}

如果以这种方式改变属性并不是最好的做事方式，那么当然可以这样说。否则，我做错了什么不起作用？看起来它与订单有关（当主类更改颜色属性时，它已经创建了矩形并且更改它已经太晚了？）

谢谢：D

编辑：意识到执行此代码时可能会有所帮助。基本上从Engine类更改颜色属性不会改变矩形的颜色，它们都只保持白色（FFFFFF）

Answer 1

您遇到的问题是，当您这样做时：

new Paddle();

运行构造函数代码。这意味着Rectangle已经使用在类顶部定义的颜色绘制。然后你就改变了颜色属性，正如你所看到的那样没有效果。

我建议您为draw()制作一个Paddle函数。它可以接受一种颜色并用于绘制矩形。它可能看起来像这样：

public class Paddle extends MovieClip
{

    private var _child:Shape;


    public function Paddle() 
    {
        _child = new Shape();
        addChild(_child);
    }


    public function draw(color:uint):void
    {
        _child.graphics.clear();
        _child.graphics.beginFill(color);
        _child.graphics.drawRect(0, 260, 15, 80);
        _child.graphics.endFill();
    }

}

这种方式提供了一个优点，即您可以修改draw()的参数以接受Rectangle的尺寸或其他会影响视觉效果的元素。如果您决定要这样做，这将比向类本身添加更多属性更清晰，更快。

然后你就可以这样做了：

var paddle1:Paddle = new Paddle();
var paddle2:Paddle = new Paddle();

paddle1.draw(0xFF00FF);
paddle2.draw(0xFF0000);

Answer 2

你可能会做的是允许构造函数另外指定一个颜色来创建颜色的setter，让两个调用随后绘制paddle（顺便说一句，也可以是一个简单的flash.display.Shape）：

<强> Paddle.as：

package
{
    //Imports
    import flash.display.Sprite;

    //Class
    public class Paddle extends Sprite
    {
        //Constants
        private static const DEFAULT_COLOR:uint = 0xFF0000;

        //Properties
        private var mColor:uint;

        //Constructor
        public function Paddle(color:uint = DEFAULT_COLOR) 
        {
            mColor = color;

            draw();
        }

        //Draw
        private function draw():void
        {
            graphics.clear();
            graphics.beginFill(mColor);
            graphics.drawRect(0, 0, 15, 80);
            graphics.endFill();
        }

        //Set Color
        public function set color(value:uint):void
        {
            mColor = value;

            draw();
        }

        //Get Color
        public function get color():uint
        {
            return mColor;
        }
    }
}

所以现在您可以根据需要创建和定位尽可能多的Paddle实例，每个实例都有自己的颜色设置器：

红色实例：

var paddleRed:Paddle = new Paddle();
paddleRed.y = 10;
addChild(paddleRed);

绿色实例：

var paddleGreen:Paddle = new Paddle(0x00FF00);
paddleGreen.y = 126;
addChild(paddleGreen);

蓝色实例：

var paddleBlue:Paddle = new Paddle();
paddleBlue.color = 0x00FF00;
paddleBlue.y = 260;
addChild(paddleBlue);

Answer 3

为什么不两个都做？：d

public class Paddle extends MovieClip
{
    private var color:uint;
    private var rec:Shape;

    public function Paddle(newColor:uint = 0xFFFFFF) // default color
    {
        color = newColor;
        rec = new Shape();
        drawShape();
        addChild(rec);
    }

    public function drawShape()
    {
        child.graphics.clear();
        child.graphics.beginFill(color);
        child.graphics.drawRect(0, 260, 15, 80);
        child.graphics.endFill();
    }

    public function setColor(newColor:uint)
    { 
        color = newColor;
        drawShape();
    }
}

在AS3中更改类属性

3 个答案: