Question

我正在尝试将xml转换为新结构，然后在转换中处理新结构。我的问题是让新结构可用作节点集。我在webapp的lib中使用Tomcat 6和saxon9he。为了测试新结构的可用性，我创建了以下xsl。

<?xml version="1.0" encoding="UTF-8"?>

<xsl:stylesheet version="2.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:output method="xml" omit-xml-declaration="no" indent="yes" encoding="UTF-8"/>

<xsl:include href="nodeTest.xsl"/>
<xsl:variable name="theDoc"> 
  <doc>
    <source>from</source>
    <source>here</source>
    <target>to</target>
    <target>there</target>
  </doc>
</xsl:variable>

<xsl:template match="/">
  <xsl:variable name="result1">
    <xsl:call-template name="createLinks">
    <xsl:with-param name="doc" select="$theDoc/doc/*"/>
    </xsl:call-template>
  </xsl:variable>
input:
<xsl:value-of select="$theDoc/doc/*"/>
output:
<xsl:value-of select="$result1"/>
</xsl:template>

</xsl:stylesheet>

我希望变量theDoc包含有效的节点集，并且createLinks模板会将其作为节点集处理。这是creatlelInks模板;

<?xml version="1.0" encoding="UTF-8"?>

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" > 

<xsl:template match="node()" mode="makeLink"> 
  <xsl:param name="theSource" select="'source'"/>
  <xsl:param name="theTarget" select="'target'"/>
  <xsl:param name="theUsage" select="'usage'"/>
  <xsl:element name="link" >
  <xsl:element name="usage" ><xsl:value-of select="$theUsage"/></xsl:element>
  <xsl:element name="source" ><xsl:value-of select="$theSource"/></xsl:element>
  <xsl:element name="target" ><xsl:value-of select="$theTarget"/></xsl:element>
  </xsl:element>    
</xsl:template>

<xsl:template name="createLinks">
<xsl:param name="doc" select="*"/>
the input doc:
<xsl:value-of select="$doc"/>
<xsl:copy>
  <xsl:element name="Links">
        <xsl:apply-templates mode="makeLink" select=".">
      <xsl:with-param name="theUsage" select="'link from source to target'"/>
      <xsl:with-param name="theSource" select="$doc/source/*"/>
      <xsl:with-param name="theTarget" select="$doc/target/*"/>
        </xsl:apply-templates>
  </xsl:element>
   </xsl:copy>
</xsl:template>

</xsl:stylesheet>

执行时，结果如下所示;

<?xml version="1.0" encoding="UTF-8"?>
input:
from here to there
output:

the input doc:
fromheretotherelink from source to target

很明显，Doc不是节点集。我的理解是xslt 2.0标准将theDoc作为节点集，而不是结果树片段。如何更改这些简单的xsls以将theDoc的内容作为节点集处理？

Answer 1

我不清楚你是如何得出结论的：

“很明显，theDoc不是一个节点集。我的理解是xslt 2.0标准将theDoc作为节点集，而不是结果树片段。如何更改这些简单的xsls来处理内容theDoc作为节点集？“

这里的第一个问题是您使用的是XSLT 1.0数据模型术语。在2.0中，没有节点集，只有序列，并且没有结果树片段。

$ theDoc的值是文档节点。该文档节点有一个名为doc的子元素，后者又有四个子元素，分别是source，source，result和result。

执行此操作时：

<xsl:value-of select="$doc"/>

它输出此文档节点的字符串值，它是后代文本节点的串联，即fromheretothere。

执行此操作时：

<xsl:value-of select="$result1"/>

输出$ result1的字符串值，它本身就是一个文档节点;这个文档节点有一个名为link的子节点，它有三个子节点，叫做usage，source和target;用法元素具有文本内容“从源到目标的链接”，源元素和目标元素都是空的。它们为空的原因是表达式$doc/source/*和$doc/target/*没有选择任何内容;他们没有选择任何东西，因为$ doc有一个叫doc的孩子;源元素和目标元素是它们的孙子。

Answer 2

XSLT中有一些问题阻止它按预期工作。第一个是使用 xsl：value-of 来显示变量的值。例如

<xsl:value-of select="$doc"/>

这将仅显示节点集的文本值。你应该在这里使用 xsl：copy-of 来返回节点的副本。

<xsl:copy-of select="$doc" />

尝试用 xsl：copy-of 替换所有出现的 xsl：value-of ，看看你是如何上场的。

其次，当您调用'makelink'模板

时，您的参数会出现问题

<xsl:with-param name="theSource" select="$doc/source/*"/>
<xsl:with-param name="theTarget" select="$doc/target/*"/>

*将匹配源和目标元素的子元素，但它们没有子元素，只有子文本节点（元素是节点，但不是所有节点）是元素！）。你可能想要这样做....

<xsl:with-param name="theSource" select="$doc/source"/>
<xsl:with-param name="theTarget" select="$doc/target"/>

事实上，由于您调用模板的方式，即使这样也行不通。

<xsl:call-template name="createLinks">
    <xsl:with-param name="doc" select="$theDoc/doc/*"/>
</xsl:call-template>

以这种方式调用意味着来源和目标是顶级元素。你可能想要这样做......

 <xsl:call-template name="createLinks">
     <xsl:with-param name="doc" select="$theDoc/doc"/>
 </xsl:call-template>

xslt 2.0变量元素节点集处理

2 个答案: