Question

我有2个文件，每个文件有50行..

FILE1 FILE2

现在，我需要在一个while或for循环中逐行读取两个文件行，我应该将相应的行推送到2个输出数组。我尝试过这样的事情。但它没有成功。请帮助

#!/usr/bin/perl

   my @B =();
   my @C =();
   my @D =();
   my $lines = 0;
   my $i = 0;
   my $sizeL = 0;
   my $sizeR = 0;
  my $gf = 0; 
  $inputFile = $ARGV[0];
  $outputFile = $ARGV[1];
  open(IN1FILE,"<$inputFile") or die "cant open output file ";
  open(IN2FILE,"<$outputFile") or die "cant open output file";

  while((@B=<IN1FILE>)&&(@C= <IN2FILE>))
  {
  my $line1 = <IN1FILE>;
  my $line2 = <IN2FILE>;
  print $line2;
  }

这里数组2没有得到构建..但我得到数组1的值。

Answer 1

在循环条件下，您将整个文件读入其数组中。然后将列表赋值用作布尔值。这只能工作一次，因为在评估条件后将读取文件。此外，循环内的readlines将返回undef。

以下代码应该有效：

my (@lines_1, @lines_2);
# read until one file hits EOF
while (!eof $INFILE_1 and !eof $INFILE_2) {
  my $line1 = <$INFILE_1>;
  my $line2 = <$INFILE_2>;
  say "from the 1st file: $line1";
  say "from the 2nd file: $line2";
  push @lines_1, $line1;
  push @lines_2, $line2;
}

你也可以这样做：

my (@lines_1, @lines_2);
# read while both files return strings
while (defined(my $line1 = <$INFILE_1>) and defined(my $line2 = <$INFILE_2>)) {
  say "from the 1st file: $line1";
  say "from the 2nd file: $line2";
  push @lines_1, $line1;
  push @lines_2, $line2;
}

或者：

# read once into arrays
my @lines_1 = <$INFILE_1>;
my @lines_2 = <$INFILE_2>;
my $min_size = $#lines_1 < $#lines_2 ? $#lines_1 : $#lines_2; # $#foo is last index of @foo
# then interate over data
for my $i ( 0 .. $min_size) {
  my ($line1, $line2) = ($lines_1[$i], $lines_2[$i]);
  say "from the 1st file: $line1";
  say "from the 2nd file: $line2";
}

当然，我假设您执行了use strict; use warnings;和use feature 'say'，并使用了open的3-arg形式的词法文件句柄：

my ($file_1, $file_2) = @ARGV;
open my $INFILE_1, '<', $file_1 or die "Can't open $file_1: $!"; # also, provide the actual error!
open my $INFILE_2, '<', $file_2 or die "Can't open $file_2: $!";

我还强烈建议您使用描述性变量名而不是单个字母，并在最可能的范围内声明变量 - 在开头声明变量几乎与使用坏的坏全局变量相同。

使用一个循环perl读取多个文件

1 个答案: