Question

我在ActionScript中编写了一些基本函数，以便使用RTMFP：

import flash.events.NetStatusEvent;
import flash.net.NetConnection;
import flash.net.NetStream;
import flash.ui.Keyboard;

private var serverAddress:String = "rtmfp://cc.rtmfp.net/";
private var serverKey:String = "xxxxx";
private var netConnection:NetConnection;
private var outgoingStream:NetStream;
private var incomingStream:NetStream;

private function initConnection():void {
    netConnection = new NetConnection();
    netConnection.addEventListener(NetStatusEvent.NET_STATUS, netConnectionHandler);
    netConnection.connect(serverAddress + serverKey);
}

private function netConnectionHandler(event:NetStatusEvent):void {
    receivedMessages.text += "NC Status: " + event.info.code + "\n";

    //Some status handling will be here, for now, just print the result out.
    switch (event.info.code) {
        case 'NetConnection.Connect.Success':
            receivedMessages.text += "My ID: " + netConnection.nearID + "\n";
            break;
    }
}

private function sendInit():void {
    outgoingStream = new NetStream(netConnection, NetStream.DIRECT_CONNECTIONS);
    outgoingStream.addEventListener(NetStatusEvent.NET_STATUS, outgoingStreamHandler);
    outgoingStream.publish("media");

    var sendStreamObject:Object = new Object();
    sendStreamObject.onPeerConnect = function(sendStr:NetStream):Boolean {
        receivedMessages.text += "Peer Connected ID: " + sendStr.farID + "\n";
        return true;
    }

    outgoingStream.client = sendStreamObject;
}

private function receiveInit():void {
    receivedMessages.text += "Initializing Receiving Stream: " + incomingID.text + "\n";

    incomingStream = new NetStream(netConnection, incomingID.text);
    incomingStream.addEventListener(NetStatusEvent.NET_STATUS, incomingStreamHandler);
    incomingStream.play("media");
    incomingStream.client = this;
}

public function receiveMessage(message:String):void {
    receivedMessages.text += "Received Message: " + message + "\n";
}

private function outgoingStreamHandler(event:NetStatusEvent):void {
    receivedMessages.text += "Outgoing Stream: " + event.info.code + "\n";
}

private function incomingStreamHandler(event:NetStatusEvent):void {
    receivedMessages.text += "Incoming Stream: " + event.info.code + "\n";
}

private function sendMessage():void {   
    outgoingStream.send("receiveMessage", toSendText.text);
}

private function disconnectNetConnection():void {
    netConnection.close();
    netConnection.removeEventListener(NetStatusEvent.NET_STATUS, netConnectionHandler);
    netConnection = null;
}

private function disconnectOutgoing():void {
    outgoingStream.close();
    outgoingStream.removeEventListener(NetStatusEvent.NET_STATUS, outgoingStreamHandler);
    outgoingStream = null;
}

private function disconnectIncoming():void {
    incomingStream.close();
    incomingStream.removeEventListener(NetStatusEvent.NET_STATUS, incomingStreamHandler);
    incomingStream = null;
}

initConnection初始化NC，sendInit初始化发送 stream，receiveInit基于远端对等体初始化传入流我将其复制粘贴到incomingID.text
我将每个结果打印到receivedMessages.text
我没有防火墙，也没有NAT。
Adobe示例应用程序（http://labs.adobe.com/technologies/cirrus/samples/）完美无缺。

我遵循的程序：

在应用程序1.（发件人）
在应用程序2上初始化NC。（接收方）
我将far peer id复制到应用程序2.并运行receveInit。
我在应用程序1上初始化发送流（sendInit）。

注意：我试图颠倒最后两个程序，无论如何都要做好工作。

在此之后，我执行sendMessage（），它从toSendText.text读取消息。

不起作用。为什么？我的代码出了什么问题？

提前感谢您提供的所有有用答案。

Answer 1

因为cc.rtmfp.net是连接检查程序，而不是P2P介绍服务（p2p.rtmfp.net）。 cc执行一些快速测试，发送结果并断开连接。它不执行任何其他功能，也不提供任何其他服务。

Answer 2

我发现了。

对于开发和测试，我使用Mac并在那里测试了应用程序。不工作。仍然没有工作。在Windows上，它运行良好。

奇怪。

Answer 3

您必须为receiveMessage()添加处理程序。否则它只是一个你必须调用它的函数。

为什么rtmfp不能使用这些参数和函数？

3 个答案: