Question

我正在开发一个项目，它基于两个主要部分，第一部分由Flex完成，第二部分是Flash专业项目，包含PROJECTNAME.fla和PROJECTNAME.as文件。我的问题是如何在flex部分中设置.fla项目中的一些参数（例如用户名，用户图像）。我按照以下说明主要程序;

通过flex部分连接到服务器并获取用户的状态
运行由上述Flash专业项目创建的.swf
在.swf文件中设置一些参数。

我搜索了很多，但我找不到任何解决方案。（有一些解决方案将符号转换为flex组件，因为它适用于转换单个符号）。任何想法将不胜感激。

Answer 1

有几种方法可以将params从一个swf（在你的情况下是flex）传递给另一个运行时加载的fla.swf：

1.浏览加载查询参数：

flex.swf中的代码：

    public function astest()
    {
        var loader:Loader = new Loader();
        addChild(loader);
        loader.load( new URLRequest("astest1.swf?param1=value1&param2=value2"));
    }

从fla.swf访问参数：

public function astest1()
{
    if(stage)
        onAdded();
    else
        addEventListener(Event.ADDED_TO_STAGE, onAdded);
}

protected function onAdded(event:Event = null):void
{
    //root.loaderInfo.parameters - params of this swf file
    //stage.loaderInfo.parameters - params of core swf file
    var params:Object = root.loaderInfo.parameters;
    for (var param:String in params)
        trace(param,"=",params[param]);
}

输出：

param2 = value2
param1 = value1

缺少这种方法：

- 一次使用时，您只能在加载时传递params一次 - 第二个swf必须由url运行时加载，例如，你不能嵌入它（或其中一个类）。

2.通过活动进行的实时通信
我建议使用这种方法，它不缺乏以前的方法使用stage作为全局公共调度程序的示例。

flex.swf：

    public function astest()
    {
        addEventListener("ready", onReady);
        var loader:Loader = new Loader();
        addChild(loader);
        loader.load( new URLRequest("astest1.swf"));
    }

    protected function onReady(event:Event):void
    {
        sendParams("param1=value1&param2=value2");
    }

    protected function sendParams(params:String):void
    {
        stage.dispatchEvent(new DataEvent("params", false, false, params));
    }

fla.swf：

public function astest1()
{
    if(stage)
        onAdded();
    else
        addEventListener(Event.ADDED_TO_STAGE, onAdded);
}

protected function onAdded(event:Event = null):void
{
    stage.addEventListener("params", onParams);
    //fire event with bubbling that anables handling it in the parent swf
    dispatchEvent(new Event("ready", true));
}

protected function onParams(event:DataEvent):void
{
    var data:String = event.data;
    trace(data);
}

输出：

param1=value1&param2=value2

使用这种方法可以根据需要发送尽可能多的参数，你可以创建自定义事件来传递Object参数，但在这种情况下，两个项目都必须在源路径中有这个cusom事件。

Flex和FLash之间的连接

1 个答案: