Question

我想知道在分析构造函数的字节码时是否有一种明显而快速的方法，以确定super()代码的结束位置。

更具体地说，与Java形成鲜明对比的是，构造函数中对任何super()构造函数方法的调用是可选的（或者更确切地说，当不存在时 - 隐式），在字节码世界中总是需要它。

出于黑魔法的目的，我需要通过字节码分析和最简单的方法来了解什么是INVOKESPECIAL调用，它对应于Java世界的super()调用。

我会带着一个简单的例子离开这里：

public static class A {
    public A(Object o, Object b) {
    }
}

public static class B extends A {
    public B() {
        //the below super is in bold just to signal that's the one
        //I'm looking for
        SUPER(new A(new Object(), new Integer(2)), new Integer(1));
        System.out.println(new A(new Object(), new Integer(2)));
    }
}

带有相应的字节码： enter image description here

Answer 1

实际上，字节码构造函数的规则比Java的规则要宽松得多。

唯一的规则是，必须在任何正常返回的路径上调用一个构造函数，如果构造函数调用抛出异常，那么您也必须抛出异常。

除此之外，这意味着构造函数可能包含对其他构造函数的多个调用，或者根本没有调用。

无论如何，确定给定invokespecial调用是否正在初始化当前对象的唯一保证方法是进行数据流分析，因为可以初始化同一类的其他对象，这会混淆一个天真的检测器。

编辑：这是一个完全有效的类（使用Krakatau汇编语法）的示例，显示了您可能遇到的一些问题。除此之外，它还调用同一个类中的其他构造函数，构造函数的递归调用，以及在构造函数中构造同一个类的其他对象。

.class public ctors
.super java/lang/Object

; A normal constructor
.method public <init> : ()V
    .limit locals 1
    .limit stack 1

    aload_0
    invokespecial java/lang/Object <init> ()V
    return
.end method

; A weird constructor
.method public <init> : (I)V
    .limit locals 2
    .limit stack 5

    iload_1
    ifne LREST
        aload_0
        invokespecial ctors <init> ()V
        return

LREST:
    aload_0
    new ctors
    iinc 1 -1
    iload_1
LFAKE_START:
    invokespecial ctors <init> (I)V
LFAKE_END:
    iconst_0
    invokespecial ctors <init> (I)V
    return

.catch [0] from LFAKE_START to LFAKE_END using LCATCH
LCATCH:
    aload_0
    invokespecial java/lang/Object <init> ()V
    return
.end method

.method public static main : ([Ljava/lang/String;)V
    .limit locals 1
    .limit stack 2

    new ctors
    iconst_5
    invokespecial ctors <init> (I)V
    return
.end method

Answer 2

一个简单的解决方案是计算new A个对象的数量和A.<init>的数量。当您调用超级构造函数时，init比new更多。如果调用new B，您必须对B.<init>和this(...)执行相同的检查。

Answer 3

您必须找出哪个调用操作码操作数堆栈包含将用作第一个参数的this引用。为此，您只需要了解不同操作码对操作数堆栈的影响。在您的示例中，您从aload_0（这是this引用）开始，然后在该引用之上执行相当多的魔术（始终更新操作数堆栈）。一段时间后，您正在寻找的调用操作码就在那里，它会使用this引用（以及参数的一些引用）。然后是super电话。

Answer 4

super（）调用的答案是第no行。 31。

我通过eclipse的类文件编辑器发现它很容易。看看下面附带的按扣。

这里要记住的一件事是，前缀'a'表示操作码正在操作对象引用。前缀'i'表示操作码正在操纵整数。

因此，逐行解释如下，

12  new java.lang.Integer //Create a new java.lang.Integer 
15  dup //Make a extra reference to the same Integer
16  iconst_2 // this means opcode is manipulating Integer as Integer(2)
17  invokespecial java.lang.Integer(int) //Integer(2) is invoked
20  invokespecial A(java.lang.Object, java.lang.Object) //new A(new Object(), new Integer(2) is invoked
23  new java.lang.Integer //Create a new java.lang.Integer
26  dup //Make a extra reference to the same Integer
27  iconst_1 // this means opcode is manipulating Integer as Integer(1)
28  invokespecial java.lang.Integer(int) //Integer(1) is invoked
31  invokespecial A(java.lang.Object, java.lang.Object) **//super(new A(new Object(), new Integer(2)), new Integer(1)) is invoked**

我希望后者很容易理解。：）

56 - this invoke is for the sysout related A(object,object) invocation.

enter image description here

在字节码中确定哪里是super（）方法调用，所有构造函数必须在JVM上执行

4 个答案: