ASP未终止的字符串常量错误

Question

我收到以下错误，我不明白如何修复它。

错误：

Microsoft VBScript compilation error '800a0409'

Unterminated string constant

/junk/airsearch/search.htm, line 118

response.write("
----------------^

ASP代码负责：

  <% if con("notes") = "" then
  response.write("")
  else
  response.write("
  <tr>
    <td colspan='8'><strong>Notes:</strong> con('notes')</td>
  </tr>")
  endif
  %>

整页代码：

<%@CODEPAGE=65001%> 
<%
pagetitle="Aircraft and Simulator Multi-use List 06/074"
%>
<!--#INCLUDE VIRTUAL="/_lib/include/header.htm"-->
<!--#INCLUDE VIRTUAL="/_lib/include/menu.htm"-->
<script>
$(document).ready(function() {
    $("#state").change(function () {
    this.form.submit();
})
$('#supplier_name, #aircraft_type').focus()
$("#supplier_name").val($("#supplier_name").val());
$("#aircraft_type").val($("#aircraft_type").val());
var typingTimer;                
var doneTypingInterval = 800;  

$('#supplier_name, #aircraft_type').keyup(function(){
    clearTimeout(typingTimer);
    if ($('#supplier_name, #aircraft_type').val) {
        typingTimer = setTimeout(doneTyping, doneTypingInterval);
    }
});

function doneTyping () {
    $("form").submit();
}

});
</script>
<div class="twoColumnRow">
<div class="twoColumnContent">
<p class="breadCrm"><a href="/index.htm">Home</a> <span>&gt;</span> <a href="/tools/index.htm">Tools of the Trade</a> <span>&gt;</span> <a href="/tools/finance/index.htm">Finance and Purchasing</a><span>&gt;</span> <a href="/tools/finance/procurement/index.htm">Procurement and Contracts information</a></p>
<div class="contentPad">
<!-- Start of main content -->

<p class="imageRight">&nbsp;</p>
<h1><%=pagetitle%></h1>

<%
        Dim connectString, connect, conDB, sconDB, lDB, con, scon, lcon, src_ccn, src_state
        connectString = "Driver={Microsoft Text Driver (*.txt; *.csv)}; DBQ=" & Server.MapPath("data")
              src_supplier_name = Request.QueryString("supplier_name")
              src_aircraft_type = Request.QueryString("aircraft_type")
              src_state = Request.QueryString("state")
        set connect = Server.CreateObject("ADODB.connection")
        connect.open connectString

        if src_state = "" then
            conDB = "SELECT * FROM mul.csv WHERE ucase(supplier_name) LIKE ucase('%"+src_supplier_name+"%') AND ucase(aircraft_type) LIKE ucase('%"+src_aircraft_type+"%')"   
            lDB = "SELECT * FROM mul.csv WHERE ucase(supplier_name) LIKE ucase('%"+src_supplier_name+"%')" 
        elseif src_state = "any" then
            conDB = "SELECT * FROM mul.csv WHERE ucase(supplier_name) LIKE ucase('%"+src_supplier_name+"%') AND ucase(aircraft_type) LIKE ucase('%"+src_aircraft_type+"%')"   
            lDB = "SELECT * FROM mul.csv WHERE ucase(supplier_name) LIKE ucase('%"+src_supplier_name+"%') AND ucase(aircraft_type) LIKE ucase('%"+src_aircraft_type+"%')" 
        else 
            conDB = " SELECT * FROM mul.csv WHERE ucase(state) LIKE ucase('%"+src_state+"%') AND ucase(supplier_name) LIKE ucase('%"+src_supplier_name+"%') AND ucase(aircraft_type) LIKE ucase('%"+src_aircraft_type+"%')"
            lDB = " SELECT * FROM mul.csv WHERE ucase(state) LIKE ucase('%"+src_state+"%') AND ucase(supplier_name) LIKE ucase('%"+src_supplier_name+"%') AND ucase(aircraft_type) LIKE ucase('%"+src_aircraft_type+"%')"
        end if

        sconDB = "SELECT * FROM mul.csv"    

        set con = connect.execute(conDB)
        set scon = connect.execute(sconDB)
        set lcon = connect.execute(lDB)
%>
<h2>Search results</h2>
<% if not con.BOF then %>
<div style="margin-top:1em">

  <form id="searchf" action="search.htm" method="get">

      <p>Supplier name: <input id="supplier_name" name="supplier_name" type="text" value="<%=src_supplier_name%>"> Aircraft type: <input id="aircraft_type" name="aircraft_type" type="text" value="<%=src_aircraft_type%>"> </p>
     <p>State or Territory:<br/>
      <select style="width: 497px;" id="state" name="state">
        <option class="group" label="Any state or territory" value="any" <%if request.querystring("state") = "any" then response.write("selected") %>></option>
        <option class="group" label="Australian Capital Territory" value="ACT" <%if request.querystring("state") = "ACT" then response.write("selected") %>></option>
        <option class="group" label="New South Whales" value="NSW" <%if request.querystring("state") = "NSW" then response.write("selected") %>></option>
        <option class="group" label="Northern Territory" value="NT" <%if request.querystring("state") = "NT" then response.write("selected") %>></option>
        <option class="group" label="Queensland" value="QLD" <%if request.querystring("state") = "QLD" then response.write("selected") %>></option>
        <option class="group" label="South Australia" value="SA" <%if request.querystring("state") = "SA" then response.write("selected") %>></option>
        <option class="group" label="Tasmania" value="TAS" <%if request.querystring("state") = "TAS" then response.write("selected") %>></option>
        <option class="group" label="Victoria" value="VIC" <%if request.querystring("state") = "VIC" then response.write("selected") %>></option>
        <option class="group" label="Western Australia" value="WA" <%if request.querystring("state") = "WA" then response.write("selected") %>></option>
        <option class="group" label="Other" value="other" <%if request.querystring("state") = "other" then response.write("selected") %>></option>
      </select>

    <input type="submit" value="Search" /></p>
  </form>
  <br />

<table style="font-size:.9em;" class="contentTable">
  <tr>
    <th width="25%">Supplier</th>
    <th width="5%">State</th>
    <th width="20%">Aircraft type</th>
    <th width="10%">Variant</th>
    <th width="10%">Hourly cost</th>
    <th width="10%">Rental basis</th>
    <th width="10%">Timing method</th>
    <th width="10%">Insurance excess</th>

  </tr>
  <% con.Movefirst() %>
  <% while (NOT con.EOF) %>
  <tr>
    <td><a href="searchcomp.htm?ccn=<%=con("ccn")%>"><%=con("supplier_name")%></a></td>
    <td><%=con("state")%></td>
    <td><%=con("aircraft_type")%></td>
    <td><%=con("variant")%></td>
    <td><%=con("cost_hr")%></td>
    <td><%=con("rental_basis")%></td>
    <td><%=con("timing_method")%></td>
    <td><%=con("insurance_excess")%></td>
  </tr>
  <% if con("notes") = "" then
  response.write("")
  else
  response.write("
  <tr>
    <td colspan='8'><strong>Notes:</strong> con('notes')</td>
  </tr>")
  endif
  %>
  <%
    con.MoveNext()
    Wend
  %>
</table>

</div>
<% else %>
    <% scon.Movefirst() %>
  <form id="searchf" action="search.htm" method="get">

      <p>Supplier name: <input id="supplier_name" name="supplier_name" type="text" value="<%=src_supplier_name%>"> Aircraft type: <input id="aircraft_type" name="aircraft_type" type="text" value="<%=src_aircraft_type%>"> </p>
     <p>State or Territory:<br/>
      <select style="width: 497px;" id="state" name="state">
        <option class="group" label="Any state or territory" value="any" <%if request.querystring("state") = "any" then response.write("selected") %>></option>
        <option class="group" label="Australian Capital Territory" value="ACT" <%if request.querystring("state") = "ACT" then response.write("selected") %>></option>
        <option class="group" label="New South Whales" value="NSW" <%if request.querystring("state") = "NSW" then response.write("selected") %>></option>
        <option class="group" label="Northern Territory" value="NT" <%if request.querystring("state") = "NT" then response.write("selected") %>></option>
        <option class="group" label="Queensland" value="QLD" <%if request.querystring("state") = "QLD" then response.write("selected") %>></option>
        <option class="group" label="South Australia" value="SA" <%if request.querystring("state") = "SA" then response.write("selected") %>></option>
        <option class="group" label="Tasmania" value="TAS" <%if request.querystring("state") = "TAS" then response.write("selected") %>></option>
        <option class="group" label="Victoria" value="VIC" <%if request.querystring("state") = "VIC" then response.write("selected") %>></option>
        <option class="group" label="Western Australia" value="WA" <%if request.querystring("state") = "WA" then response.write("selected") %>></option>
        <option class="group" label="Other" value="other" <%if request.querystring("state") = "other" then response.write("selected") %>></option>
      </select>
    </p>
    <input type="submit" value="Search" />
  </form>
  <br /><hr />
<p>No records match your query.</p>
<p><a href="dbtest.htm">Return to search page</a></p>
<%
  end if
  con.close
%>


<!-- End of main content -->
</div> <!-- end contentPad div -->
</div> <!-- end twocolumncontent div -->
<div class="twoColumnLinks">

<!--<div class="relatedLinks">
<h3>Related Links</h3>
<ul>
<li><a href="/index.htm">Related link 1</a></li>
</ul>
</div>--> <!-- end relatedlinks div -->
<!--#INCLUDE VIRTUAL="/_lib/include/quicklinks.htm"-->
<!--#INCLUDE VIRTUAL="/_lib/include/mylinks.htm"-->
</div> <!-- end twocolumnlinks div -->
</div> <!-- end twocolumnrow div -->
<!--#INCLUDE VIRTUAL="/_lib/include/footer.htm"-->

Answer 1

你不能在多行上使用字符串。

将字符串全部放在一行上，或者在行的末尾结束字符串，并将其与下一行的字符串连接起来，依此类推。

Answer 2

至少有三种不同的方式来格式化代码以实现您的目标：

<% Dim con_notes : con_notes = con("notes") %>

<% if con_notes = "" then
response.write("")
else
response.write("<tr>")
response.write("  <td colspan='8'><strong>Notes:</strong> " & con_notes & "</td>")
response.write("</tr>")
end if
%>

或

<% if con_notes <> "" then %>
<tr>
  <td colspan="8"><strong>Notes:</strong> <%=con_notes %></td>
</tr>
<% end if %>

或

<%
if con_notes <> "" then
  response.write "<tr>" & _
                   "<td colspan='8'><strong>Notes:</strong> " & _
                   con_notes & _
                   "</td>" & _
                 "</tr>"
end if
%>

我倾向于选择格式化代码的第二种方式。