Question

我正在努力教自己Perl和我一直在努力...昨晚我做了一个程序来计算用户提供的一组数字的平均值，以便了解列表和用户输入所以今天我想我会做摩尔斯电码解码器来了解哈希。我仔细阅读了我买的这本书并没有真正解释哈希......它实际上并没有很好地解释很多事情。任何帮助，将不胜感激！

无论如何，我想编写一个解码用户输入的莫尔斯代码的程序。因此用户将输入：

-.-.
.-
-
...
!
.-.
..-
.-..
.

感叹号将代表一个单独的词。此消息将向用户返回“Cats Rule”。下面是我到目前为止的代码......记住..我已经在perl编程了不到24小时哈哈。

代码：

  use 5.010;




my %morsecode=(
    '.-'    =>'A',  '-...'  =>'B',  '-.-.'  =>'C',  '-..'   =>'D',
    '.' =>'E',  '..-.'  =>'F',  '--.'   =>'G',  '....'  =>'H',
    '..'    =>'I',  '.---'  =>'J',  '-.-'   =>'K',  '.-..'  =>'L',
    '--'    =>'M',  '-.'    =>'N',  '---'   =>'O',  '.--.'  =>'P',
    '--.-'  =>'Q',  '.-.'   =>'R',  '...'   =>'S',  '-' =>'T',
    '..-'   =>'U',  '...-'  =>'V',  '.--'   =>'W',  '-..-'  =>'X',
    '-.--'  =>'Y',  '--..'  =>'Z',  '.----' =>'1',  '..---' =>'2',
    '...--' =>'3',  '....-' =>'4',  '.....' =>'5',  '-....' =>'6',
    '--...' =>'7',  '---..' =>'8',  '----.' =>'9',  '-----' =>'0',
    '.-.-.-'=>'.',  '--..--'=>',',  '---...'=>':',  '..--..'=>'?',
    '.----.'=>'\'', '-...-' =>'-',  '-..-.' =>'/',  '.-..-.'=>'\"'
);

my @k = keys %morsecode;
my @v = values %morsecode;

say "Enter a message in morse code separated by a line. Use the exclamation point (!) to separate words. Hit Control+D to signal the end of input.";
my @message = <STDIN>;
chomp @message;

my $decodedMessage = encode(@message);


sub encode {
    foreach @_ {
    if (@_ == @k) {
        return @k;

#This is where I am confused... I am going to have to add the values to an array, but I don't really know how to go about it.


        }
    else if(@_ == '!') {return ' '}
    else
    {
    return 'Input is not valid';
    }
    }
}

Answer 1

您的代码包含两个语法错误：foreach需要列表进行迭代;这意味着parens。与C和其他语言不同，Perl不支持else if (...)。相反，请使用elsif (...)。

然后会出现一些语义错误：迭代的当前值存储在$_中。数组@_包含对函数调用的参数。

Perl以不同的方式比较字符串和数字：

Strings Numbers
eq      ==
lt      <
gt      >
le      <=
ge      >=
ne      !=
cmp     <=>

为手头的任务使用正确的运算符，在这种情况下，使用严格的运算符。

（你的代码@_ == @k做了一些事情，即在数字 context 中使用数组。这会产生元素的数量，然后进行比较。@_ == '!'很奇怪。）

您真正想要做的是将输入的值映射到字符列表。您的哈希定义了此映射，但我们想要应用它。 Perl有一个map函数，就像

一样

@out_list = map { ACTION } @in_list;

在操作块内，当前值可用作$_。

我们希望我们的操作在哈希中查找适当的值，或者如果输入字符串没有映射，则包含错误消息：

my @letters = map { $morsecode{$_} // "<unknown code $_>" } @message;

这假定!已在morsecode哈希中注册为空格。

然后，我们通过join用空字符串创建这些字母的单个字符串：

my $translated_message = join "", @letters;

不要忘记打印出结果！

完整的代码：

#!/usr/bin/perl
use strict; use warnings; use 5.012;

my %morsecode=(
  '.-'    =>'A',  '-...'  =>'B',  '-.-.'  =>'C',  '-..'   =>'D',
  '.'     =>'E',  '..-.'  =>'F',  '--.'   =>'G',  '....'  =>'H',
  '..'    =>'I',  '.---'  =>'J',  '-.-'   =>'K',  '.-..'  =>'L',
  '--'    =>'M',  '-.'    =>'N',  '---'   =>'O',  '.--.'  =>'P',
  '--.-'  =>'Q',  '.-.'   =>'R',  '...'   =>'S',  '-'     =>'T',
  '..-'   =>'U',  '...-'  =>'V',  '.--'   =>'W',  '-..-'  =>'X',
  '-.--'  =>'Y',  '--..'  =>'Z',  '.----' =>'1',  '..---' =>'2',
  '...--' =>'3',  '....-' =>'4',  '.....' =>'5',  '-....' =>'6',
  '--...' =>'7',  '---..' =>'8',  '----.' =>'9',  '-----' =>'0',
  '.-.-.-'=>'.',  '--..--'=>',',  '---...'=>':',  '..--..'=>'?',
  '.----.'=>'\'', '-...-' =>'-',  '-..-.' =>'/',  '.-..-.'=>'"',
  '!'     =>' ',
);

say "Please type in your morse message:";
my @codes = <>;
chomp @codes;

my $message = join "", map { $morsecode{$_} // "<unknown code $_>" } @codes;

say "You said:";
say $message;

这会产生所需的输出。

Answer 2

学习如何以及为什么有很多价值，但这就是：

sub encode {
  my $output;
  foreach my $symbol (@_) {
    my $letter = $morsecode{$symbol};
    die "Don't know how to decode $symbol" unless defined $letter;
    $output .= $letter
  }
  return $output;
}

如果你不太担心错误检查，那么

甚至只要sub encode { join '', map $morsecode{$_}, @_ }。任何事情都不需要@k和@v。

Answer 3

在哈希中搜索值是一项非常紧张的工作，只需使用反向哈希就可以了。您可以使用Perl中的reverse function轻松反转哈希值。此外，在观察您的代码时，我已经看到您将能够输入小写输入。但是在密钥上搜索哈希时，这是区分大小写的。所以你需要uppercase你的意见。另外，我真的不喜欢“结束”STDIN的方式。退出字/标志会更好更清洁。

我对你的代码的看法

my %morsecode=(
    '.-'    =>'A',  '-...'  =>'B',  '-.-.'  =>'C',  '-..'   =>'D',
    '.' =>'E',  '..-.'  =>'F',  '--.'   =>'G',  '....'  =>'H',
    '..'    =>'I',  '.---'  =>'J',  '-.-'   =>'K',  '.-..'  =>'L',
    '--'    =>'M',  '-.'    =>'N',  '---'   =>'O',  '.--.'  =>'P',
    '--.-'  =>'Q',  '.-.'   =>'R',  '...'   =>'S',  '-' =>'T',
    '..-'   =>'U',  '...-'  =>'V',  '.--'   =>'W',  '-..-'  =>'X',
    '-.--'  =>'Y',  '--..'  =>'Z',  '.----' =>'1',  '..---' =>'2',
    '...--' =>'3',  '....-' =>'4',  '.....' =>'5',  '-....' =>'6',
    '--...' =>'7',  '---..' =>'8',  '----.' =>'9',  '-----' =>'0',
    '.-.-.-'=>'.',  '--..--'=>',',  '---...'=>':',  '..--..'=>'?',
    '.----.'=>'\'', '-...-' =>'-',  '-..-.' =>'/',  '.-..-.'=>'\"'
);
my %reversemorse = reverse %morsecode;
print "Enter a message\n";
chomp (my $message = <STDIN>);
print &encode($message);

sub encode{
    my $origmsg = shift(@_);
    my @letters = split('',$origmsg);
    my $morse = '';
    foreach $l(@letters)
    {
        $morse .= $reversemorse{uc($l)}." ";
    }    
    return $morse;
}

Perl中的莫尔斯码解码器

3 个答案: