Question

有没有办法解析vb.net中的字符串（比如内置方法），可以像Eval那样进行数学运算吗？例如，3 +（7 / 3.5）作为字符串将返回2.

我不是要求你为我编写代码，我只是想知道是否有内置方式来执行此操作，如果不存在，我将自己编写代码。

我可以打赌它不能自己解析像Sin（90）这样的东西，我明白需要用Math.Sin（90）代替。

如果有内置方法，你如何使用它？

Answer 1

使用DataTable.Compute method有限制（即简单）数学表达式的快捷方式。显然，这不是很强大（功能有限），并且为了这个目的而滥用DataTable感觉很不自在，但我想我会添加到当前的答案中。

示例：

var result = new DataTable().Compute("3+(7/3.5)", null); // 5

“罪（90）”不适合这种方法。有关支持的功能列表，请参阅DataColumn.Expression Property page，特别是在“聚合”部分下。

使用System.CodeDom命名空间是一个选项。

一些有用的链接：

编辑：来解决您的评论，这是一种演示用等效的Math类方法替换三角函数的方法。

<强> C＃

string expression = "(Sin(0) + Cos(0)+Tan(0)) * 10";
string updatedExpression = Regex.Replace(expression, @"(?<func>Sin|Cos|Tan)\((?<arg>.*?)\)", match =>
            match.Groups["func"].Value == "Sin" ? Math.Sin(Int32.Parse(match.Groups["arg"].Value)).ToString() :
            match.Groups["func"].Value == "Cos" ? Math.Cos(Int32.Parse(match.Groups["arg"].Value)).ToString() :
            Math.Tan(Int32.Parse(match.Groups["arg"].Value)).ToString()
        );
var result = new DataTable().Compute(updatedExpression, null); // 10

<强> VB.NET

Dim expression As String = "(Sin(0) + Cos(0)+Tan(0)) * 10"
Dim updatedExpression As String = Regex.Replace(expression, "(?<func>Sin|Cos|Tan)\((?<arg>.*?)\)", Function(match As Match) _
        If(match.Groups("func").Value = "Sin", Math.Sin(Int32.Parse(match.Groups("arg").Value)).ToString(), _
        If(match.Groups("func").Value = "Cos", Math.Cos(Int32.Parse(match.Groups("arg").Value)).ToString(), _
        Math.Tan(Int32.Parse(match.Groups("arg").Value)).ToString())) _
        )
Dim result = New DataTable().Compute(updatedExpression, Nothing)

但请注意，您需要知道“arg”组的内容。我知道它们是整数，所以我在它们上面使用了Int32.Parse。如果它们是项目的组合，那么这种简单的方法将不起作用。我怀疑如果问题变得过于复杂以及更多不受支持的函数调用，您将不断需要对该解决方案进行创可贴，在这种情况下，CodeDom方法或其他方法可能更合适。

Answer 2

以下是一种评估我在其他任何地方都没有提到的表达式的方法：使用WebBrowser控件和JavaScript eval()：

Option Strict On

Imports System.Security.Permissions

<PermissionSet(SecurityAction.Demand, Name:="FullTrust")> _
<System.Runtime.InteropServices.ComVisibleAttribute(True)>
Public Class Form1
    Dim browser As New WebBrowser

    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        browser.ObjectForScripting = Me
        'browser.ScriptErrorsSuppressed = True
        browser.DocumentText = "<script>function evalIt(x) { return eval(x); }</script>"
    End Sub

    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click

        Dim result = browser.Document.InvokeScript("evalIt", New String() {"3+4*5"})
        If result IsNot Nothing Then
            MessageBox.Show(result.ToString())     '23
        End If
    End Sub
End Class

Answer 3

我不知道内置的VB.net，但我们通过在IronPython运行时链接并传递表达式来做这样的事情。这比使用反射更快。

Answer 4

此CodeProject文章可能会解决这个问题：

用VB.NET编写的表达式求值程序
http://www.codeproject.com/KB/vb/expression_evaluator.aspx

还有这个：
http://www.dotnetspider.com/resources/2518-mathematical-expression-expression-evaluate-VB.aspx

Answer 5

一种方法是使用CodeDom命名空间编译它并使用反射执行它。可能不是那种表现，我不知道。

Answer 6

这有点晚了，但这正是你想要的（确保你解析输入以确保没有像'something + vbcrlf + exec'格式c：“'中的语句）：

用法：

MessageBox.Show(COR.Tools.EvalProvider.Eval("return 8-3*2").ToString())

类：

'Imports Microsoft.VisualBasic
Imports System


Namespace COR.Tools


Public Class EvalProvider


    Public Shared Function Eval(ByVal vbCode As String) As Object
        Dim c As VBCodeProvider = New VBCodeProvider
        Dim icc As System.CodeDom.Compiler.ICodeCompiler = c.CreateCompiler()
        Dim cp As System.CodeDom.Compiler.CompilerParameters = New System.CodeDom.Compiler.CompilerParameters

        cp.ReferencedAssemblies.Add("System.dll")
        cp.ReferencedAssemblies.Add("System.xml.dll")
        cp.ReferencedAssemblies.Add("System.data.dll")
        ' Sample code for adding your own referenced assemblies
        'cp.ReferencedAssemblies.Add("c:\yourProjectDir\bin\YourBaseClass.dll")
        'cp.ReferencedAssemblies.Add("YourBaseclass.dll")
        cp.CompilerOptions = "/t:library"
        cp.GenerateInMemory = True
        Dim sb As System.Text.StringBuilder = New System.Text.StringBuilder("")
        sb.Append("Imports System" & vbCrLf)
        sb.Append("Imports System.Xml" & vbCrLf)
        sb.Append("Imports System.Data" & vbCrLf)
        sb.Append("Imports System.Data.SqlClient" & vbCrLf)
        sb.Append("Imports Microsoft.VisualBasic" & vbCrLf)

        sb.Append("Namespace MyEvalNamespace  " & vbCrLf)
        sb.Append("Class MyEvalClass " & vbCrLf)

        sb.Append("public function  EvalCode() as Object " & vbCrLf)
        'sb.Append("YourNamespace.YourBaseClass thisObject = New YourNamespace.YourBaseClass()")
        sb.Append(vbCode & vbCrLf)
        sb.Append("End Function " & vbCrLf)
        sb.Append("End Class " & vbCrLf)
        sb.Append("End Namespace" & vbCrLf)
        Debug.WriteLine(sb.ToString()) ' look at this to debug your eval string
        Dim cr As System.CodeDom.Compiler.CompilerResults = icc.CompileAssemblyFromSource(cp, sb.ToString())
        Dim a As System.Reflection.Assembly = cr.CompiledAssembly
        Dim o As Object
        Dim mi As System.Reflection.MethodInfo
        o = a.CreateInstance("MyEvalNamespace.MyEvalClass")
        Dim t As Type = o.GetType()
        mi = t.GetMethod("EvalCode")
        Dim s As Object
        s = mi.Invoke(o, Nothing)
        Return s
    End Function


End Class ' EvalProvider


End Namespace

在jb中像Eval一样在vb.net中进行数学运算

6 个答案: