我有以下脚本
awk '{printf "%s", $1"-"$2", "}' $a >> positions;
其中$a存储文件名。我实际上是将多个列值写入一行。但是，我想在我不在最后一行时打印一个逗号。
答案 0 :(得分：19)
单程方式：
cat "$a" | # look, I can use this in a pipeline!
awk 'NR > 1 { printf(", ") } { printf("%s-%s", $1, $2) }'
请注意，我还简化了字符串格式。
答案 1 :(得分：11)
享受这一个：
awk '{printf t $1"-"$2} {t=", "}' $a >> positions
是的，乍一看看起来有点棘手。所以我要解释一下，首先让printf改为print以明确：
awk '{print t $1"-"$2} {t=", "}' file
并查看其功能，例如，对于包含此简单内容的文件：
1 A
2 B
3 C
4 D
所以它会产生以下结果：
1-A
, 2-B
, 3-C
, 4-D
技巧是前面的t变量，它在开头是空的。该变量仅在显示{t=...}后的下一步处理时设置为{print t ...}。因此，如果我们（awk）继续迭代，我们将获得所需的序列。
答案 2 :(得分：5)
我会通过在运行脚本之前查找行数来实现，例如：使用coreutils和bash：
awk -v nlines=$(wc -l < $a) '{printf "%s", $1"-"$2} NR != nlines { printf ", " }' $a >>positions
如果您的文件只有2列，则以下coreutils替代方案也可以使用。示例数据：
paste <(seq 5) <(seq 5 -1 1) | tee testfile
输出：
1 5
2 4
3 3
4 2
5 1
现在用换行符替换制表符，paste可以轻松地将日期组合成所需的格式：
<testfile tr '\t' '\n' | paste -sd-,
输出：
1-5,2-4,3-3,4-2,5-1
答案 3 :(得分：2)
您可能认为awk的ORS和OFS是处理此问题的合理方法：
$ awk '{print $1,$2}' OFS="-" ORS=", " input.txt
但这导致最终的ORS，因为输入在最后一行包含换行符。换行符是一个记录分隔符，因此从awk的角度来看，输入中有一个空的最后一条记录。你可以通过一些hackery解决这个问题，但由此产生的复杂性消除了单线的优雅。
所以这是我对此的看法。既然你说你正在“编写多个列值”，那么使用ORS和OFS就可能会导致问题。因此，我们可以完全通过格式化来实现所需的输出。
$ cat input.txt
3 2
5 4
1 8
$ awk '{printf "%s%d-%d",t,$1,$2; t=", "} END{print ""}' input.txt
3-2, 5-4, 1-8
这类似于Michael和rook的单遍方法，但它使用单个printf并正确使用格式字符串进行格式化。
这可能比迈克尔的解决方案表现得更好，因为分配应该比测试花费更少的CPU，并且明显优于任何多遍解决方案，因为文件只需要读取一次。
答案 4 :(得分：1)
这是一种更好的方法，不需要求助于coreutils：
awk 'FNR==NR { c++; next } { ORS = (FNR==c ? "\n" : ", "); print $1, $2 }' OFS="-" file file
答案 5 :(得分：0)
awk '{a[NR]=$1"-"$2;next}END{for(i=1;i<NR;i++){print a[i]", " }}' $a > positions