Question

我正在使用Delphi XE3，我正在开发一个从Excel读取数字类型单元格的应用程序。我正在使用TStringGrid进行此导入。

我已经知道，如何将它们转换为字符串网格，但无法像Excel中那样设置任何数学函数。如何计算字符串网格的选定单元格值的最小值，最大值和平均值？

Answer 1

您可以尝试以下功能。它返回当前字符串网格选择中找到的数值的计数。要传递给它的声明参数，返回当前选择的数值（如果有的话）的最小值，最大值和平均值：

uses
  Math;

function CalcStats(AStringGrid: TStringGrid; var AMinValue, AMaxValue,
  AAvgValue: Double): Integer;
var
  Col, Row, Count: Integer;
  Value, MinValue, MaxValue, AvgValue: Double;
begin
  Count := 0;
  MinValue := MaxDouble;
  MaxValue := MinDouble;
  AvgValue := 0;

  for Col := AStringGrid.Selection.Left to AStringGrid.Selection.Right do
    for Row := AStringGrid.Selection.Top to AStringGrid.Selection.Bottom do
    begin
      if TryStrToFloat(AStringGrid.Cells[Col, Row], Value) then
      begin
        Inc(Count);
        if Value < MinValue then
          MinValue := Value;
        if Value > MaxValue then
          MaxValue := Value;
        AvgValue := AvgValue + Value;
      end;
    end;

  Result := Count;
  if Count > 0 then
  begin
    AMinValue := MinValue;
    AMaxValue := MaxValue;
    AAvgValue := AvgValue / Count;
  end;
end;

以下是一个示例用法：

procedure TForm1.Button1Click(Sender: TObject);
var
  MinValue, MaxValue, AvgValue: Double;
begin
  if CalcStats(StringGrid1, MinValue, MaxValue, AvgValue) > 0 then
    Label1.Caption :=
      'Min. value: ' + FloatToStr(MinValue) + sLineBreak +
      'Max. value: ' + FloatToStr(MaxValue) + sLineBreak +
      'Avg. value: ' + FloatToStr(AvgValue)
  else
    Label1.Caption := 'There is no numeric value in current selection...';
end;

另一章是如何在字符串网格的选择发生变化时获得通知。实现OnSelectionChange之类的事件没有事件或虚拟方法。但这可能是另一个问题的主题。

如何计算字符串网格中所选单元格的最小值，最大值和平均值？

1 个答案: