Question

我有一个功能，它会拍摄彩色照片并返回它的灰色版本。如果我在主机上运行顺序代码，一切都很完美。如果我在设备上运行它，结果会略有不同（1000中的一个像素与正确值相比为+1或-1）。

我认为这与转化有关，但我不确定。这是我使用的代码：

    __global__ void rgb2gray_d (unsigned char *deviceImage, unsigned char *deviceResult, const int height, const int width){
    /* calculate the global thread id*/
    int threadsPerBlock  = blockDim.x * blockDim.y;
    int threadNumInBlock = threadIdx.x + blockDim.x * threadIdx.y;
    int blockNumInGrid   = blockIdx.x  + gridDim.x  * blockIdx.y;

    int globalThreadNum = blockNumInGrid * threadsPerBlock + threadNumInBlock;
    int i = globalThreadNum;

    float grayPix = 0.0f;
    float r = static_cast< float >(deviceImage[i]);
    float g = static_cast< float >(deviceImage[(width * height) + i]);
    float b = static_cast< float >(deviceImage[(2 * width * height) + i]);
    grayPix = (0.3f * r) + (0.59f * g) + (0.11f * b);

    deviceResult[i] = static_cast< unsigned char > (grayPix);
}

void rgb2gray(unsigned char *inputImage, unsigned char *grayImage, const int width, const int height, NSTimer &timer) {

    unsigned char *deviceImage;
    unsigned char *deviceResult;

    int initialBytes = width * height * 3;  
    int endBytes =  width * height * sizeof(unsigned char);

    unsigned char grayImageSeq[endBytes];

    cudaMalloc((void**) &deviceImage, initialBytes);
    cudaMalloc((void**) &deviceResult, endBytes);
    cudaMemset(deviceResult, 0, endBytes);
    cudaMemset(deviceImage, 0, initialBytes);

    cudaError_t err = cudaMemcpy(deviceImage, inputImage, initialBytes, cudaMemcpyHostToDevice);    

    // Convert the input image to grayscale 
    rgb2gray_d<<<width * height / 256, 256>>>(deviceImage, deviceResult, height, width);
    cudaDeviceSynchronize();

    cudaMemcpy(grayImage, deviceResult, endBytes, cudaMemcpyDeviceToHost);

    ////// Sequential
    for ( int y = 0; y < height; y++ ) {
             for ( int x = 0; x < width; x++ ) {
                   float grayPix = 0.0f;
                   float r = static_cast< float >(inputImage[(y * width) + x]);
                   float g = static_cast< float >(inputImage[(width * height) + (y * width) + x]);
                   float b = static_cast< float >(inputImage[(2 * width * height) + (y * width) + x]);

                   grayPix = (0.3f * r) + (0.59f * g) + (0.11f * b);
                   grayImageSeq[(y * width) + x] = static_cast< unsigned char > (grayPix);
              }
        }

    //compare sequential and cuda and print pixels that are wrong
    for (int i = 0; i < endBytes; i++)
    {
        if (grayImage[i] != grayImageSeq[i])
        cout << i << "-" << static_cast< unsigned int >(grayImage[i]) <<
                 " should be " << static_cast< unsigned int >(grayImageSeq[i]) << endl;
        }

    cudaFree(deviceImage);
    cudaFree(deviceResult);
}

我提到我为初始图像宽度*高度* 3分配，因为初始图像是CImg。

我使用的是GeForce GTX 480。

Answer 1

最后我找到了答案。 CUDA自动融合了单精度和双精度的乘法加法。使用第{4.4}节1下面的文档，我设法解决了这个问题。而不是做

grayPix = (0.3f * r) + (0.59f * g) + (0.11f * b);

我现在在做

grayPix = __fadd_rn(__fadd_rn(__fmul_rn(0.3f, r),__fmul_rn(0.59f, g)), __fmul_rn(0.11f, b));

这会禁用乘法的合并，并添加到融合的乘法 - 加法指令中。

Floating Point and IEEE 754 Compliance for NVIDIA GPUs

Answer 2

浮点数学在设备代码与主机代码之间会产生略微不同的结果。

为什么会出现这种情况有多种可能性。您必须考虑这两个函数由两个不同的编译器编译为两个不同的二进制程序，运行在两个不同的浮点硬件实现上。

例如，如果以不同顺序执行浮点计算，则舍入错误会导致不同的结果。

当在x86架构CPU上使用32位（浮点）或64位（双）浮点表示运行浮点计算时，浮点数学运算由内部使用80位精度的FPU单元完成，然后，对于浮点数据类型，结果将被截断为32位，对于双数据类型，结果将被截断为64位。

GPU的ALU使用32位精度进行浮点数学运算（假设您使用的是浮点数据类型）。

可以找到一篇讨论浮点表示和算术主题的优秀文章here。

在主机和GPU上添加CUDA的结果不同

2 个答案: