Question

使用以下XML：

<Sections><Section Type="Type1" Text="blabla1"><Section Type="Type2" Text="blabla2"/>  </Section></Sections>

我想生成以下输出：

<Sections><Type1 Text="blabla1"><Type2 Text="blabla2"/></Type1></Sections>

我正在玩XSLT很多个小时，我甚至无法想出一些事情...... XLST转换有很多很好的例子，但我仍然缺少一些关于递归的东西并使用Type属性来创建我的节点。如何将文档中的任何节节点转换为其对应的类型属性？

任何类似的教程，xslt资源或任何可以开始的东西都很棒

由于

Answer 1

如何（根据评论中的要求，修改为双向转换）：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes"/>

  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>

  <!-- Prevent Type attributes from being copied to the output-->
  <xsl:template match="@Type" />

  <!-- Convert <Section Type="Nnn" ... /> into <Nnn ... /> -->
  <xsl:template match="Section">
    <xsl:element name="{@Type}">
      <xsl:apply-templates select="@* | node()"/>
    </xsl:element>
  </xsl:template>

  <!-- Convert <Nnn .... /> into <Section Type="Nnn" ... /> -->
  <xsl:template match="Sections//*[not(self::Section)]">
    <Section Type="{name()}">
      <xsl:apply-templates select="@* | node()" />
    </Section>
  </xsl:template>

</xsl:stylesheet>

在第一个示例上运行时的输出：

<Sections>
  <Type1 Text="blabla1">
    <Type2 Text="blabla2" />
  </Type1>
</Sections>

在第二个示例上运行时的输出：

<Sections>
  <Section Type="Type1" Text="blabla1">
    <Section Type="Type2" Text="blabla2" />
  </Section>
</Sections>

使用属性进行递归XSLT转换

1 个答案: