Question

我知道还有其他一些与此相似的问题/答案，但我还没有读过一篇解决我对这种转变的困惑的问题。我需要从这种格式移动XML文档：

<root>
    <row>
        <t0>1</t0>
        <title>Main Title</title>
    </row>
    <row>
        <t0>2</t0>
        <title>Secondary Title</title>
        <note>Note</note>
    </row>
    <row>
        <t0>3</t0>
        <title>Tertiary Title</title>
    </row>
    <row>
        <t0>3</t0>
        <title>Another Title</title>
    </row>
    <row>
        <t0>2</t0>
        <title>A Second Secondary Title</title>
        <note>Note</note>
    </row>
    <row>  
        <t0>3</t0>
        <title>Third Level Title</title>
    </row>
    <row> 
        <t0>3</t0>
        <title>Title at Level Three</title>
    </row>
</root>

采用以下格式：

<root>
    <header>List</header>
    <t01>
        <title>Main Title</title>
        <t02>
            <title>Secondary Title</title>
            <note>Note</note>
            <t03>
                <title>Tertiary Title</title>
            </t03>
            <t03>
                <title>Another Title</title>
            </t03>
        </t02>
        <t02>
            <title>A Second Secondary Title</title>
            <note>Note</note>
            <t03>
                <title>Third Level Title</title>
            </t03>
            <t03>   
                <title>Title at Level Three</title>
            </t03>
        </t02>
    </t01>
</root>

我正在使用XSLT 2.0，并且我已经挂断了递归申请每个组。谢谢你的时间和麻烦。

Answer 1

使用XSLT 2.0，我强烈建议将for-each-grouping与递归函数或模板一起使用;下面是使用函数的示例：

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="2.0"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  xmlns:mf="http://example.com/mf"
  exclude-result-prefixes="xs mf">

<xsl:output indent="yes"/>

<xsl:function name="mf:group" as="element()*">
  <xsl:param name="elements" as="element(row)*"/>
  <xsl:param name="level" as="xs:integer"/>
  <xsl:for-each-group select="$elements" group-starting-with="row[t0 = $level]">
    <xsl:element name="t{format-number($level, '00')}">
      <xsl:copy-of select="* except t0"/>
      <xsl:sequence select="mf:group(current-group() except ., $level + 1)"/>
    </xsl:element>
  </xsl:for-each-group>
</xsl:function>

<xsl:template match="root">
  <xsl:copy>
    <header>List</header>
    <xsl:sequence select="mf:group(row, 1)"/>
  </xsl:copy>
</xsl:template>

</xsl:stylesheet>

Answer 2

请试一试：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes"/>

  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="/root">
    <root>
      <header>List</header>
      <xsl:apply-templates select="row[t0 = 1]" />
    </root>
  </xsl:template>

  <xsl:template match="row">
    <xsl:variable name="level" select="t0" />

    <xsl:element name="{concat('t0', $level)}">
      <xsl:apply-templates select="title | note" />
      <xsl:variable name="nextPeer" 
            select="following-sibling::row[t0 &lt;= $level]" />
      <xsl:variable name="children" 
            select="following-sibling::row[t0 = $level + 1][not($nextPeer) 
                 or (count(preceding-sibling::row) &lt; count($nextPeer[1]/preceding-sibling::row))]" />

      <xsl:apply-templates select="$children" />
    </xsl:element>
  </xsl:template>
</xsl:stylesheet>

XSLT如何应用递归来从平面文件转换为嵌套树

2 个答案: