Question

所以，我真的陷入困境，开始认为它不是正确的方法。考虑这个字符串：“[APPLE | ORANGE] PEAR” 这里的逻辑应该 “如果APPLE是字符串，给我它的颜色ELSE如果ORANGE是字符串，让我的颜色ELSE返回空字符串。现在总是返回PEAR颜色。”

我能够让Hello World正常工作。我正在努力让ANTLR理解我的字符串中的条件逻辑。我正在努力让ANTLR为每个标识符调用getColor（）。任何帮助或指导将不胜感激。我此刻正在冒烟。

grammar Test;

@header {
  package org.mytest.Test;
}

@members {
    private String answer = "";

    private void getColor(String fruit)
    {
        //Use java reflection to get Fruit class and invoke method getColor()
        answer = fruit.color;
    }

}

 @lexer::header {
  package org.mytest.Test;
}


/*------------------------------------------------------------------
 * PARSER RULES
 *------------------------------------------------------------------*/

row returns [List<String> list]
@init {list = new ArrayList<String>();}
  :  a=value {list.add($a.val);} (WS b=value {list.add($b.val);})* (EOF)
  ;

conditionalString    returns [String color]:
                (
                a=IDENTIFIER (WS IDENTIFIER)* {getColor($a.text); } 
                )
                {$color=answer;};

//Get the text string for the matched identifier?
value returns [String val]  :  IDENTIFIER {val = $IDENTIFIER.text;}  ;


/*------------------------------------------------------------------
 * LEXER RULES
 *------------------------------------------------------------------*/

IDENTIFIER  :   ('A'..'Z')+;


WS : ( '\t' | ' ')+     { $channel = HIDDEN; } ;

理想的用法如下。 “context”参数将是一些资源句柄。我会手动编辑构造函数以传递上下文，以便ANTL知道如何处理每个令牌。

TestLexer lex = new TestLexer(new ANTLRStringStream("[APPLE|ORANGE] PEAR"));
CommonTokenStream tok = new CommonTokenStream(lex);
TestParser par = new TestParser(context,tok);
System.out.println(par.conditionalString());

Answer 1

这是一个我认为接近你所要求的语法。它只完全按照您的指定处理案例：[id|id|id]是一个简单的条件，条件之外的任何id都按原样评估。

Fruit.g

grammar Fruit;

@parser::members { 

    private StringBuilder output = new StringBuilder();
    private java.util.HashMap<String, String> colors = new java.util.HashMap<String, String>();

    public void addColor(String fruit, String color){
        colors.put(fruit, color);
    }

    private void printColor(String fruit){
        if (colors.containsKey(fruit)){
            output.append(colors.get(fruit));
            output.append(" ");
        } else { 
            output.append("(no color for ").append(fruit).append(")");
        }
    }

    private void printColor(Token id){
        printColor(id.getText());
    }

    private void evaluateCondition(java.util.List<Token> tokens){
        for (Token token : tokens){
            String fruit = token.getText();
            if (colors.containsKey(fruit)){
                printColor(fruit);
                break;
            }
        }
    }
}

conditionalString returns [String result]
@after { result = output.toString();}
            : expr
            ;

expr        : cond_expr+
            ;

cond_expr   : ID
            {printColor($ID);}
            | LSQB values+=ID (OR values+=ID)* RSQB
            {evaluateCondition($values);}
            ;

OR          : '|';
LSQB        : '[';
RSQB        : ']';
ID          : ('A'..'Z')+;
WS          : ('\t'|' ')+ {skip();};

这是测试类。解析器上的方法addColor用于简化测试。例如，如果水果“ORANGE”的颜色为“橙色”且输入字符串为“ORANGE ORANGE”，则输出应为“橙色橙色”。

FruitTest.java

public class FruitTest {

    public static void main(String[] args) throws Exception {
        CharStream input = new ANTLRStringStream("[APPLE|ORANGE] PEAR");
        FruitLexer lexer = new FruitLexer(input);
        CommonTokenStream tokens = new CommonTokenStream(lexer);

        FruitParser parser = new FruitParser(tokens);

        parser.addColor("APPLE", "red");
        parser.addColor("ORANGE", "orange");
        parser.addColor("PEAR", "yellow");

        String result = parser.conditionalString();

        if (lexer.getNumberOfSyntaxErrors() > 0 || parser.getNumberOfSyntaxErrors() > 0){
            throw new Exception("Syntax errors encountered!");
        }

        System.out.println(result);
    }
}

测试案例1：很多水果

APPLE = red
ORANGE = orange
PEAR =黄色

输入：[APPLE|ORANGE] PEAR
输出：red yellow

测试案例2：大量水果

ORANGE = orange
PEAR =黄色

输入：[APPLE|ORANGE] PEAR
输出：orange yellow

测试案例3：水果低

PEAR =黄色

输入：[APPLE|ORANGE] PEAR
输出：yellow

测试案例4：绝食（未定义水果颜色）

输入：[APPLE|ORANGE] PEAR
输出：(no color for PEAR)

由于PEAR不是条件的一部分，因此预计会定义它。

对于像这样的东西，ANTLR是正确的方法吗？

1 个答案: