我写了一个批处理文件,它执行以下操作:
REM @ECHO OFF
rem %1 = coid
rem %2 = rpg location with ending /
rem get the path of this cmd script
SET SUBDIR=%~dp0
SET BKUPDIR=%SUBDIR%BACKUPS\
SET LOGFILE=%BKUPDIR%backup.log
ECHO ************************************************* >>%LOGFILE%
ECHO STARTING BACKUP FOR %1 AT %2 >>%LOGFILE%
FOR /f "skip=1" %%x in ('wmic os get localdatetime') DO IF NOT defined mydate SET mydate=%%x
SET filedate=%mydate:~0,14%
SET fullname=%BKUPDIR%%1_%FILEDATE%.ZIP
ECHO BKUPDIR: %BKUPDIR% >>%LOGFILE%
ECHO mydate: %mydate% >>%LOGFILE%
ECHO filedate: %filedate% >>%LOGFILE%
ECHO fullname: %fullname% >>%LOGFILE%
ECHO SUBDIR: %SUBDIR% >>%LOGFILE%
rem lets make sure the backup directory exists before starting
IF NOT EXIST %BKUPDIR% MD %BKUPDIR% >>%LOGFILE%
%SUBDIR%7z a -tzip %fullname% %2%1*.d
IF ERRORLEVEL 255 ECHO user_stopped_the_process >>%LOGFILE%
IF ERRORLEVEL 8 ECHO not_enough_memory >>%LOGFILE%
IF ERRORLEVEL 7 ECHO command_line_error >>%LOGFILE%
IF ERRORLEVEL 2 ECHO fatal_error >>%LOGFILE%
IF ERRORLEVEL 1 ECHO ok_warnings >>%LOGFILE%
IF ERRORLEVEL 0 GOTO END
IF EXIST %fullname% DEL %fullname%
:END
ECHO FINISHING BACKUP FOR %1 >>%LOGFILE%
ECHO ************************************************* >>%LOGFILE%
set mydate=
我将文件保存为%1
以及创建文件的日期/时间:
SSS_20130110133304.ZIP
SSS_20130110133336.ZIP
我在任务计划程序中运行它以便每晚运行。
我想避免在目录中包含太多的zip文件,所以我想保留最后30个zip文件。
我在这一点上陷入困境。如何保留最新的30个zip文件,这样我就不会收到大量的zip文件?
答案 0 :(得分:10)
这将列出从最新到最旧的.zip文件(按创建日期),跳过前30个文件。
for /f "skip=30 delims=" %%A in ('dir /a:-d /b /o:-d /t:c *.zip ^2^>nul') do if exist "%%~fA" echo "%%~fA"
如果您想要实际删除文件,只需将echo
更改为del
即可。的 :)
强>
答案 1 :(得分:3)
只关注问题 - 如何保留30个最新文件,并删除其余文件:
您可以使用正确的排序执行dir > clean.lst
,以便最新的文件位于clean.lst
的开头。然后,您可以使用for
命令跳过文件中的前30行,并删除第30个文件后列出的文件。
考虑这个测试用例:
C:>md xyz
C:>cd xyz
c:\xyz>copy con genfiles.bat
@echo off
set _i=1
:loop
if %_i%==100 goto :EOF
echo.>%_i%.txt
set /a _i+=1
goto loop
^Z
1 file(s) copied.
c:\xyz>genfiles
c:\xyz>del genfiles.bat
现在XYZ文件夹中有99个文本文件。
您可以删除除最近30个之外的所有内容:
C:\xyz>dir /b /o-d *.txt > clean.lst
C:\xyz>for /f "skip=30 delims=" %i in (clean.lst) do del "%i"
C:\xyz>del clean.lst
dir
仅显示文本文件70.txt - 99.txt,其余文件已被删除。
对于您的批处理文件,我认为它看起来像这样:
cd /d %BKUPDIR%
dir /b /o-d *.zip > clean.lst
for /f "skip=30 delims=" %%i in (clean.lst) do del "%%i"
del clean.lst