Question

我的要求是从Jenkins构建服务器调用一些处理，以确定自上次构建以来域模型是否已更改。我得出的结论是，前进的方法是编写一个脚本，该脚本将从db-migration插件调用一系列现有脚本。然后我可以在调用test-app和war的步骤中调用它。

我查看了Grails文档，以及一些db-migration脚本，我发现自己被卡住了 - 不知道从哪里开始尝试。如果有人能指出我在任何合适的来源，我真的很感激。顺便说一句，我在Grails中有点生疏。两年前通过概念证明项目开始自学，历时6个月。然后它回到Eclipse富客户端工作。这可能是我问题的一部分，尽管我从不参与剧本。

我在Jenkins evt中需要的一件事是获取用于构建的当前SVN修订号。建议欢迎。

问候，约翰

Answer 1

运行grails create-script scriptname创建新脚本。数据库迁移插件脚本配置为易于重用。 _DatabaseMigrationCommon.groovy中有很多共享代码，每个脚本定义一个具有唯一名称的目标。因此，您可以导入共享脚本或任何独立脚本（或多个脚本），并调用目标，就像它们是方法一样。

默认情况下，create-script生成的脚本会通过_GrailsInit“导入”includeTargets << grailsScript("_GrailsInit")脚本，您也可以这样做，利用指向已安装插件目录的魔术变量：

includeTargets << new File("$databaseMigrationPluginDir/scripts/DbmGenerateChangelog.groovy")

如果你这样做，你可以删除_GrailsInit的包含，因为它已经包含在内，但是如果你没有那么好，因为Grails只包含一次文件。

然后，您可以定义目标并调用任何插件的目标。目标不能接受参数，但您可以将数据添加到argsMap（这是Grails从解析的命令行参数创建的映射）以模拟用户指定的args。请注意，数据库迁移插件的脚本会看到传递给您脚本的任何args，因为它们使用相同的argsMap。

这是一个示例脚本，与dbm-generate-changelog完全相同，但添加了前后消息：

includeTargets << new File("$databaseMigrationPluginDir/scripts/DbmGenerateChangelog.groovy")

target(foo: "Just calls dbmGenerateChangelog") {
   println 'before'
   dbmGenerateChangelog()
   println 'after'
}

setDefaultTarget foo

请注意，我已将目标从main重命名为foo，因此它是唯一的，以防您想从其他脚本调用此目标。

作为使用args的示例，这是一个修改后的版本，如果没有提供，则指定默认的更改日志名称：

println 'before'
if (!argsMap.params) {
   argsMap.params = ['foo2.groovy']
}
dbmGenerateChangelog()
println 'after'

编辑：这是一个更全面的示例，它将dbm-gorm-diff的输出捕获到字符串：

includeTargets << new File("$databaseMigrationPluginDir/scripts/_DatabaseMigrationCommon.groovy")

target(foo: "foo") {
   depends dbmInit

   def configuredSchema = config.grails.plugin.databasemigration.schema
   String argSchema = argsMap.schema
   String effectiveSchema = argSchema ?: configuredSchema ?: defaultSchema

   def realDatabase
   boolean add = false // booleanArg('add')
   String filename = null // argsList[0]

   try {
      printMessage "Starting $hyphenatedScriptName"

      ByteArrayOutputStream baos = new ByteArrayOutputStream()
      def baosOut = new PrintStream(baos)

      ScriptUtils.executeAndWrite filename, add, dsName, { PrintStream out ->
         MigrationUtils.executeInSession(dsName) {
            realDatabase = MigrationUtils.getDatabase(effectiveSchema, dsName)
            def gormDatabase = ScriptUtils.createGormDatabase(dataSourceSuffix, config, appCtx, realDatabase, effectiveSchema)
            ScriptUtils.createAndPrintFixedDiff(gormDatabase, realDatabase, realDatabase, appCtx, diffTypes, baosOut)
         }
      }

      String xml = new String(baos.toString('UTF-8'))
      def ChangelogXml2Groovy = classLoader.loadClass('grails.plugin.databasemigration.ChangelogXml2Groovy')
      String groovy = ChangelogXml2Groovy.convert(xml)

      // do something with the groovy or xml here

      printMessage "Finished $hyphenatedScriptName"
   }
   catch (e) {
      ScriptUtils.printStackTrace e
      exit 1
   }
   finally {
      ScriptUtils.closeConnection realDatabase
   }
}

setDefaultTarget foo

grails：编写脚本的指导，esp用于调用现有的数据库迁移脚本

1 个答案: