Question

我有这个xml文档：

<tags>
<w lemme="déclaration" pos="NOM">Déclaration</w>
<w lemme="du" pos="PRP:det">des</w>
<w lemme="droit" pos="NOM">droits</w>
<w lemme="de" pos="PRP">de</w>
<w lemme="le" pos="DET:ART">l'</w>
<w lemme="homme" pos="NOM">homme</w>
<w lemme="et" pos="KON">et</w>
<w lemme="," pos="PUN">,</w>
...
</tags>

我正在尝试使用xsl过滤掉文章和标点符号。喜欢这里＆lt; w lemme =“，”pos =“PUN”＆gt;，＆lt; / w＆gt;和＆lt; w lemme =“de”pos =“PRP”＆gt; de＆lt; /并且R w ＆LT; w lemme =“le”pos =“DET：ART”＆gt; l'＆lt; / w的取代。所以我制作了以下样式表，但是将我的所有条件概括为所有标签，包括标签＆lt;标签取代。

<xsl:template match="*">
<xsl:choose>
<xsl:when test="contains(@pos,'PUN')"></xsl:when>
<xsl:when test="contains(@pos,'PRP')"></xsl:when>
<xsl:when test="contains(@pos,'DET')"></xsl:when>
<xsl:otherwise>
<xsl:copy>
<xsl:attribute name="lemme">
<xsl:value-of select="@lemme"/>
</xsl:attribute>
<xsl:attribute name="pos">
<xsl:value-of select="@pos"/>
</xsl:attribute>
<xsl:apply-templates/>
</xsl:copy>
</xsl:otherwise>
</xsl:choose>
</xsl:template>

我有这个结果：

<tags lemme="" pos="">
<w lemme="déclaration" pos="NOM">Déclaration</w>
<w lemme="droit" pos="NOM">droits</w>
<w lemme="homme" pos="NOM">homme</w>
<w lemme="et" pos="KON">et</w>
<w lemme="citoyen" pos="NOM">citoyen</w>

所以它有效并且只向我显示我感兴趣的行，只是我不希望它在＆lt;中添加lemme =“”pos =“”。标签＆gt;标记在第一行。我应该在xsl中更改什么才能使其仅使用＆lt; w>标签。我试过＆lt; xsl：template match =“w”＆gt;但它没有产生有效的xml。请帮忙吗？

Answer 1

您应该使用标准身份转换，即此模板：

<xsl:template match="node()|@*">
  <xsl:copy>
    <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
</xsl:template>

您始终可以使用它来复制从源到输出的所有内容。例外由额外的模板处理，如下所示：

<xsl:template match="w[contains(@pos,'PUN')]
                    |w[contains(@pos,'PRP')]
                    |w[contains(@pos,'DET')]"/>

什么也没做。它只是匹配不需要的元素，并阻止身份转换模板匹配和复制它们。完整的样式表如下所示：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0">
  <xsl:template match="node()|@*">
    <xsl:copy>
      <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="w[contains(@pos,'PUN')]
                      |w[contains(@pos,'PRP')]
                      |w[contains(@pos,'DET')]"/>
</xsl:stylesheet>

Answer 2

有几种方法可以解决这个问题，但是增加已有内容的一种方法是让一个规则匹配并输出tags-element，然后应用仅匹配w元素的第二个模板

首先，在您拥有的模板之前添加此模板：

<xsl:template match="/tags">
<xsl:copy>
<xsl:apply-templates select="w"/>
</xsl:copy>
</xsl:template>

对于第二位，将当前模板更改为：

<xsl:template match="w">

为清楚起见，这是完整的样式表：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" encoding="utf-8" indent="yes"/>

    <xsl:template match="/tags">
        <xsl:copy>
            <xsl:apply-templates select="w"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="w">
        <xsl:choose>
            <xsl:when test="contains(@pos,'PUN')"></xsl:when>
            <xsl:when test="contains(@pos,'PRP')"></xsl:when>
            <xsl:when test="contains(@pos,'DET')"></xsl:when>
            <xsl:otherwise>
                <xsl:copy>
                    <xsl:attribute name="lemme">
                        <xsl:value-of select="@lemme"/>
                    </xsl:attribute>
                    <xsl:attribute name="pos">
                        <xsl:value-of select="@pos"/>
                    </xsl:attribute>
                    <xsl:apply-templates/>
                </xsl:copy>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

</xsl:stylesheet>

这产生了预期的结果：

<?xml version="1.0" encoding="utf-8"?>
<tags>
    <w lemme="déclaration" pos="NOM">Déclaration</w>
    <w lemme="droit" pos="NOM">droits</w>
    <w lemme="homme" pos="NOM">homme</w>
    <w lemme="et" pos="KON">et</w>
</tags>

希望这有帮助。

XSL消除元素

2 个答案: