Question

我喜欢使用Google Docs function = importxml（）但是很想知道Excel 2010中是否有类似内容？我似乎无法找到一种方法让程序自动从链接的XML文件中提取数据。

例如，我希望能够设置标题为“项目名称”的列，然后让下一列将用户输入的项目名称附加到此网址的上一列

http://util.eveuniversity.org/xml/itemLookup.php?name=

然后解析生成的XML文件以返回类型ID。这是使用

在谷歌文档中完成的

=importxml(concatenate("http://util.eveuniversity.org/xml/itemLookup.php?name=",A3);"//itemLookup/typeID")

A3是具有项目名称的列，在本例中为Tritanium，并从生成的XML文件中导入数据

http://util.eveuniversity.org/xml/itemLookup.php?name=Tritanium

返回值34。

我有一个大约20个项目名称的列表，每次打开文件时，Google文档都会自动更新项目ID。 Excel 2010有没有办法复制此功能？

谢谢！

威尔

Answer 1

问题是从2013年开始，过了一段时间......

使用Excel 2013，有一个函数WEBSERVICE来加载XML文档，这将完全符合您的要求。

还有FILTERXML使用XPath搜索加载的XML文档。

Answer 2

您需要编写自己的UDF。

一种方法是使用MSXML2库，如下所示：

Function GetData(sName As String, sItem As String, Optional sURL = "") As Variant
    Dim oHttp As New MSXML2.XMLHTTP60
    Dim xmlResp As MSXML2.DOMDocument60
    Dim result As Variant
    On Error GoTo EH

    If sURL = "" Then
        sURL = "http://util.eveuniversity.org/xml/itemLookup.php?name="
    End If

    'open the request and send it
    oHttp.Open "GET", sURL & sName, False
    oHttp.Send

    'get the response as xml
    Set xmlResp = oHttp.responseXML
    ' get Item
    GetData = xmlResp.getElementsByTagName(sItem).Item(0).Text

    ' Examine output of these in the Immediate window
    Debug.Print sName
    Debug.Print xmlResp.XML

CleanUp:
    On Error Resume Next
    Set xmlResp = Nothing
    Set oHttp = Nothing
Exit Function
EH:
    GetData = CVErr(xlErrValue)
    GoTo CleanUp
End Function

这样称呼它（A5包含所需的typeName）

=GetData(A5, "typeID")

Answer 3

Function ImportXML(url As String, query As String)

    Dim document    As MSXML2.DOMDocument60
    Dim http        As New MSXML2.XMLHTTP60

    http.Open "GET", url, False
    http.send

    Set document = http.responseXML

    ImportXML = document.SelectSingleNode(query).nodeTypedValue

End Function

Answer 4

“数据”菜单上的“从网络”功能会将在线数据直接提取到电子表格中。 XML数据导入也可以在From Other Sources子菜单下找到，该子菜单也列在数据菜单上。

通过“数据”菜单上的“连接”对话框管理创建的连接。

创建“来自网络”连接时使用记录宏的示例代码：

Sub Macro1()
' Macro1 Macro
With ActiveSheet.QueryTables.Add(Connection:= _
        "URL;http://en.wikipedia.org/wiki/Microsoft_Excel" _
        , Destination:=Range("$A$1"))
        .Name = _
        "?affID=110195&tt=270912_7a_3912_6&babsrc=HP_ss&mntrId=3e2fc48700000000000088532eb428ec"
        .FieldNames = True
        .RowNumbers = False
        .FillAdjacentFormulas = False
        .PreserveFormatting = True
        .RefreshOnFileOpen = False
        .BackgroundQuery = True
        .RefreshStyle = xlInsertDeleteCells
        .SavePassword = False
        .SaveData = True
        .AdjustColumnWidth = True
        .RefreshPeriod = 0
        .WebSelectionType = xlEntirePage
        .WebFormatting = xlWebFormattingNone
        .WebPreFormattedTextToColumns = True
        .WebConsecutiveDelimitersAsOne = True
        .WebSingleBlockTextImport = False
        .WebDisableDateRecognition = False
        .WebDisableRedirections = False
        .Refresh BackgroundQuery:=False
    End With
End Sub

功能类似于Excel中的importxml？

4 个答案: