Question

我有一组看起来像这样的数据

col1    col2    col3    col4
ABC1    DEF1    GHI1    cond1
ABC2    DEF2    GHI2    cond1-cond2
ABC3    DEF3    GHI3    cond2/cond1
ABC4    DEF4    GHI4    cond2 cond1
ABC5    DEF5    GHI5    cond4/cond1
ABC6    DEF6    GHI6    cond1
ABC7    DEF7    GHI7    mcond1
ABC8    DEF8    GHI8    cond2
ABC9    DEF9    GHI9    cond1 at 50
ABCa    DEFa    GHIa    con cond1
ABCb    DEFb    GHIb    no. cond1
ABCc    DEFc    GHIc    cond1 something
ABCc    DEFc    GHIc    Mcond1

我正在尝试编写一些命令来根据“col4”分离数据以获取：

包含字符串“cond1”的文件，除了“M”和“m”字母之外或之后的ANYTHING。我目前正在使用此命令（显然不排除M和m）：
```
awk 'BEGIN{IGNORECASE=1} $4 ~ /.cond1/ || $4 ~ /cond1./ ' /filepath.tab
```
请注意，第4行，第9行和第11行数据包含“cond1”和其他字符串之间的空格，我希望在文件中包含此内容。（命令中的“。”是否包含空格？）
我写了一个命令，只在“col4”中获取一个包含“cond1”的文件
```
awk 'BEGIN{IGNORECASE=1} $4 ~ /^cond1$/ '  /filepath.tab
```
它与大多数数据一起工作正常，但我在结果中得到了这两个错误：
```
ABC9    DEF9    GHI9    cond1 at 50
ABCc    DEFc    GHIc    cond1 something
```

任何人都可以帮我解决这两个命令吗？感谢。

我正在寻找3个不包含任何重复项的文件的输出，这是一个例子： File1（包含cond1的所有组合）：

col1    col2    col3    col4
ABC2    DEF2    GHI2    cond1-cond2
ABC3    DEF3    GHI3    cond2/cond1
ABC4    DEF4    GHI4    cond2 cond1
ABC5    DEF5    GHI5    cond4/cond1
ABC9    DEF9    GHI9    cond1 at 50
ABCa    DEFa    GHIa    con cond1
ABCb    DEFb    GHIb    no. cond1
ABCc    DEFc    GHIc    cond1 something

File2（仅包含cond1）：

col1    col2    col3    col4
ABC1    DEF1    GHI1    cond1
ABC6    DEF6    GHI6    cond1

File3（包含未包含在file1和file2中的任何内容）：

col1    col2    col3    col4
ABC7    DEF7    GHI7    mcond1
ABC8    DEF8    GHI8    cond2
ABCc    DEFc    GHIc    Mcond1

请注意，3个文件的总行数与原始文件的总行数相同如果这听起来相当复杂，我很抱歉，但实际情况就是如此。

Answer 1

问题是第4列中有空格而且您的文件未按预期格式化awk -F'\t' {print $4} file并注意到它可能不是您所期望的。

首先使用sed

以CSV格式打开文件

$ sed 's/\s\+/,/;s/\s\+/,/;s/\s\+/,/;' file
col1,col2,col3,col4
ABC1,DEF1,GHI1,cond1
ABC2,DEF2,GHI2,cond1-cond2
ABC3,DEF3,GHI3,cond2/cond1
ABC4,DEF4,GHI4,cond2 cond1
ABC5,DEF5,GHI5,cond4/cond1
ABC6,DEF6,GHI6,cond1
ABC7,DEF7,GHI7,mcond1
ABC8,DEF8,GHI8,cond2
ABC9,DEF9,GHI9,cond1 at 50
ABCa,DEFa,GHIa,con cond1
ABCb,DEFb,GHIb,no. cond1
ABCc,DEFc,GHIc,cond1 something
ABCc,DEFc,GHIc,Mcond1

这只会将前3个空格组转换为逗号，并根据需要保留col4。要将更改存储在文件中，请使用-i选项：

sed -i 's/\s\+/,/;s/\s\+/,/;s/\s\+/,/;' file

现在可以使用字段分隔符,。

awk 'BEGIN{FS=",";OFS="\t"} NR==1{print $1,$2,$3,$4} $4~/cond1./|| $4~/[^mM]cond1/{print $1,$2,$3,$4}' file
col1    col2    col3    col4
ABC2    DEF2    GHI2    cond1-cond2
ABC3    DEF3    GHI3    cond2/cond1
ABC4    DEF4    GHI4    cond2 cond1
ABC5    DEF5    GHI5    cond4/cond1
ABC9    DEF9    GHI9    cond1 at 50
ABCa    DEFa    GHIa    con cond1
ABCb    DEFb    GHIb    no. cond1
ABCc    DEFc    GHIc    cond1 something

$ awk 'BEGIN{FS=",";OFS="\t"} NR==1{print $1,$2,$3,$4} $4~/^cond1$/{print $1,$2,$3,$4}' file 
col1    col2    col3    col4
ABC1    DEF1    GHI1    cond1
ABC6    DEF6    GHI6    cond1

$ awk 'BEGIN{FS=",";OFS="\t"} $4!~/cond1/ || $4~/[Mm]cond1/{print $1,$2,$3,$4}' file
col1    col2    col3    col4
ABC7    DEF7    GHI7    mcond1
ABC8    DEF8    GHI8    cond2
ABCc    DEFc    GHIc    Mcond1

只需重定向即可保存新文件awk '{...}' > file1。

Answer 2

由于您的字段以制表符分隔，请使用FS="\t"块中的BEGIN。你的病情也不合适。所以我改变了它。

awk 'BEGIN{IGNORECASE=1; FS="\t"; } $4 ~ /cond1/ && $4 !~ /mcond1|cond1m/' data

Answer 3

您可以通过一次完成任务。像：

一样运行

awk -f script.awk file

script.awk的内容：

BEGIN {
    FS="\t"
}

NR==1 {
    r=$0
    next
}

{
    i = ($4 == "cond1" ? 2 : ($4 ~ /cond1/ && $4 !~ /[Mm]cond1/ ? 1 : 3))
    print (!a[i]++ ? r ORS : "") $0 > "file" i ".txt"
}

grep . file[1-3].txt的结果：

file1.txt:col1  col2    col3    col4
file1.txt:ABC2  DEF2    GHI2    cond1-cond2
file1.txt:ABC3  DEF3    GHI3    cond2/cond1
file1.txt:ABC4  DEF4    GHI4    cond2 cond1
file1.txt:ABC5  DEF5    GHI5    cond4/cond1
file1.txt:ABC9  DEF9    GHI9    cond1 at 50
file1.txt:ABCa  DEFa    GHIa    con cond1
file1.txt:ABCb  DEFb    GHIb    no. cond1
file1.txt:ABCc  DEFc    GHIc    cond1 something
file2.txt:col1  col2    col3    col4
file2.txt:ABC1  DEF1    GHI1    cond1
file2.txt:ABC6  DEF6    GHI6    cond1
file3.txt:col1  col2    col3    col4
file3.txt:ABC7  DEF7    GHI7    mcond1
file3.txt:ABC8  DEF8    GHI8    cond2
file3.txt:ABCc  DEFc    GHIc    Mcond1

或者，这是单行：

awk -F "\t" 'NR==1 { r=$0; next } { i = ($4 == "cond1" ? 2 : ($4 ~ /cond1/ && $4 !~ /[Mm]cond1/ ? 1 : 3)); print (!a[i]++ ? r ORS : "") $0 > "file" i ".txt" }' file

用awk搜索多个条件字符串

3 个答案: