Question

是否可以检查我在同一模板中与模板匹配的节点类型？如果是的话，我该怎么办？例如，我想做这样的事情：

<xsl:template match="@*|node()">
    <xsl:choose>
        <xsl:when test="current() is an attribute">
        <!-- ... -->
        </xsl:when>
        <xsl:when test="current() is an element">
        <!-- ... -->
        </xsl:when>
        <xsl:otherwise>
        <!-- ... -->
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

Answer 1

请在此处查看此答案，因为这可以为您提供所需的信息：

Difference between: child::node() and child::*

这提供了以下 xsl：choose 来测试所有节点，包括文档节点。

<xsl:choose>
  <xsl:when test="count(.|/)=1">
    <xsl:text>Root</xsl:text>
  </xsl:when>
  <xsl:when test="self::*">
    <xsl:text>Element </xsl:text>
    <xsl:value-of select="name()"/>
  </xsl:when>
  <xsl:when test="self::text()">
    <xsl:text>Text</xsl:text>
  </xsl:when>
  <xsl:when test="self::comment()">
    <xsl:text>Comment</xsl:text>
  </xsl:when>
  <xsl:when test="self::processing-instruction()">
    <xsl:text>PI</xsl:text>
  </xsl:when>
  <xsl:when test="count(.|../@*)=count(../@*)">
    <xsl:text>Attribute</xsl:text>
  </xsl:when>
</xsl:choose>

Answer 2

确定节点$node是根节点的更精确方法：

not(count($node/ancestor::node()))

TimC的答案中的表达式测试当前节点的类型：

count(.|/)=1

但不适用于我们想要确定变量中节点类型的情况 - 可能属于另一个文档 - 而不是当前文档。

此外，还测试了命名空间节点：

count($node | $node/../namespace::*) = count($node/../namespace::*)

Answer 3

我强烈建议您使用expressions on sequence types introduced in XPath 2.0。例如：

. instance of document-node()
. instance of element()

检查XSL模板中的节点类型

3 个答案: