Question

由于gl_LightSource等内置制服现在在OpenGL规范的最新版本中被标记为已弃用，我目前正在实施一个基本的照明系统（现在点光源），它接收所有光线和材质信息通过自定义统一变量。

我已经为点光源实现了光衰减和镜面反射高光，除了位置毛刺外，它似乎工作得很好：我手动移动光线，改变它沿X轴的位置。然而，光源（通过它投射在它下面的方形平面上的光线来判断）似乎不是沿着X轴移动，而是沿着X轴和Z轴对角移动（可能也是Y，但它不是完全是一个定位错误。）

下面是失真看起来的截图（光线在-35,5,0，Suzanne ist在0,2,0： This is obviously distorted ：

当光线为0,5,0时看起来不错： This looks fine

根据OpenGL规范，所有默认光计算都在眼睛坐标中进行，这就是我在这里尝试模拟的（因此光位置与vMatrix相乘）。我只使用视图矩阵，因为将渲染的顶点批处理的模型转换应用到灯光中并没有多大意义。

如果重要，所有飞机的法线都指向正上方 - 0,1,0。

（注意：我现在修复了这个问题，感谢msell和myAces！以下片段是更正版本。现在还有一个选项可以将聚光灯参数添加到灯光中（d3d样式））

以下是我在顶点着色器中使用的代码：

#version 330

uniform mat4 mvpMatrix;
uniform mat4 mvMatrix;
uniform mat4 vMatrix;

uniform mat3 normalMatrix;
uniform vec3 vLightPosition;
uniform vec3 spotDirection;
uniform bool useTexture;

uniform bool    fogEnabled;
uniform float   minFogDistance;
uniform float   maxFogDistance;

in vec4 vVertex;
in vec3 vNormal;
in vec2 vTexCoord;

smooth out vec3     vVaryingNormal;
smooth out vec3     vVaryingLightDir;
smooth out vec2     vVaryingTexCoords;
smooth out float    fogFactor;

smooth out vec4     vertPos_ec;
smooth out vec4     lightPos_ec;
smooth out vec3     spotDirection_ec;

void main() {
    // Surface normal in eye coords
    vVaryingNormal = normalMatrix * vNormal;

    vec4 vPosition4 = mvMatrix * vVertex;
    vec3 vPosition3 = vPosition4.xyz / vPosition4.w;

    vec4 tLightPos4 = vMatrix * vec4(vLightPosition, 1.0);
    vec3 tLightPos  = tLightPos4.xyz / tLightPos4.w;

    // Diffuse light
    // Vector to light source (do NOT normalize this!)
    vVaryingLightDir = tLightPos - vPosition3;

    if(useTexture) {
        vVaryingTexCoords = vTexCoord;
    }

    lightPos_ec = vec4(tLightPos, 1.0f);
    vertPos_ec = vec4(vPosition3, 1.0f);

    // Transform the light direction (for spotlights) 
    vec4 spotDirection_ec4 = vec4(spotDirection, 1.0f);
    spotDirection_ec = spotDirection_ec4.xyz / spotDirection_ec4.w; 
    spotDirection_ec = normalMatrix * spotDirection;

    // Projected vertex
    gl_Position = mvpMatrix * vVertex;

    // Fog factor
    if(fogEnabled) {
        float len = length(gl_Position);
        fogFactor = (len - minFogDistance) / (maxFogDistance - minFogDistance);
        fogFactor = clamp(fogFactor, 0, 1);
    }   
}

这是我在片段着色器中使用的代码：

#version 330

uniform vec4 globalAmbient;

// ADS shading model
uniform vec4 lightDiffuse;
uniform vec4 lightSpecular;
uniform float lightTheta;
uniform float lightPhi;
uniform float lightExponent;

uniform int shininess;
uniform vec4 matAmbient;
uniform vec4 matDiffuse;
uniform vec4 matSpecular;

// Cubic attenuation parameters
uniform float constantAt;
uniform float linearAt;
uniform float quadraticAt;
uniform float cubicAt;

// Texture stuff
uniform bool useTexture;
uniform sampler2D colorMap;

// Fog
uniform bool    fogEnabled;
uniform vec4    fogColor;

smooth in vec3  vVaryingNormal;
smooth in vec3  vVaryingLightDir;
smooth in vec2  vVaryingTexCoords;
smooth in float fogFactor;
smooth in vec4  vertPos_ec;
smooth in vec4  lightPos_ec;
smooth in vec3  spotDirection_ec;

out vec4 vFragColor;

// Cubic attenuation function
float att(float d) {
    float den = constantAt + d * linearAt + d * d * quadraticAt + d * d * d * cubicAt;

    if(den == 0.0f) {
        return 1.0f;
    }

    return min(1.0f, 1.0f / den);
}

float computeIntensity(in vec3 nNormal, in vec3 nLightDir) {

    float intensity = max(0.0f, dot(nNormal, nLightDir));
    float cos_outer_cone = lightTheta;
    float cos_inner_cone = lightPhi;
    float cos_inner_minus_outer = cos_inner_cone - cos_outer_cone;

    // If we are a point light
    if(lightTheta > 0.0f) {
        float cos_cur = dot(normalize(spotDirection_ec), -nLightDir);
        // d3d style smooth edge
        float spotEffect = clamp((cos_cur - cos_outer_cone) / 
                                cos_inner_minus_outer, 0.0, 1.0);
        spotEffect = pow(spotEffect, lightExponent);
        intensity *= spotEffect;
    }   

    float attenuation = att( length(lightPos_ec - vertPos_ec) );
    intensity *= attenuation;

    return intensity;
}

/**
 *  Phong per-pixel lighting shading model.
 *  Implements basic texture mapping and fog.
 */
void main() {       
    vec3 ct, cf;
    vec4 texel;
    float at, af;

    if(useTexture) {
        texel = texture2D(colorMap, vVaryingTexCoords); 
    } else {
        texel = vec4(1.0f);
    }

    ct = texel.rgb;
    at = texel.a;

    vec3 nNormal = normalize(vVaryingNormal);
    vec3 nLightDir = normalize(vVaryingLightDir);

    float intensity = computeIntensity(nNormal, nLightDir); 
    cf = matAmbient.rgb * globalAmbient.rgb + intensity * lightDiffuse.rgb * matDiffuse.rgb;    
    af = matAmbient.a * globalAmbient.a + lightDiffuse.a * matDiffuse.a;

    if(intensity > 0.0f) {
        // Specular light
        //  -   added *after* the texture color is multiplied so that
        //      we get a truly shiny result
        vec3 vReflection = normalize(reflect(-nLightDir, nNormal));
        float spec = max(0.0, dot(nNormal, vReflection));
        float fSpec = pow(spec, shininess) * lightSpecular.a;
        cf += intensity * vec3(fSpec) * lightSpecular.rgb * matSpecular.rgb;
    }

    // Color modulation
    vFragColor = vec4(ct * cf, at * af);

    // Add the fog to the mix
    if(fogEnabled) {
        vFragColor = mix(vFragColor, fogColor, fogFactor);
    }
}

什么算术错误可能导致这种失真？

编辑1：

我已更新着色器代码。现在正在片段着色器中计算衰减，因为它应该一直存在。但它目前已被禁用 - 该错误与衰减无关。当仅渲染光的衰减系数时（参见片段着色器的最后几行），计算衰减 right 。这意味着灯光位置正确地转换为眼睛坐标，因此它不能成为错误的来源。

片段着色器的最后几行可以用于某些（略微hackish但仍然很有洞察力）的调试 - 看起来光的强度不是按照片段计算的，尽管我不知道为什么。

有趣的是，这个bug只能在（非常）大的四边形上看到，就像图像中的地板一样。它在小型号上并不明显。

编辑2：

我已将着色器代码更新为工作版本。现在一切都很好，我希望它可以帮助任何未来的用户阅读这个，因为截至今天，我还没有看到任何实现灯光的glsl教程，绝对没有固定的功能和秘密的隐式转换（例如gl_LightSource[i].*和对眼睛空间的隐式转换。）

我的代码根据BSD 2条款许可和can be found on GitHub许可！

Answer 1

我最近遇到了类似的问题，在使用大型多边形时，照明工作有些不对劲。问题是在顶点着色器中对眼睛矢量进行标准化，因为插值标准化值会产生不正确的结果。

更改

vVaryingLightDir = normalize( tLightPos - vPosition3 );

到

vVaryingLightDir = tLightPos - vPosition3;

在您的顶点着色器中

。您可以在片段着色器中保持规范化。

Answer 2

因为我注意到了：

vec3 tLightPos = (vMatrix * vec4(vLightPosition, 1.0)).xyz;

你只是在这里消除齐次坐标，而不是先将它分开。这会引起一些问题。

OpenGL可编程管道点光源

编辑1：

编辑2：

2 个答案: