Question

我正在使用Delphi 2007（没有Unicode支持），我正在从Google AnalyticsAPI中检索XML和JSON数据。下面是我为URL引用路径获得的一些UTF-8编码数据：

GA：referralPath = /添加/％D0％9F％D0％B8％D0％B6％D0％B0％D0％BC

当我使用this decoder对其进行解码时，它会正确生成：

GA：referralPath = /添加/Пижам

我可以在Delphi 2007中使用哪个函数来执行此解码吗？

更新该数据对应于URL。最终我想要做的是将它存储在SqlServer数据库中（开箱即用 - 没有针对字符集修改设置）。然后能够生成/创建一个带有此页面工作链接的html页面（注意：我只处理此示例中的url引用路径 - 显然要创建一个有效的url链接，需要一个源代码。）

Answer 1

D2007支持Unicode，只是达不到D2009 +的程度。 D2007中的Unicode使用WideString和少数存在的RTL支持函数来处理。

URL包含百分比编码的UTF-8字节八位字节。只需将这些序列转换为二进制表示，然后使用UTF8Decode()将UTF-8数据解码为WideString。例如：

function HexToBits(C: Char): Byte;
begin
  case C of
    '0'..'9': Result := Byte(Ord(C) - Ord('0'));
    'a'..'f': Result := Byte(10 + (Ord(C) - Ord('a')));
    'A'..'F': Result := Byte(10 + (Ord(C) - Ord('A')));
  else
    raise Exception.Create('Invalid encoding detected');
  end;
end;

var
  sURL: String;
  sWork: UTF8String;
  C: Char;
  B: Byte;
  wDecoded: WideString;
  I: Integer;
begin
  sURL := 'ga:referralPath=/add/%D0%9F%D0%B8%D0%B6%D0%B0%D0%BC';
  sWork := sURL;
  I := 1;
  while I <= Length(sWork) do
  begin
    if sWork[I] = '%' then
    begin
      if (I+2) > Length(sWork) then
        raise Exception.Create('Incomplete encoding detected');
      sWork[I] := Char((HexToBits(sWork[I+1]) shl 4) or HexToBits(sWork[I+2]));
      Delete(sWork, I+1, 2);
    end;
    Inc(I);
  end;
  wDecoded := UTF8Decode(sWork);
  ...
end;

Answer 2

您可以使用以下使用Windows API的代码：

function Utf8ToStr(const Source : string) : string;
var
  i, len : integer;
  TmpBuf : array of byte;
begin
  SetLength(Result, 0);
  i := MultiByteToWideChar(CP_UTF8, 0, @Source[1], Length(Source), nil, 0);
  if i = 0 then Exit;
  SetLength(TmpBuf, i * SizeOf(WCHAR));
  Len := MultiByteToWideChar(CP_UTF8, 0, @Source[1], Length(Source), @TmpBuf[0], i);
  if Len = 0 then Exit;

  i := WideCharToMultiByte(CP_ACP, 0, @TmpBuf[0], Len, nil, 0, nil, nil);
  if i = 0 then Exit;

  SetLength(Result, i);
  i := WideCharToMultiByte(CP_ACP, 0, @TmpBuf[0], Len, @Result[1], i, nil, nil);
  SetLength(Result, i);
end;

使用Delphi 2007解码UTF-8编码的西里尔文

2 个答案: