Question

在直接的XSLT 1.0中，不可能将字符串变量用作XPath表达式。

但是如果可能的表达式都很简单，比如“/ book / chapter / verse”或“/ year / make / model / style” - 只有子轴，只有元素节点，没有谓词 - 是否可以构建密钥，其中密钥字符串是该路径？像

这样的东西

<xsl:key name="elementByPath" match="*" use="path()" />

如果是这样，那么你可以

select=key(elementByPath, $var)

其中$ var可以是“/ book / chapter / verse”之类的字符串。

但直接XSLT 1.0没有path（）函数。 :(

使用

获取路径很容易

 <xsl:for-each select="ancestor-or-self::*">
      <xsl:text>/</xsl:text>
      <xsl:value-of select="name()"/>
 </xsl:for-each>

但是不能进入密钥的@use。：（

当可能的表达式（尽管很多）很简单时，是否有另一种方法可以通过变量XPath表达式选择元素？

Answer 1

可以做点什么：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:param name="pPath1" select="'/books/book/title'"/>
 <xsl:param name="pPath2" select="'/books/book/description'"/>

 <xsl:key name="kElemByPath" match="*"
  use="concat('/', name(ancestor-or-self::*[last()])
             ,'/', name(ancestor-or-self::*[last()-1])
             ,'/', name(ancestor-or-self::*[last()-2])
             )"/>

 <xsl:template match="/">
   <xsl:copy-of select="key('kElemByPath', $pPath1)"/>
==========&#xA;<xsl:text/>
   <xsl:copy-of select="key('kElemByPath', $pPath2)"/>
 </xsl:template>
</xsl:stylesheet>

对以下XML文档应用此转换时：

<books>
    <book isbn="1590593049">
        <title>Extending Flash MX 2004</title>
        <description>
        Using javascript alongwith actionscript 3.0 and mxml.</description>
    </book>
    <book isbn="0132149184">
        <title>Java Software Solutions</title>
        <description>
            Complete book full of case studies on business solutions and design concepts while building mission critical
            business applications.
        </description>
    </book>
</books>

产生了想要的正确结果：

<title>Extending Flash MX 2004</title>
<title>Java Software Solutions</title>
==========
<description>
        Using javascript alongwith actionscript 3.0 and mxml.</description>
<description>
            Complete book full of case studies on business solutions and design concepts while building mission critical
            business applications.
        </description>

如果您知道“路径”中的最大位置步数，则可以定义类似于此示例的键。位置步数较少的表达式必须以必要的斜杠数结束。

Answer 2

或者只是递归地解析字符串暴力：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
version="1.0">
<xsl:output omit-xml-declaration="yes" indent="yes"/>


<xsl:param name="pPath1" select="'books/book/title'"/>
<xsl:param name="pPath2" select="'books/book/description'"/>


<xsl:template match="/">
    <xsl:call-template name="elementsByPath">
        <xsl:with-param name="path" select="$pPath1" />
    </xsl:call-template>
    <xsl:text>==========&#xA;</xsl:text>
    <xsl:call-template name="elementsByPath">
        <xsl:with-param name="path" select="$pPath2" />
    </xsl:call-template>        
</xsl:template>


<xsl:template name="elementsByPath"> 
    <xsl:param name="path" />
    <xsl:choose>
        <xsl:when test="contains($path,'/')">
            <xsl:for-each select="*[name()=substring-before($path,'/')]"> 
                <xsl:call-template name="elementsByPath">
                    <xsl:with-param name="path" select="substring-after($path,'/')" />
                </xsl:call-template>
            </xsl:for-each>
        </xsl:when>
        <xsl:otherwise>
            <xsl:apply-templates select="*[name()=$path]" />
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

<xsl:template match="*">
    <xsl:copy-of select="." /><xsl:text>&#xA;</xsl:text>

</xsl:template>

</xsl:stylesheet>

当该转换应用于Dimitre的示例XML时，获得正确的结果：

<title>Extending Flash MX 2004</title>
<title>Java Software Solutions</title>
==========
<description>
        Using javascript alongwith actionscript 3.0 and mxml.
    </description>
<description>
        Complete book full of case studies on business solutions and design concepts while building mission critical
        business applications.
    </description>

我认为这样可行。。

伪造Xpath表达式中的变量

2 个答案: