Question

节点的高度是到最远叶节点的路径的长度。有点像node depth，但在另一个方向，虽然我不认为解决方案可以非常简单。

我对此没有任何实际用途：我最初认为我需要它的问题原来并不需要它。但是自从我在实现这个问题之前就写了一个解决方案之后，我想我会在这里发布它，以防万一将来会很方便。

Answer 1

使用：

if(node()) then max(.//node()[not(node())]/count(ancestor::node())) - count(ancestor::node()) else 0

为每个元素添加“height”属性的转换：

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> <xsl:output omit-xml-declaration="yes" indent="yes"/> <xsl:template match="node()|@*"> <xsl:copy> <xsl:apply-templates select="node()|@*"/> </xsl:copy> </xsl:template> <xsl:template match="*"> <xsl:copy> <xsl:apply-templates select="@*"/> <xsl:attribute name="height" select= "if(node()) then max(.//node()[not(node())]/count(ancestor::node())) - count(ancestor::node()) else 0 "/> <xsl:apply-templates/> </xsl:copy> </xsl:template> </xsl:stylesheet>

应用此转换时，例如在此XML文档上：

<producers> <producer> <id>8</id> <name>Emåmejeriet</name> <street>Grenvägen 1-3</street> <postal>577 39</postal> <city>Hultsfred</city> <weburl>http://www.emamejerie3t.se</weburl> <certified/> </producer> </producers>

产生了想要的正确结果：

<producers height="3"> <producer height="2"> <id height="1">8</id> <name height="1">Emåmejeriet</name> <street height="1">Grenvägen 1-3</street> <postal height="1">577 39</postal> <city height="1">Hultsfred</city> <weburl height="1">http://www.emamejerie3t.se</weburl> <certified height="0"/> </producer> </producers>

Answer 2

有什么问题

max(.//node()/count(ancestor::*)) - count(ancestor::*)

Answer 3

以下样式表将每个节点标记为height属性。

<?xml version="1.0"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:exsl="http://exslt.org/common"
                xmlns:math="http://exslt.org/math"
                extension-element-prefixes="math exsl"
                version="1.0">
  <xsl:output omit-xml-declaration="yes" indent="no"/>

  <xsl:template name="height">
    <xsl:param name="node"/>
    <xsl:choose>
      <xsl:when test="$node/node()">
        <xsl:variable name="child-heights">
          <xsl:for-each select="$node/node()">
            <height>
              <xsl:call-template name="height">
                <xsl:with-param name="node" select="."/>
              </xsl:call-template>
            </height>
          </xsl:for-each>
        </xsl:variable>

        <xsl:value-of select="math:max(exsl:node-set($child-heights)/height) + 1"/>
      </xsl:when>

      <xsl:otherwise>
        <xsl:value-of select="0"/>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

  <xsl:template match="*">
    <xsl:copy>
      <xsl:attribute name="height">
        <xsl:call-template name="height">
          <xsl:with-param name="node" select="."/>
        </xsl:call-template>
      </xsl:attribute>
      <xsl:apply-templates/>
    </xsl:copy>
  </xsl:template>
</xsl:stylesheet>

使用XSLT获取节点的高度

3 个答案: