Question

嗨我有这样的地图：

[this:0, is:1, a:2, file:3, anotherkey:4, aa:5]

我希望我能找到key给出地图的value。例如，如果给出了值5，我需要从地图返回aa。

这可能吗？

Answer 1

我不知道是否有直接的方法来获取给定值的密钥，但使用Map#find获取映射条目然后获取其值应该足够了：

def keyForValue(map, value) {
    map.find { it.value == value }?.key
}

def map = [a: 1, b: 2, c: 3]
assert keyForValue(map, 2) == 'b'
assert keyForValue(map, 42) == null

通常，地图不需要在其条目之间具有顺序关系，但Groovy的文字地图的默认实现是LinkedHashMap，有序，因此keyForValue将在使用这些地图时，总是会产生值的第一个键。

Answer 2

没有具体的命令。

幸运的是，如显示here，您可以轻松获取地图中特定值的键：

def myMap = [this:0, is:1, a:2, file:3, fix:4, aa:5]
def myValue = 5

你可以这样做：

def myKey = myMap.find{ it.value == myValue }?.key
// 'aa'

如果您想要所有按键，请执行以下操作：

def myMap = [this:0, is:1, a:2, file:3, fix:4, aa:5, bb:5]
def myValue = 5

def myKeys = []
myMap.findAll{ it.value == myValue }.each{myKeys << it?.key}
// ['aa', 'bb']

Answer 3

您可以反转地图，如下所示：

Map m = [a: '1', b: '2']
Map mInvert = m.collectEntries { e -> [(e.value): e.key] }

assert mInvert == ['1':'a', '2':'b']

assert mInvert['2'] == 'b'
assert m['b'] == '2'

Answer 4

您可能需要自己迭代entry set，并尝试找到匹配value的条目。

Answer 5

def expect = 5
def m = ['this':0, is:1, a:2, file:3,  aa:5]
def r = m.collectMany{ k,v -> (v == expect) ? [k] : []}

// Result: [aa]

给定值，在地图中查找关键字

5 个答案: