Question

尝试检查我想要阅读的文件是否存在。

Answer 1

以下是另一种方法：

使用BFILE包的fileexists和dbms_lob函数：

create or replace function FileExists(
   p_DirName in varchar2,     -- schema object name
   p_FileName in varchar2
 ) return number
is
  l_file_loc bfile;
begin
  l_file_loc := bfilename(upper(p_DirName), p_FileName);
  return dbms_lob.fileexists(l_file_loc);  -- 1 exists; 0 - not exists
end;

使用fgetattr包的utl_file函数：

create or replace function FileExists(
  p_DirName in varchar2,     -- schema object name
  p_FileName in varchar2
) return number
is
  l_fexists boolean;
  l_flen   number;
  l_bsize  number;
  l_res    number(1);
begin
  l_res := 0;
  utl_file.fgetattr(upper(p_DirName), p_FileName, l_fexists, l_flen, l_bsize);
  if l_fexists
  then
    l_res := 1;
  end if;  
  return l_res;
end;

Answer 2

创建一个检查文件是否存在的函数，只需尝试打开它并捕获任何异常（此示例函数取自AskTom）

CREATE OR REPLACE FUNCTION file_exists(p_fname IN VARCHAR2) RETURN BOOLEAN
AS
  l_file UTL_FILE.FILE_TYPE;
BEGIN
  l_file := UTL_FILE.FOPEN(SUBSTR( p_fname, 1, instr(p_fname,'/',-1) ),
                           SUBSTR( p_fname, instr( p_fname, '/', -1)+1 ), 'r' );   
  UTL_FILE.FCLOSE( l_file );
  RETURN TRUE;
EXCEPTION
  WHEN UTL_FILE.INVALID_PATH      THEN RETURN FALSE;
  WHEN UTL_FILE.INVALID_OPERATION THEN RETURN FALSE;
END;
/

然后你可以使用;

IF ( file_exists( 'MED_LIST_19_OCT_12.csv' ) )
...

检查文件是否存在？

2 个答案: