Question

我正在尝试在Prolog中编写一个程序来查找大小为N的拉丁方。

我现在有这个：

delete(X, [X|T], T).
delete(X, [H|T], [H|S]) :-
   delete(X, T, S).

permutation([], []).
permutation([H|T], R) :-
   permutation(T, X),
   delete(H, R, X).

latinSqaure([_]).
latinSquare([A,B|T], N) :-
   permutation(A,B),
   isSafe(A,B),
   latinSquare([B|T]).

isSafe([], []).
isSafe([H1|T1], [H2|T2]) :- 
   H1 =\= H2, 
   isSafe(T1, T2).

Answer 1

使用SWI-Prolog库：

:- module(latin_square, [latin_square/2]).
:- use_module(library(clpfd), [transpose/2]).

latin_square(N, S) :-
    numlist(1, N, Row),
    length(Rows, N),
    maplist(copy_term(Row), Rows),
    maplist(permutation, Rows, S),
    transpose(S, T),
    maplist(valid, T).

valid([X|T]) :-
    memberchk(X, T), !, fail.
valid([_|T]) :- valid(T).
valid([_]).

试验：

?- aggregate(count,S^latin_square(4,S),C).
C = 576.

编辑您的代码，一旦更正了删除拼写错误，它就是验证程序，而不是生成器，但是（如删除的评论中的ssBarBee所述），它的缺失就是缺失测试不相邻的行。这里是更正后的代码

delete(X, [X|T], T).
delete(X, [H|T], [H|S]) :-
    delete(X, T, S).

permutation([], []).
permutation([H|T], R):-
    permutation(T, X),
    delete(H, R, X).

latinSquare([_]).
latinSquare([A,B|T]) :-
    permutation(A,B),
    isSafe(A,B),
    latinSquare([B|T]).

isSafe([], []).
isSafe([H1|T1], [H2|T2]) :-
    H1 =\= H2,
    isSafe(T1, T2).

和一些测试

?- latinSquare([[1,2,3],[2,3,1],[3,2,1]]).
false.

?- latinSquare([[1,2,3],[2,3,1],[3,1,2]]).
true .

?- latinSquare([[1,2,3],[2,3,1],[1,2,3]]).
true .

注意上次测试是错误的，应该改为false。

Answer 2

与@CapelliC一样，我建议使用CLP（FD）约束，这些约束在所有严肃的Prolog系统中都可用。

事实上，考虑更普遍地使用约束，从约束传播中受益。

例如：

:- use_module(library(clpfd)).

latin_square(N, Rows, Vs) :-
        length(Rows, N),
        maplist(same_length(Rows), Rows),
        maplist(all_distinct, Rows),
        transpose(Rows, Cols),
        maplist(all_distinct, Cols),
        append(Rows, Vs),
        Vs ins 1..N.

示例，计算N = 4的所有解决方案：

?- findall(., (latin_square(4,_,Vs),labeling([ff],Vs)), Ls), length(Ls, L).
L = 576,
Ls = [...].

CLP（FD）版本比其他版本快得多。

请注意，最好使用labeling/2将核心关系与实际搜索分开。这使您可以快速看到核心关系也终止于较大的N：

?- latin_square(20, _, _), false.
false.

因此，我们直接看到这终止，因此这加上任何后续的labeling/2搜索都可以保证找到所有解决方案。

Answer 3

我有更好的解决方案，@ CapelliC代码需要很长时间才能获得N长度大于5的正方形。

:- use_module(library(clpfd)).

make_square(0,_,[]) :- !.
make_square(I,N,[Row|Rest]) :-
   length(Row,N),
   I1 is I - 1,
   make_square(I1,N,Rest).

 all_different_in_row([]) :- !.
 all_different_in_row([Row|Rest]) :-
    all_different(Row),
    all_different_in_row(Rest).


all_different_in_column(Square) :-
   transpose(Square,TSquare),
   all_different_in_row(TSquare).   

all_different_in_column1([[]|_]) :- !.
all_different_in_column1(Square) :-
   maplist(column,Square,Column,Rest),
   all_different(Column),
   all_different_in_column1(Rest).


   latin_square(N,Square) :-
   make_square(N,N,Square),
   append(Square,AllVars),
   AllVars ins 1..N,
   all_different_in_row(Square),
   all_different_in_column(Square),
   labeling([ff],AllVars).

Prolog - 拉丁方解决方案

3 个答案: