Question

我是xslt的新手，经过多次尝试后无法解决以下问题。

我有一个xml数据文件，其中包含我无法更改的数据。例如下面的简单xml文件：

<?xml version="1.0" encoding="UTF-8"?>
<sales>
    <sale>
        <year>2012</year>
        <amount>200</amount>
    </sale>
    <sale>
        <year>2012</year>
        <amount>180</amount>
    </sale>
    <sale>
        <year>2010</year>
        <amount>120</amount>
    </sale>
</sales>

我想按年度对销售数据进行分组并将金额相加，这样我就可以获得每年的总金额。

2012年和2010年有数据，但xml文件中没有2011年的数据。

我希望我的输出在2011年的数字为0，所以我有2010,2011和2012年所有年份的输出。

我实际上将使用xls来生成图形，但在这个简单的示例中我使用html作为输出。我正在使用Altova XMLSpy来测试xls并查看生成的html文档。

以下是我编写的简单xls代码，用于分组并以HTML格式显示数据：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="/">
  <html>
  <body>
  <table border="1">
    <tr>
      <th>Year</th>
      <th>Amount</th>
    </tr>
    <xsl:for-each-group select="sales/sale" group-by="year">
      <xsl:sort select="year"/>
      <tr>
        <td><xsl:value-of select="year"/></td>
        <td><xsl:value-of select="sum(current-group()/amount)"/></td>
      </tr>
    </xsl:for-each-group>
  </table>
  </body>
  </html>
</xsl:template>

</xsl:stylesheet>

当我使用Altova XMLSpy对xml文件运行时，我在浏览器窗口中得到以下内容。一个包含3行的小表，带有标题的标题，然后是2行数据，一个用于2012，另一个用于2010.我不能使用图像作为新用户进行stackoverflow所以这里是可以查看的源html代码在浏览器中。

<html>
    <body>
        <table border="1">
            <tr>
                <th>Year</th>
                <th>Amount</th>
            </tr>
            <tr>
                <td>2010</td>
                <td>120</td>
            </tr>
            <tr>
                <td>2012</td>
                <td>380</td>
            </tr>
        </table>
    </body>
</html>

我可以使用xls为2011年创建一个数量为0的行，以便我的输出显示2010,2011和2012年范围内的数据吗？

请注意我不能硬编码xls中的年份，我必须得到那些缺少的。

通常我会确保源xml文件包含所有必需的数据，但在这种情况下它是不可能的。

感谢任何帮助。

亲切的问候

切尔

Answer 1

这是一个解决方案：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  exclude-result-prefixes="xs">

<xsl:output method="html" indent="yes"/>

<xsl:key name="sale-by-year" match="sale" use="xs:integer(year)"/>

<xsl:template match="/">
  <html>
  <body>
  <table border="1">
    <tr>
      <th>Year</th>
      <th>Amount</th>
    </tr>
    <xsl:variable name="doc" select="/"/>
    <xsl:for-each select="min(sales/sale/year/xs:integer(.)) to max(sales/sale/year/xs:integer(.))">
      <xsl:variable name="sales-of-year" select="key('sale-by-year', ., $doc)"/>
      <tr>
        <td>
          <xsl:value-of select="."/>
        </td>
        <td>
          <!--  <xsl:value-of select="if ($sales-of-year) then sum($sales-of-year/amount) else 0"/> -->
          <xsl:value-of select="sum($sales-of-year/amount)"/>
        </td>
       </tr>
     </xsl:for-each>

  </table>
  </body>
  </html>
</xsl:template>

</xsl:stylesheet>

Answer 2

<强>予。略短的XSLT 2.0 ：

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:xs="http://www.w3.org/2001/XMLSchema" exclude-result-prefixes="xs">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:key name="kSalesByYear" match="sale" use="year"/>
 <xsl:variable name="vDoc" select="/"/>

 <xsl:template match="/">
  <html>
    <body>
          <table border="1">
            <tr>
              <th>Year</th>
              <th>Amount</th>
            </tr>
        <xsl:for-each select=
         "min(/*/*/year/xs:integer(.)) to max(/*/*/year/xs:integer(.))">
         <tr>
           <td><xsl:sequence select="."/></td>
           <td><xsl:sequence select=
            "sum(key('kSalesByYear',string(.),$vDoc)/amount)"/></td>
         </tr>
        </xsl:for-each>
      </table>
    </body>
   </html>
 </xsl:template>
</xsl:stylesheet>

<强> II。 XSLT 1.0解决方案：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:key name="kSalesByYear" match="sale" use="year"/>
 <xsl:variable name="vDoc" select="/"/>

 <xsl:variable name="vMinMax">
  <xsl:for-each select="/*/*/year">
   <xsl:sort/>
   <xsl:if test="position()=1">
    <xsl:value-of select="."/>
   </xsl:if>
   <xsl:if test="position()=last()">
    <xsl:value-of select="concat('|',.)"/>
   </xsl:if>
  </xsl:for-each>
 </xsl:variable>

 <xsl:variable name="vMin" select="substring-before($vMinMax, '|')"/>
 <xsl:variable name="vMax" select="substring-after($vMinMax, '|')"/>

 <xsl:template match="/">
  <html>
    <body>
          <table border="1">
            <tr>
              <th>Year</th>
              <th>Amount</th>
            </tr>
        <xsl:for-each select=
         "(document('')//node()|document('')//@*|document('')//namespace::*)
           [not(position() > $vMax - $vMin +1)]
         ">
         <xsl:variable name="vYear" select="$vMin + position() -1"/>

         <xsl:for-each select="$vDoc">
             <tr>
               <td><xsl:value-of select="$vYear"/></td>
               <td><xsl:value-of select=
                "sum(key('kSalesByYear',$vYear)/amount)"/></td>
             </tr>
         </xsl:for-each>
        </xsl:for-each>
      </table>
    </body>
   </html>
 </xsl:template>
</xsl:stylesheet>

当以上两个转换中的任何一个应用于提供的XML文档时：

<sales>
    <sale>
        <year>2012</year>
        <amount>200</amount>
    </sale>
    <sale>
        <year>2012</year>
        <amount>180</amount>
    </sale>
    <sale>
        <year>2010</year>
        <amount>120</amount>
    </sale>
</sales>

产生了想要的正确结果：

<html>
   <body>
      <table border="1">
         <tr>
            <th>Year</th>
            <th>Amount</th>
         </tr>
         <tr>
            <td>2010</td>
            <td>120</td>
         </tr>
         <tr>
            <td>2011</td>
            <td>0</td>
         </tr>
         <tr>
            <td>2012</td>
            <td>380</td>
         </tr>
      </table>
   </body>
</html>

xslt - 当某些日期不在源xml中时，如何输出一系列日期的数据

2 个答案: