Question

我有一个xml：

<sitemapnode>
<node id="1"/>
<node id="2"/>
<node id="3"/>
<node id="4"/>
<node id="5"/>
<node id="6"/>
<node id="7"/>
<node id="8"/>
</sitemapnode>

我想将其转换为类似于的html。

<div>
 <ul>
   <li>1</li>
   <li>2</li>
   <li>3</li>
   <li>4</li>
 </ul>
</div>
<div>
 <ul>
   <li>5</li>
   <li>6</li>
   <li>7</li>
   <li>8</li>
 </ul>
</div>

如何遍历所有节点并分别为每一个节点提供div和uls？此外，如果节点的数量是奇数，则可以在上半部分节点数量减半之后完成上限。我从3天开始就在努力解决这个问题。并且还没有找到任何解决方案。请请帮助......

以下是实际代码：

<xsl:template match="/">
<div>
<!-- The menu starts here. -->
    <ul class="nav" id="main-nav">
        <!-- Looping the sitemap nodes. -->
        <xsl:for-each select="siteMap/siteMapNode/siteMapNode">
            <!-- checking if the node is visible on top nav or not. -->     
            <xsl:if test="@isVisibleInTopnav = 'true'">
                <!-- Creating the L1 navigation. -->
                <li class="drop">
                    <a class="top_link">
                        <xsl:attribute name="href">
                            <xsl:value-of select="@url"/>
                        </xsl:attribute>
                        <span>
                            <xsl:value-of select="@topNavTitle"/>
                        </span>                 
                    </a>
                    <!-- Creating the L2 navigation, L3 navigations..... -->
                    <div class="nav-sub">
                        <div class="inner">
                            <xsl:call-template name="nested_levels">    
                            </xsl:call-template>
                        </div>
                    </div>
                </li>
            </xsl:if>
        </xsl:for-each>
    </ul>
</div>

</xsl:template>

<xsl:template name="nested_levels">
    <xsl:param name="nodeCount" select="count(siteMapNode)"/>
    <xsl:variable name="columns" select="ceiling($nodeCount div 2)"/>
    <xsl:if test="count(siteMapNode) > 0">
                    <xsl:for-each select="siteMapNode">
                            <xsl:if test="ceiling((position() - 1) div $columns) = (position() - 1) div $columns">  
                                <div class="row mod">
                                    <xsl:apply-templates select="self::node|following-sibling::node[position() &lt; $columns]" mode="list" />
                                </div>
                            </xsl:if>
                    </xsl:for-each>     
    </xsl:if>
 </xsl:template>

 <xsl:template match="node" mode="list">
        <div>   <span class="h1">                       
                                    <a>
                                        <xsl:attribute name="href">
                                            <xsl:value-of select="@url"/>
                                        </xsl:attribute>
                                        <xsl:value-of select="@topNavTitle"/>                               
                                    </a>
                                        </span>


        </div>
 </xsl:template>

以下是示例xml：

<?xml version="1.0" encoding="utf-8"?>
<siteMap>
    <siteMapNode url="/" isVisibleInTopnav="" isVisibleInRightnav="" isVisibleInSitemap="" topNavTitle="" rightNavTitle="" hasBlueBackground="" showChildNav="" locatorKey="">
        <siteMapNode url="/a/" isVisibleInTopnav="true" isVisibleInRightnav="false" isVisibleInSitemap="true" topNavTitle="Personal Banking" rightNavTitle="" hasBlueBackground="false" showChildNav="false" locatorKey="">
            <siteMapNode url="/a/b/" isVisibleInTopnav="true" isVisibleInRightnav="true" isVisibleInSitemap="true" topNavTitle="Checking" rightNavTitle="Checking Accounts" hasBlueBackground="false" showChildNav="false" locatorKey="">
                <siteMapNode url="/a/b/c/" isVisibleInTopnav="true" isVisibleInRightnav="true" isVisibleInSitemap="false" topNavTitle="Checking Accounts" rightNavTitle="Compare Checking Accounts" hasBlueBackground="false" showChildNav="false" locatorKey="" />
            </siteMapNode>
        </siteMapNode>
    </siteMapNode>
</siteMap>

Answer 1

您不应该考虑迭代所有节点。你应该采取的方法是首先得到数字的一半，然后得到第1和第5（或任何一半）位置的节点。

首先获得创建变量的一半节点数

<xsl:variable name="number" select="ceiling(count(/*/node) div 2)" />

然后要获得相关的起始节点元素，您可以执行此操作

<xsl:apply-templates select="node[position() mod $number = 1]" />

然后，在此模板中，输出 ul 元素，然后输出当前元素和以下三个元素，如下所示：

<xsl:apply-templates 
     select="self::node|following-sibling::node[position() &lt; $number]" 
     mode="list" />

这将寻找两个节点的并集。 self :: node 将匹配当前节点， follow-sibling :: node [position（）＆lt; $ number] 匹配接下来的3个兄弟姐妹。请注意，在这种情况下，位置与当前元素相关。

请注意使用模式，否则您将有两个与节点元素匹配的模板，因此您需要一种方法来区分它们。如果没有模式元素以及该模式的其他模板， self :: node 匹配将导致无限递归。

这是完整的XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes"/>
    <xsl:variable name="number" select="ceiling(count(/*/node) div 2)" />

    <xsl:template match="/*">
        <div>
            <xsl:apply-templates select="node[position() mod $number = 1]" />
        </div>
    </xsl:template>

    <xsl:template match="node">
        <ul>
            <xsl:apply-templates select="self::node|following-sibling::node[position() &lt; $number]" mode="list" />
        </ul>
    </xsl:template>

    <xsl:template match="node" mode="list">
        <li><xsl:value-of select="@id" /></li>
    </xsl:template>
</xsl:stylesheet>

应用于XML时，输出以下内容

<div>
   <ul>
      <li>1</li>
      <li>2</li>
      <li>3</li>
      <li>4</li>
   </ul>
   <ul>
      <li>5</li>
      <li>6</li>
      <li>7</li>
      <li>8</li>
   </ul>
</div>

将每个半xml子节点添加到单独的div中

1 个答案: