Question

我有一个XSLT问题，这是我几周前提出的一个问题。

Extracting a class from the section attribute using xsl

这一次的挑战是为部分的第一页和最后一页提取单页数。上一个问题的XSLT解决方案由@Kirill Polishchuk提供。

我有一些使用concat的线索，如xslt: substring-before所示，但我无法使用密钥实现它。

请注意我正在使用XSLT 1.0。任何建议或指导都会非常感激。

谢谢JJ。

输入：

<root>
  <page number="1" section="Arsenal_Stadium">Arsenal_Stadium</page> 
  <page number="2" section="Arsenal_Stadium">Arsenal_Stadium</page> 
  <page number="3" section="Arsenal_Stadium">Arsenal_Stadium</page> 
  <page number="4" section="Arsenal_Stadium">Arsenal_Stadium</page> 
  <page number="5" section="Arsenal_Stadium">Arsenal_Stadium</page> 
  <page number="6" section="Arsenal_Stadium">Arsenal_Stadium</page> 
  <page number="7" section="Arsenal_Stadium">Arsenal_Stadium</page> 
  <page number="8,9" section="Arsenal_Crowds">Arsenal_Crowds</page> 
  <page number="8,9" section="Arsenal_Crowds">Arsenal_Crowds</page> 
  <page number="10" section="Arsenal_Crowds">Arsenal_Crowds</page> 
  <page number="11" section="Arsenal_Crowds">Arsenal_Crowds</page> 
  <page number="12" section="Arsenal_Crowds">Arsenal_Crowds</page> 
  <page number="13,14" section="Arsenal_Finances">Arsenal_Finances</page> 
  <page number="13,14" section="Arsenal_Finances">Arsenal_Finances</page> 
  <page number="15" section="Arsenal_Outlook">Arsenal_Outlook</page> 
  <page number="16" section="Arsenal_Outlook">Arsenal_Outlook</page> 
  <page number="17" section="Arsenal_Outlook">Arsenal_Outlook</page> 
  <page number="18" section="Arsenal_Outlook">Arsenal_Outlook</page> 
  <page number="19" section="Arsenal_Outlook">Arsenal_Outlook</page> 
 </root>

输出：

<table>
<tr>
<td class="Stadium">Arsenal_Stadium</td>
<td></td>
<td class="Crowds">Arsenal_Crowds</td>
<td></td>
<td class="Finances">Arsenal_Finances</td>
<td></td>
<td class="Outlook">Arsenal_Outlook</td>
<td></td>
</tr>
<tr>
<td>1</td>
<td>7</td>
<td>8</td>
<td>12</td>
<td>13</td>
<td>14</td>
<td>15</td>
<td>19</td>
</tr>
</table>

Answer 1

使用此模板：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" omit-xml-declaration="yes" indent="yes"/>

  <xsl:key name="k" match="page" use="@section"/>

  <xsl:template match="/root">
    <table>
      <tr>
        <xsl:apply-templates select="page[generate-id() = generate-id(key('k', @section))]"/>
      </tr>
      <tr>
        <xsl:apply-templates select="page[generate-id() = generate-id(key('k', @section))]" mode="page"/>
      </tr>
    </table>
  </xsl:template>

  <xsl:template match="page">
    <td class="{substring-after(@section, '_')}">
      <xsl:value-of select="."/>
    </td>
    <td></td>
  </xsl:template>

  <xsl:template match="page" mode="page">
    <td>
      <xsl:choose>
        <xsl:when test="contains(@number, ',')">
          <xsl:value-of select="substring-before(@number, ',')"/>
        </xsl:when>
        <xsl:otherwise>
          <xsl:value-of select="@number"/>
        </xsl:otherwise>
      </xsl:choose>
    </td>
    <td>
      <xsl:call-template name="get-last-number">
        <xsl:with-param name="pText" select="key('k', @section)[last()]/@number"/>
      </xsl:call-template>
    </td>
  </xsl:template>

  <xsl:template name="get-last-number">
    <xsl:param name="pText"/>

    <xsl:variable name="separator">,</xsl:variable>

    <xsl:choose>
      <xsl:when test="contains($pText, $separator)">
        <xsl:call-template name="get-last-number">
          <xsl:with-param name="pText" select="substring-after($pText, $separator)"/>
        </xsl:call-template>
      </xsl:when>
      <xsl:otherwise>
        <xsl:value-of select="$pText"/>
      </xsl:otherwise>
    </xsl:choose>

  </xsl:template>

</xsl:stylesheet>

它产生想要的结果：

<table>
  <tr>
    <td class="Stadium">Arsenal_Stadium</td>
    <td />
    <td class="Crowds">Arsenal_Crowds</td>
    <td />
    <td class="Finances">Arsenal_Finances</td>
    <td />
    <td class="Outlook">Arsenal_Outlook</td>
    <td />
  </tr>
  <tr>
    <td>1</td>
    <td>7</td>
    <td>8</td>
    <td>12</td>
    <td>13</td>
    <td>14</td>
    <td>15</td>
    <td>19</td>
  </tr>
</table>

XSLT提取：逗号前后的单页码

1 个答案: