Question

我正在尝试创建一个批处理文件来读取Microsoft Access .ldb锁定文件。锁定文件包含计算机名称和用户名列表。我想提取计算机名称，并最终针对外部命令运行它们。

批处理文件的格式是单行（1）计算机名称（2）NULL字符（Hex 00）（3）约20个空格（4）用户名（5）一个NULL字符（6）约20个空格重复。

Notepad ++中的示例，其中(NUL)表示Hex 00：

COMPUTER0123(NUL)                     Admin(NUL)                     COMPUTER0507(NUL)                     Admin(NUL)

我尝试了几种使用FOR来读取文件但无法通过第一个计算机名称的方法。

setlocal EnableDelayedExpansion
set file=database.ldb

for /F %%a in ('type %file%') do (
    echo %%a
    )

对于大多数Access数据库，文件中的用户名为Admin。我已经能够使用FIND告诉我文件中出现了多少次“管理员”（加1）。

for /f "delims=" %%n in ('find /c /v "Admin" %file%') do set "len=%%n"
set "len=!len:*:=!"
echo %len% (minus 1) computer names to process 
<%file% (
  for /l %%l in (1 1 !len!) do (  
    set "line="
    set /p "line="
    echo(!line!)    
    )
)

迭代找到的行不起作用，可能是因为文件中只有一行（没有回车）。

我想找到一个适用于标准安装Windows XP的解决方案。

收到接受的答案后，我将其合并到我在下面发布的批处理文件中。我将文件命名为ShowUsersInLDB.bat并将其放在我的 SendTo 文件夹中。

@echo off
::===================================================================
:: Put this in your SendTo folder and it will let you right-click 
:: on an Access .ldb/.laccdb lock file and tell you the computer
:: names that have opened the database.  
::
:: After the computer names are shown, this will prompt you to 
:: search for the user names associated with each computer.  This
:: depends upon finding a 3rd party file named NetUsers.exe in
:: the user profile folder.  Feel free to change the path if you
:: want to store the file in another location.
:: 
:: NetUsers.exe can be downloaded from here:  http://www.optimumx.com/downloads.html#NetUsers
::
:: Notes:
:: 1) Keep in mind that sometimes after people leave the database 
:: the lock file still shows their computer name.  Don't jump
:: to conclusions.
:: 2) NetUsers.exe seems to report all users who have logged on
:: to the computer and not logged off, including services.  
:: If you aren't familiar with your user names or your users are
:: sharing remote desktops/Citrix/Terminal Services, you may have 
:: to guess who might have created the lock entry. 
::
:: Installation:
:: You may find a batch file named Install_UsersInLDB.bat that will 
:: copy this file to the SendTo folder and the NetUsers.exe file to 
:: the user profile (or a place you define).
::
:: Ben Sacherich - March 2014
:: Please let me know if you have any ideas for improvements.
::===================================================================

setlocal
set file="%1"

:: Make sure the file has a compatible extension.
if  "%~x1"==".ldb"    goto :ExtensionIsValid
if  "%~x1"==".laccdb" goto :ExtensionIsValid

echo.
echo "%~n1%~x1" is not the correct file type.
echo.
pause
goto :End

:ExtensionIsValid
echo The Access "%~n1%~x1" file contains
echo the following computer names:
echo.
set "compNameLine=1"
for /f %%A in ('more "%file%"') do (
  if defined compNameLine (
    echo %%A
    set "compNameLine="
  ) else set "compNameLine=1"
)

echo.
echo Are you ready to look up the user names on each computer?
pause

set "compNameLine=1"
for /f %%A in ('more "%file%"') do (
  if defined compNameLine (
    ::echo %%A
    "%userprofile%\netusers" \\%%A
    set "compNameLine="
  ) else set "compNameLine=1"
)

echo.
echo -- Validation finished at %time%  
pause
:End
exit

Answer 1

CMD.EXE通常不能很好地与NUL字节一起使用。但是有一些外部命令可以处理NUL字节。

您还必须担心“线”的长度。 CMD.EXE不喜欢长度超过8191字节的行。

我认为你最好的选择是更多，因为它将NUL转换为新线。

以下内容应与您的计算机名称相呼应。

@echo off
setlocal
set "file=database.ldb"
set "compNameLine=1"
for /f %%A in ('more "%file%"') do (
  if defined compNameLine (
    echo %%A
    set "compNameLine="
  ) else set "compNameLine=1"
)

需要帮助编写批处理文件以读取带有空分隔符的MS Access .ldb锁定文件

1 个答案: