Question

我需要在画布上绘制一些线条，但是我需要使用自定义样式，没有标准样式作为实体，点，......

例如，我需要画一条线作为“__。__。_ ”或“。_。_。_。_”。我的所有行都是破折号和点的混合，我需要设置短划线和破折号，点宽。

我不想使用GDI +或其他外部库......

有一种简单的方法吗？

Answer 1

您可以使用普通GDI执行此操作：

procedure TForm1.FormPaint(Sender: TObject);
const
  pattern: array[0..3] of cardinal = (10, 1, 1, 1);
var
  lb: TLogBrush;
  pen, oldpen: HPEN;
begin
  lb.lbStyle := BS_SOLID;
  lb.lbColor := RGB(255, 0, 0);
  pen := ExtCreatePen(PS_COSMETIC or PS_USERSTYLE, 1, lb, length(pattern), @pattern);
  if pen <> 0 then
    try
      oldpen := SelectObject(Canvas.Handle, pen);
      Canvas.MoveTo(0, 0);
      Canvas.LineTo(ClientWidth, ClientHeight);
      SelectObject(Canvas.Handle, oldpen);
    finally
      DeleteObject(pen);
    end;
end;

Answer 2

您还可以使用LineDDA API。确定Pen造型（由Andreas Rejbrand提供建议）要快得多，但LineDDA允许您以不同的颜色绘制线条的部分。

var
  DottedLineDrawCounter: Integer;

procedure DDAProc(AX, AY: Integer; ACanvas: TCanvas); stdcall;
begin
  if DottedLineDrawCounter mod 4 = 0 then
    ACanvas.Pixels[AX, AY] := clRed
  else
    ACanvas.Pixels[AX, AY] := clBlack;
  Inc(DottedLineDrawCounter);
end;

...
begin
  // Usage
  DottedLineDrawCounter := 0;
  LineDDA(X1, Y1, X2, Y2, @DDAProc, LPARAM(Canvas));
end;

在画布上画一条自定义样式（delphi）

2 个答案: