Question

说我有以下文件

<block>
    <foo val="bar"/>
    <foo val="bar"/>
</block>
<block>
    <foo val="bar"/>
    <foo val="bar"/>
</block>

我怎么能把它变成

<block>
    <foo val="bar1"/>
    <foo val="bar"/>
</block>
<block>
    <foo val="bar1"/>
    <foo val="bar"/>
</block>

我尝试做的一件事是使用:%s/bar/bar1/gc录制一个宏，然后分别按y和n，然后尝试编辑该宏。由于某种原因，我无法编辑宏。：（

Answer 1

只是为了证明这可以通过替换来完成：

:let a = ['', '1']
:%s/bar\zs/\=reverse(a)[0]/g

概述

在每次替换后，数组在就地反转后，将每个bar的末尾替换为变量a中数组的第一个元素。

细节的荣耀

let a = ['', '1']定义一个变量a来保存我们的数组
%s/.../.../对文件中的每一行进行替换
%s/bar\zs/.../在栏上进行替换，但在使用\zs

\=

:s使用以下表达式的值
reverse(a)反向只是反转数组，但是就地执行
reverse(a)[0]反向返回现在反转的数组，因此得到第一个元素
/g替换行中的所有出现（可选）

一般案例

:let a = ['a', 'b', 'c']
:%s/bar\zs/\=add(a, remove(a, 0))[-1]/g

一般情况下，就地“旋转”数组a，并使用数组的最后位置作为替换替换的值。

如需更多帮助，请参阅

:h :s
:h range
:h /\zs
:h :s\=
:h reverse(
:h :s_flags
:h Lists
:h add(
:h remove

Answer 2

您可以使用

:%s/bar/bar1/gc

如果你想替换它，它会在每场比赛中问你。

否则你必须指定整个内容，并用bar1替换第一个栏。

Answer 3

我用宏来做：

qv            start recording in register v
/"bar"/e<cr>  search for "bar" and position the cursor at the end of the match
i1<esc>       insert 1 before the cursor and go back to normal mode
n             jump to next match
q             stop recording

之后，执行{count}@v。

Answer 4

试试这个：

:%s/bar\(.*\)\n\(.*\)bar/bar1\1\r\2bar

Answer 5

这是一个自定义命令应该可以解决问题。它使用替换表达式来计算已完成的替换，并使用传递的附加参数来决定是否应该替换。（这允许比每隔一个更复杂的安排。）你的例子将是一个简单的：

:%SubstituteSelected/\<bar\>/&1/ yn

这是（不幸的是很长）实施：

":[range]SubstituteSelected/{pattern}/{string}/[flags] {answers}
"           Replace matches of {pattern} in the current line /
"           [range] with {string}, determining whether a particular
"           match should be replaced on the sequence of "y" or "n"
"           in {answers}. I.e. with "ynn", the first match is
"           replaced, the second and third are not, the fourth is
"           again replaced, ...
"           Handles & and \0, \1 .. \9 in {string}.
function! CountedReplace()
    let l:index = s:SubstituteSelected.count % len(s:SubstituteSelected.answers)
    let s:SubstituteSelected.count += 1

    if s:SubstituteSelected.answers[l:index] ==# 'y'
        if s:SubstituteSelected.replacement =~# '^\\='
            " Handle sub-replace-special.
            return eval(s:SubstituteSelected.replacement[2:])
        else
            " Handle & and \0, \1 .. \9 (but not \u, \U, \n, etc.)
            let l:replacement = s:SubstituteSelected.replacement
            for l:submatch in range(0, 9)
                let l:replacement = substitute(l:replacement,
                \   '\%(\%(^\|[^\\]\)\%(\\\\\)*\\\)\@<!' .
                \       (l:submatch == 0 ?
                \           '\%(&\|\\'.l:submatch.'\)' :
                \           '\\' . l:submatch
                \       ),
                \   submatch(l:submatch), 'g'
                \)
            endfor
            return l:replacement
        endif
    elseif s:SubstituteSelected.answers[l:index] ==# 'n'
        return submatch(0)
    else
        throw 'ASSERT: Invalid answer: ' . string(s:SubstituteSelected.answers[l:index])
    endif
endfunction
function! s:SubstituteSelected( range, arguments )
    let l:matches = matchlist(a:arguments, '^\(\i\@!\S\)\(.*\)\%(\%(^\|[^\\]\)\%(\\\\\)*\\\)\@<!\1\(.*\)\%(\%(^\|[^\\]\)\%(\\\\\)*\\\)\@<!\1\(\S*\)\s\+\([yn]\+\)$')
    if empty(l:matches)
        echoerr 'Invalid arguments'
        return
    endif
    let s:SubstituteSelected = {'count': 0}
    let [l:separator, l:pattern, s:SubstituteSelected.replacement, l:flags, s:SubstituteSelected.answers] = l:matches[1:5]

    execute printf('%ssubstitute %s%s%s\=CountedReplace()%s%s',
    \   a:range, l:separator, l:pattern, l:separator, l:separator, l:flags
    \)
endfunction
command! -bar -range -nargs=1 SubstituteSelected call <SID>SubstituteSelected('<line1>,<line2>', <q-args>)

修改

我现在已将此（连同相关命令）发布为PatternsOnText plugin。

Answer 6

:let dosubs=1
:%s/bar/\=[dosubs?'bar1':submatch(0),extend(g:,{'dosubs':!dosubs})][0]/g

Answer 7

我找到了一个更简单的解决方案：

:g/<block>/norm! j02f"i1

:g ............ global command
/<block>/ ..... every line with <block>
j0 ............ goes down one line and to the column 1
2f" ........... jumps to the second "
i1 ............ insert the number one

我旧的复杂解决方案

\v%(block>\_{-})\zsbar
%s,,&1,g



   \v ............ very magic (avoid lots of scapes)
   %  ............ ignore whats flows
   (  ............ starts (ignored) group
   \_ ............ multiline search
   .{-} .......... non-greedy 
   \zs ........... start pattern for substituition
   bar  .......... pattern we want to change 

   % ............. whole file
   s ............. substituition
   ,, ............ use last search (could be //)
   & ............. use searched pattern 
   1 ............. add 1 after it

在Vim中，我如何搜索和替换其他所有匹配？

7 个答案:

概述

细节的荣耀

一般案例

修改