Question

我们正在开发一个基于时间事件处理的C ++服务器。例如，如果特定用户配置了必须在特定时间处理的特定任务，则需要从数据库向C ++服务器发送事件或通知，以启动任务。调整配置存储在数据库中，C ++服务器不应该间隔轮询数据库，但应在配置的调整时从数据库通知事件。

我们使用odatabase和odynaset库来连接和访问oracle数据库11g。

请您为上述问题提供解决方案。

Answer 1

一种方法是使用Oracle's Advanced Queuing。为此，您需要设置队列（和队列表）并编写等待队列中下一条消息的PL / SQL过程。

然后，C ++端调用PL / SQL过程，该过程在下一个事件发生时返回。

在Oracle方面，您需要使用DBMS_SCHEDULER或类似工具来创建事件，即在适当的时间将新消息插入队列。

这仍然是一种投票方式。但是，两个事件之间绝对没有活动。

<强>更新

以下是一些示例代码。

队列的初始设置（消息包含数字和文本值）：

grant AQ_ADMINISTRATOR_ROLE to appuser;
grant EXECUTE ON DBMS_AQ to appuser;
grant EXECUTE ON DBMS_AQ to appuser;


CREATE TYPE sample_payload_type AS OBJECT
(
  cmd  VARCHAR2(20),
  id   NUMBER
);


BEGIN
  DBMS_AQADM.CREATE_QUEUE_TABLE (
    queue_table        => 'sample_queue_table',
    queue_payload_type => 'sample_payload_type',
    sort_list          => 'ENQ_TIME',
    compatible         => '10.0'
  );
END;
/

BEGIN
  DBMS_AQADM.CREATE_QUEUE (
    queue_name         => 'sample_queue',
    queue_table        => 'sample_queue_table'
  );

  DBMS_AQADM.START_QUEUE (
    queue_name         => 'sample_queue'
  );
END;
/

包标题：

create or replace package sample_queue_pkg
as

  procedure get_next_msg(
    i_max_wait      number
   ,o_cmd      out  varchar2
   ,o_id       out  number
  );


  procedure put_msg(
    i_cmd           varchar2
   ,i_id            number
  );

end sample_queue_pkg;
/

包体：

create or replace package body sample_queue_pkg
as

  procedure get_next_msg(
    i_max_wait      number
   ,o_cmd      out  varchar2
   ,o_id       out  number
  )
  is
    dequeue_options dbms_aq.dequeue_options_t;
    message_properties dbms_aq.message_properties_t;
    message_handle RAW(16);
    message sample_payload_type;

    NO_MESSAGE_RECEIVED EXCEPTION;
    PRAGMA EXCEPTION_INIT(NO_MESSAGE_RECEIVED, -25228);

  begin
    dequeue_options.wait := i_max_wait;
    DBMS_AQ.DEQUEUE (
      queue_name => 'appuser.sample_queue',
      dequeue_options => dequeue_options,
      message_properties => message_properties,
      payload => message,
      msgid => message_handle
    );

    o_cmd := message.cmd;
    o_id := message.id;

  exception
    when NO_MESSAGE_RECEIVED then
      o_cmd := null;
      o_id := null;

  end get_next_msg;


  procedure put_msg(
    i_cmd           varchar2
   ,i_id            number
  )
  is
    enqueue_options dbms_aq.enqueue_options_t;
    message_properties dbms_aq.message_properties_t;
    message_handle RAW(16);
    message sample_payload_type;
    message_id NUMBER;

  begin
    message := sample_payload_type(i_cmd, i_id);
    DBMS_AQ.ENQUEUE(
      queue_name => 'appuser.sample_queue',
      enqueue_options => enqueue_options,
      message_properties => message_properties,
    payload => message,
      msgid => message_handle
    );
  end put_msg;

end sample_queue_pkg;
/

数据库服务器可以使用以下代码发送消息：

sample_queue_pkg.put_msg('run_task', 8234);
commit;

C ++服务器可以等待消息（并接收它们）来调用存储的sample_queue_pkg.get_next_msg。参数i_max_wait指定等待下一条消息的最长时间（以秒为单位）。您可能希望实现一个等待下一条消息的循环并对其进行处理，直到它收到服务器即将退出的信号为止。

Answer 2

一种方法是使用dbms_pipe或dbms_alert。即从C ++服务器会话连接到db（PRO C）并调用dbms_pipe / alert，它将阻塞，直到db，在另一个会话中向下发送数据，c ++服务器将读取然后进行处理。例如，如果它是一个简单的“现在跑！”你想发送，然后dbms_alert会这样做。

例如：

SQL> declare
  2    v_name  varchar2(200);
  3    v_msg   varchar2(200);
  4    v_sts   number; -- 0 = alert occured, 1 = timeout
  5  begin
  6    dbms_alert.register('RUN_PROGRAM_A');
  7    dbms_alert.register('RUN_PROGRAM_B');
  8
  9    loop
 10      dbms_alert.waitany(v_name,
 11                         v_msg,
 12                         v_sts,
 13                         dbms_alert.maxwait);
 14
 15      if (v_sts = 0)
 16      then
 17        dbms_output.put_line('i got alert: ' ||v_name);
 18        dbms_output.put_line(' with assoc message: ' ||v_msg);
 19      end if;
 20      if (v_name  = 'RUN_PROGRAM_B')
 21      then
 22        exit;
 23      end if;
 24    end loop;
 25  end;
 26  /
i got alert: RUN_PROGRAM_A
with assoc message: whatever you want to transmit.
i got alert: RUN_PROGRAM_A
with assoc message: whatever you want to transmit.
i got alert: RUN_PROGRAM_B
with assoc message: whatever you want to transmit.

PL/SQL procedure successfully completed.

db控制会话发出此信息：

SQL> exec dbms_alert.signal('RUN_PROGRAM_A', 'whatever you want to transmit.');

PL/SQL procedure successfully completed.

SQL> commit;

Commit complete.

SQL> exec dbms_alert.signal('RUN_PROGRAM_A', 'whatever you want to transmit.');

PL/SQL procedure successfully completed.

SQL> commit;

Commit complete.

SQL> exec dbms_alert.signal('RUN_PROGRAM_B', 'whatever you want to transmit.');

PL/SQL procedure successfully completed.

SQL> commit;

Commit complete.

SQL>

另一种方法是调度程序方法（dbms_queue），这是一种消息队列方法，您可以在其中对队列表进行轮询（出队），并在消息到达时执行某些操作。

如何获取C ++应用程序的数据库通知

2 个答案: