Question

如何正确发送数据包到UDP服务器？我正在尝试，但它没有工作，我没有从服务器收到任何东西。

我需要的是发送一个数据包：int64|int|int

从服务器接收数据包：int|int|int64

如何正确完成？感谢。

type
  Tconnecting = record
    a: int64;
    b: integer;
    c: integer;
  end;
  Treply_connect = record
    a: integer;
    b: integer;
    c: int64;
  end;

var 
  udp: TIdUDPClient;
  send_data: TIdBytes;
  received_data: TIdBytes;
  i: integer;
  packet: Tconnecting;
  reply_packet: Treply_connect;

begin
  packet.a := 41727101980;
  packet.b := 0;
  packet.c := RandomRange(1, 9999999);
  SetLength(send_data, sizeof(packet));
  Move(packet, send_data[0], sizeof(packet));
  udp := TIdUDPClient.Create(nil);
  try
    udp.Host := 'server.com';
    udp.Port := 1234;
    udp.SendBuffer(send_data);
    SetLength(received_data, 0);
    i := udp.ReceiveBuffer(received_data, 5000);
    Memo1.Lines.Add('Data reiceived! Len:'+IntToStr(Length(received_data))+',data:|'+BytesToString(received_data, 0)+'|');
  finally
    FreeAndNil(udp);
  end;

Answer 1

您没有正确使用ReceiveBuffer()。您将输出缓冲区的大小设置为0字节，因此ReceiveBuffer()将没有任何内存来读取接收到的数据。您需要将输出缓冲区预分配到您期望的最大大小。 ReceiveBuffer()的返回值将告诉您实际读入缓冲区的字节数。

换句话说，改变这个：

SetLength(received_data, 0);

对此：

SetLength(received_data, SizeOf(Treply_connect));

并改变这一点：

Memo1.Lines.Add('Data reiceived! Len:'+IntToStr(Length(received_data))+', data:|'+BytesToString(received_data, 0)+'|');

对此：

Memo1.Lines.Add('Data received! Len:'+IntToStr(i)+', data:|'+BytesToString(received_data, 0, i)+'|');

另外，Indy有一个RawToBytes()功能，可用于将数据包复制到TIdBytes：

send_data := RawToBytes(packet, SizeOf(packet));

还有BytesToRaw()函数，用于何时提取收到的数据包：

BytesToRaw(received_data, reply_packet, SizeOf(reply_packet));

IdUDPClient，如何将数据包发送到服务器？

1 个答案: