Question

我正在寻找一些正确编码的XSLT（用于Umbraco CMS）而且我有点难过。我想做的是：

从某个节点开始，将每个子节点放入div;对于每3个孩子，包裹在父母div。

而不是我的for-each，choose和when语句混乱，我尝试实现apply-template结构，但我似乎无法摆脱它;所以现在这是我的乱七八糟的XSLT（我确信这是不好的做法，而且性能很差，但我真的不知道该怎么做）：

<div class="row four">
<h2>Smart Phones <a href="#" class="see-all">see all smart phones &rarr;</a></h2>
<div class="row three"> <!-- This div should be created again for every 3 divs -->
        <xsl:for-each select="umbraco.library:GetXmlNodeById('1063')/descendant::*[@isDoc and string(showInMainNavigation) = '1']">
            <xsl:choose>
                <xsl:when test="position() &lt; 3">
                    <div class="col">
                        <a href="{umbraco.library:NiceUrl(./@id)}">
                            <img class="phonePreviewImg" src="{./previewImage}" style="max-width:117px; max-height:179px;" />
                            <h4 class="phoneTitle"><xsl:value-of select="./@nodeName" />/h4>
                            <p class="phonePrice">$<xsl:value-of select="./price" /></p
                        </a>
                     </div>
                 </xsl:when>

                 <xsl:when test="position() = 3"> <!-- set this div to include class of `omega` -->
                    <div class="col omega">
                        <a href="{umbraco.library:NiceUrl(./@id)}">
                            <img class="phonePreviewImg" src="{./previewImage}" style="max-width:117px; max-height:179px;" />
                            <h4 class="phoneTitle"><xsl:value-of select="./@nodeName" />/h4>
                            <p class="phonePrice">$<xsl:value-of select="./price" /></p
                        </a>
                     </div>
                 </xsl:when>                                                                                
             </xsl:choose>
         </xsl:for-each>
     </div> <!-- End Row Three -->
</div> <!-- End Row Four -->

显然这段代码不会产生“每三个换行”。任何人都可以阐明我需要做些什么来实现这个目标吗？

Answer 1

更新 - 改进了答案

我无法想到使用模板的优雅解决方案，但这个带有循环的笨重的工作方式：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:template name="render">
    <xsl:param name="node"/>
    <xsl:param name="last"/>
    <div>
      <xsl:if test="$last">
        <xsl:attribute name="class">
          <xsl:text>omega</xsl:text>
        </xsl:attribute>
      </xsl:if>
      <xsl:value-of select="$node"/>
    </div>
  </xsl:template>

  <xsl:template match="/*">
    <root>
      <xsl:variable name="nodes" select="*[not(@skip)]"/>
      <xsl:for-each select="$nodes">
        <xsl:if test="(position() mod 3)=1">
          <xsl:variable name="position" select="position()"/>
          <div>
            <xsl:call-template name="render">
              <xsl:with-param name="node" select="."/>
              <xsl:with-param name="last" select="false()"/>
            </xsl:call-template>
            <xsl:if test="$nodes[$position+1]">
              <xsl:call-template name="render">
                <xsl:with-param name="node" select="$nodes[$position+1]"/>
                <xsl:with-param name="last" select="false()"/>
              </xsl:call-template>
            </xsl:if>
            <xsl:if test="$nodes[$position+2]">
              <xsl:call-template name="render">
                <xsl:with-param name="node" select="$nodes[$position+2]"/>
                <xsl:with-param name="last" select="true()"/>
              </xsl:call-template>
            </xsl:if>
          </div>
        </xsl:if>
      </xsl:for-each>
    </root>
  </xsl:template>

</xsl:stylesheet>

适用于：

<root>
  <node>1</node>
  <node skip="1">to be skipped</node>
  <node>2</node>
  <node>3</node>
  <node skip="1">to be skipped</node>
  <node skip="1">to be skipped</node>
  <node>4</node>
  <node skip="1">to be skipped</node>
  <node>5</node>
  <node>6</node>
  <node>7</node>
  <node skip="1">to be skipped</node>
</root>

产生

<root>
  <div>
    <div>1</div>
    <div>2</div>
    <div class="omega">3</div>
  </div>
  <div>
    <div>4</div>
    <div>5</div>
    <div class="omega">6</div>
  </div>
  <div>
    <div>7</div>
  </div>
</root>

您需要将用于设置select变量的$nodes替换为选择所需节点的XPath，并将render模板替换为生成所需结果所需的代码每个节点。

Answer 2

简单明了：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="num[position() mod 3 = 1]">
   <div>
       <xsl:apply-templates mode="inGroup"
         select=".|following-sibling::*[not(position() >2)]"/>
   </div>
 </xsl:template>

 <xsl:template match="num" mode="inGroup">
  <p><xsl:apply-templates mode="inGroup"/></p>
 </xsl:template>
 <xsl:template match="text()"/>
</xsl:stylesheet>

对以下XML文档应用此转换时：

<nums>
  <num>01</num>
  <num>02</num>
  <num>03</num>
  <num>04</num>
  <num>05</num>
  <num>06</num>
  <num>07</num>
  <num>08</num>
  <num>09</num>
  <num>10</num>
</nums>

产生了想要的正确结果：

<div>
   <p>01</p>
   <p>02</p>
   <p>03</p>
</div>
<div>
   <p>04</p>
   <p>05</p>
   <p>06</p>
</div>
<div>
   <p>07</p>
   <p>08</p>
   <p>09</p>
</div>
<div>
   <p>10</p>
</div>

Answer 3

这是使用模板的优雅解决方案。

当这个XSLT：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:output omit-xml-declaration="yes" indent="yes" />
  <xsl:strip-space elements="*" />

  <xsl:param name="pNumInGroup" select="3" />

  <xsl:template match="/*">
    <html>
      <xsl:apply-templates select="*[position() mod $pNumInGroup = 1]" />
    </html>
  </xsl:template>

  <xsl:template match="node">
     <div>
        <xsl:for-each
          select=".|following-sibling::*[not(position() &gt; $pNumInGroup - 1)]">
          <div>
            <xsl:apply-templates />
          </div>
        </xsl:for-each> 
     </div>
  </xsl:template>

</xsl:stylesheet>

...适用于@MiMo提供的示例XML：

<root>
  <node>1</node>
  <node>2</node>
  <node>3</node>
  <node>4</node>
  <node>5</node>
  <node>6</node>
  <node>7</node>
</root>

...产生了正确的结果：

<html>
  <div>
    <div>1</div>
    <div>2</div>
    <div>3</div>
  </div>
  <div>
    <div>4</div>
    <div>5</div>
    <div>6</div>
  </div>
  <div>
    <div>7</div>
  </div>
</html>

如果参数值更改为5：

<xsl:param name="pNumInGroup" select="5" />

...仍然会产生正确的结果：

<html>
  <div>
    <div>1</div>
    <div>2</div>
    <div>3</div>
    <div>4</div>
    <div>5</div>
  </div>
  <div>
    <div>6</div>
    <div>7</div>
  </div>
</html>

<强>解释

我们在文档顶部定义了一个pNumInGroup参数（默认值为3）。这很有用，因为它允许更灵活地使用XSLT（即，如果每组需要不同数量的<div>个元素，只需将它们作为参数传递）。
第一个模板与根节点匹配，重新创建它，并告诉XSLT处理器将模板应用于每个分组的第一个元素（here's a refresher in modular arithmetic，以备不时之需）。
第二个模板与前一个模板选择的<node>元素相匹配。对于每个元素，都会创建一个新的<div>元素，并使用适合该包装组的其余项进行填充。

注意：我通常远离<xsl:for-each>，除非我真的需要它;在最后一个模板的情况下，我并不需要它（我可以很容易地用另一个模板指定包装/辅助<div>逻辑）。但是，为了＆＃34;清脆＆＃34;并没有过度模仿XSLT，我选择了这条路线。

XSLT：在div中包装每个第3个div

3 个答案: