Question

在这个帖子中，我引用了我的上一个帖子：Convert XML to CSV using XSLT - dynamic columns。

引用线程中的 XSLT 脚本工作正常但是使用大型 XML 文档时性能不佳。现在我想编写一个XSLT脚本，输出另一个XSLT脚本，该脚本将输出最终的 CSV 文件。

问题：

如何编写第一个XSLT脚本？输出应如下所示：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" indent="yes"/>

<xsl:template match="/*">
    <xsl:text>Name;</xsl:text>
    <xsl:text>Brother;</xsl:text>
    <xsl:text>Sister</xsl:text>
    <-- this part is dynamic -->
    <xsl:apply-templates select="Person" />
</xsl:template>

<xsl:template match="Person">
    <xsl:value-of select="Name" />
    <xsl:value-of select="Brother" />
    <xsl:value-of select="Sister" />
    <-- this part is dynamic too -->
    <xsl:text>&#10;</xsl:text>
</xsl:template>
</xsl:stylesheet>

输入XML文件与引用的线程中的相同：

<Person>
    <Name>John</Name>
    <FamilyMembers>
        <FamilyMember>
            <Name>Lisa</Name>
            <Type>Sister</Type>
        </FamilyMember>
        <FamilyMember>
            <Name>Tom</Name>
            <Type>Brother</Type>
        </FamilyMember>
    </FamilyMembers>
</Person>
<Person>
    <Name>Daniel</Name>
    <FamilyMembers>
        <FamilyMember>
            <Name>Peter</Name>
            <Type>Father</Type>
        </FamilyMember>
    </FamilyMembers>
</Person>

对于每个不同的类型元素，在生成的XSLT脚本中应该有如下所示的一行：

<xsl:text>Type;</xsl:text>

Answer 1

要编写一个输出另一个XSLT的XSLT，您需要使用<xsl:element>生成输出元素，例如

<xsl:element name="xsl:text">

如果要使用文字结果元素，请使用<xsl:namespace-alias>。 XSLT spec有一个例子：

<xsl:stylesheet
  version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:fo="http://www.w3.org/1999/XSL/Format"
  xmlns:axsl="http://www.w3.org/1999/XSL/TransformAlias">

<xsl:namespace-alias stylesheet-prefix="axsl" result-prefix="xsl"/>

<xsl:template match="/">
  <axsl:stylesheet>
    <xsl:apply-templates/>
  </axsl:stylesheet>
</xsl:template>

样式表中的任何<axsl:...>元素都会在输出中变为<xsl:...>。

Answer 2

我认为Tim的解决方案在规模上表现更好，而不是两个外部阶段的解决方案（意味着写一个样式表的样式表）。请使用“大型XML文档”作为输入来衡量此解决方案的性能。

此XSLT 1.0样式表......

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text" />

<xsl:key name="kTypes" match="Type" use="." />  
<xsl:variable name="distinct-types"
  select="/*/Person/FamilyMembers/FamilyMember/Type[
  generate-id()=generate-id(key('kTypes',.)[1])]" />

<xsl:template match="/">
  <xsl:value-of select="'Name;'" />
  <xsl:for-each select="$distinct-types">
    <xsl:value-of select="." />
    <xsl:if test="position() &lt; last()">
      <xsl:value-of select="';'" />
    </xsl:if>  
  </xsl:for-each>
  <xsl:value-of select="'&#x0A;'" />
  <xsl:apply-templates select="*/Person" />
</xsl:template>

<xsl:template match="Person">
  <xsl:value-of select="concat(Name,';')" />
  <xsl:variable name="family" select="FamilyMembers/FamilyMember" />
  <xsl:for-each select="$distinct-types">
    <xsl:variable name="type" select="string(.)" />
    <xsl:value-of select="$family/self::*[Type=$type]/Name" />
    <xsl:if test="position() &lt; last()">
      <xsl:value-of select="';'" />
    </xsl:if>  
  </xsl:for-each>
  <xsl:value-of select="'&#x0A;'" />
</xsl:template>

</xsl:stylesheet>

...会对此输入（或其他有效的规模）进行转换......

<t>
<Person>
    <Name>John</Name>
    <FamilyMembers>
        <FamilyMember>
            <Name>Lisa</Name>
            <Type>Sister</Type>
        </FamilyMember>
        <FamilyMember>
            <Name>Tom</Name>
            <Type>Brother</Type>
        </FamilyMember>
    </FamilyMembers>
</Person>
<Person>
    <Name>Daniel</Name>
    <FamilyMembers>
        <FamilyMember>
            <Name>Peter</Name>
            <Type>Father</Type>
        </FamilyMember>
    </FamilyMembers>
</Person>
</t>

...并生成文字......

Name;Sister;Brother;Father
John;Lisa;Tom;
Daniel;;;Peter

Answer 3

在此处查看为另一个XSLT转换生成样式表的XSLT转换的实际示例：

http://dnovatchev.wordpress.com/2006/10/21/a-stylesheet-to-write-xslt-code/

XSLT生成另一个XSLT脚本

3 个答案: