Question

我有一些XML，我想将其转换为一个报告，显示在一个日期内符合特定条件的节点数量。

下面的示例xml。我试图在日期范围内显示基于状态的节点数。

我可以根据日期范围进行匹配，但是我无法在该范围内显示状态计数。任何指针都赞赏。

    <?xml version="1.0" encoding="UTF-8"?>
    <List>
     <Item>
       <Value name="Status">Open</Value>    
       <Value name="Date">2012-09-01</Value>
       <Value name="Name">Item 1</Value>
     </Item>
     <Item>
       <Value name="Status">Open</Value> 
       <Value name="Date">2012-10-15</Value>
       <Value name="Name">Item 2</Value>
     </Item>
     <Item>
       <Value name="Status">Open</Value> 
       <Value name="Date">2012-10-15</Value>
       <Value name="Name">Item 3</Value>
     </Item>
     <Item>
       <Value name="Status">Pending</Value> 
       <Value name="Date">2012-10-20</Value>
       <Value name="Name">Item 4</Value>
     </Item>
     <Item>
       <Value name="Status">Closed</Value>
       <Value name="Date">2012-10-30</Value>
       <Value name="Name">Item 5</Value>
     </Item>
    </List>

示例输出将是： -

   Status         2012-10-01 - 2012-10-31
   Open           2
   Closed         1
   Pending        1

Answer 1

就这么简单：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:param name="pStartDate" select="20121001"/>
 <xsl:param name="pEndDate" select="20121031"/>

 <xsl:template match="/">
   <xsl:variable name="vInRange" select=
    "/*/*[translate(Value[@name='Date'],'-','') >= $pStartDate
         and
          $pEndDate >= translate(Value[@name='Date'],'-','')
         ]"/>
     Open      <xsl:value-of select="count($vInRange[Value[@name='Status']='Open'])"/>
     Closed    <xsl:value-of select="count($vInRange[Value[@name='Status']='Closed'])"/>
     Pending   <xsl:value-of select="count($vInRange[Value[@name='Status']='Pending'])"/>
 </xsl:template>
</xsl:stylesheet>

在提供的XML文档上应用此转换时：

<List>
    <Item>
        <Value name="Status">Open</Value>
        <Value name="Date">2012-09-01</Value>
        <Value name="Name">Item 1</Value>
    </Item>
    <Item>
        <Value name="Status">Open</Value>
        <Value name="Date">2012-10-15</Value>
        <Value name="Name">Item 2</Value>
    </Item>
    <Item>
        <Value name="Status">Open</Value>
        <Value name="Date">2012-10-15</Value>
        <Value name="Name">Item 3</Value>
    </Item>
    <Item>
        <Value name="Status">Pending</Value>
        <Value name="Date">2012-10-20</Value>
        <Value name="Name">Item 4</Value>
    </Item>
    <Item>
        <Value name="Status">Closed</Value>
        <Value name="Date">2012-10-30</Value>
        <Value name="Name">Item 5</Value>
    </Item>
</List>

产生了想要的正确结果：

 Open      2
 Closed    1
 Pending   1

XSLT：根据多个条件计算特定节点

1 个答案: