Question

我试图把它放到画布文本中

名称飞行岩浆水

这样做..它会检查玩家是否应该有飞行，熔岩或水等名称。因此标签文本以玩家的名字开头。所有标签都有这个。然后如果像canwater这样的任何“额外”都是真的那么它将添加一个带有相关文本的新行。见下文。

                canwater := (FTherePlayers.Player[strtoint(name2)].values['water'] = 'Yes');  //checks if unit can enter water
                canlava := (FTherePlayers.Player[strtoint(name2)].values['lava'] = 'Yes');  //checks if unit can enter lava
                canfly := (FTherePlayers.Player[strtoint(name2)].values['Flying'] = 'Yes');   //checks if unit can fly
                labeltext :=  FTherePlayers.Player[strtoint(name2)].values['name'];
               if canfly then
                  labeltext := labeltext+ #13#10+ 'Flying';
               if canlava then
                  labeltext := Labeltext+#13#10+'Lava';
               if canwater then
                  labeltext := labeltext+#13#10+'Water';
               hexmap1.AddLabelName(Labeltext,posL); //add name to placement label

现在它会给标题提供正确的信息。但它永远不会添加新行，而是看起来像这样

name[][]flying[][]lava[][]water[][]

其中[]是小方块我用于textout的代码看起来像这样。

procedure THexmap.AddLabelName(text :string; Position :TPoint);
var
  hex_id :string;
  P0:tpoint;

begin
    with TempMap.canvas do
   begin
      hex_id := text;
           hex_id := text;
           {font := self.font;}
           p0 := convertcoords(point(Position.X,Position.Y),ptROWCOL);
           textout(p0.x - (trunc(textwidth(hex_id) / 2)) ,p0.y- (textheight(hex_id)) ,hex_id);
   end;
       Refresh;
end;

几乎将新图像或本文中的文本加载到临时地图中..hex_ID是名称/ flying / lava ..是PO是将它放在地图上的位置，即第1行，第3列至于发短信，我不确定它是如何工作的。但是，想象一下“换行”代码＃10＃13在那里搞砸了。关于如何解决这个问题的任何想法？

添加了我如何得到我的XY（tpoint）

{******************************************************************************}
{  This function will return the Row / Col pair based on a given X/Y
   for a using application that calls it}
 function THexMap.ConvertCoords(point:Tpoint;pointtype:Tpointtype):Tpoint;
 var
   temp:TPoint;
 begin
   case PointType of
     ptXY: {Convert from x/y to Row/Col}
     Begin

       temp.x:= round( (point.x + (HexRadius/2) ) / (1.5 * Hexradius));



       if odd(temp.x) then
          temp.y := round( (point.y + rise) / (rise*2))
       else
          temp.y := round( point.y  / (2*rise));

       { This section insures row / col is good}
      if (temp.x < 1) or (temp.y < 1) then
         begin
           temp.x := 0;
           temp.y := 0;
          end
       else if (temp.y > HexRows) or (temp.x > HexColumns) then
         begin
           temp.y := 0;
           temp.x := 0;
         end;

       ConvertCoords := temp;
     end;

     ptRowCol:  { Converts Row/Col to X/Y }
     begin
       if point.x=1 then
        temp.x:= HexRadius
       else
        temp.x := HexRadius+(point.x-1) * (round(1.5 * hexradius));

       if odd(point.x) then
        if point.y=1 then
           temp.y:= rise
        else
           temp.y := rise+(point.y-1) * (2 * rise)
       else
         temp.y := (point.y * (2*rise));

       ConvertCoords := temp;
     end;
   end;
 end;

Answer 1

TextOut只是将＃13＃10视为要绘制的两个字符。这就是你看到正方形的原因。它不知道您打算将文本放在不同的行上。

您必须将文字放在不同的行上，例如通过写4次调用TextOut。

您也可以使用Win32 API中的DrawText。

Answer 2

var
 s:String;
 r:TRect;
begin
   s := 'Just'#13#10'for'#13#10'demonstration';
   r.Left := 10;
   r.top := 10;
   r.Right := 100;
   r.Bottom := 100;

   // you can use this with newer Delphiversions
   // Canvas.TextRect(r,s, [tfCenter,tfWordBreak]);
   // with olderversions you can use this             =1              =16
   DrawTextEx(Canvas.Handle, PChar(s), Length(s), r, DT_CENTER or DT_WORDBREAK, nil);
end;

作为如何从点

获取矩形的问题的答案

var
 s:String;
 r:TRect;
begin
   s := 'Just'#13#10'for'#13#10'demonstration';
   r.Left := p0.x;
   r.top := p0.y;
   r.Right := p0.x + 10000;    // we will calculate needed rect later
   r.Bottom := p0.y + 10000;   // via DT_CALCRECT

   // you can use this with newer Delphiversions
   // Canvas.TextRect(r,s, [tfCenter,tfWordBreak,tfCalcRect]);
   // with olderversions you can use this             =1              =16           1024
   DrawTextEx(Canvas.Handle, PChar(s), Length(s), r, DT_CENTER or DT_WORDBREAK or DT_CALCRECT, nil);

   // you can use this with newer Delphiversions
   // Canvas.TextRect(r,s, [tfCenter,tfWordBreak]);
   // with olderversions you can use this             =1              =16
   DrawTextEx(Canvas.Handle, PChar(s), Length(s), r, DT_CENTER or DT_WORDBREAK, nil);
end;

在canvas.textout中添加一个新行

2 个答案: