如何在查询中使用许多复选框值

Question

我的目标是通过将Query字符串与变量合并，将5个文本框的结果返回到SQL查询中。

如何让我的代码运行，以便在选中复选框时，会记录值（例如：ID，SC ...）并将其放入查询中？如果未选中复选框，则不会将其置于查询中。

5个复选框如下：

我当前的代码必须记录是否选择了文本框，并将值（例如：ID，SC，AS ...）放入变量中，如下所示：

If (Me.BoxID = False) And (Me.BoxSC = False) And (Me.BoxASSC = False) And (Me.BoxAS = False) And (Me.BoxEH = False) Then
MsgBox "You must check a Fonction Checkbox", 0
Exit Sub
Else
    If (Me.BoxID= True) Then IDValue = Chr(34) & "ID" & Chr(34) Else IDValue = """"""
    If (Me.BoxSC= True) Then SCValue = Chr(34) & "SC" & Chr(34) Else SCValue = """"""
    If (Me.BoxASSC= True) Then ASSCValue = Chr(34) & "ASSC" & Chr(34) Else ASSCValue = """"""
    If (Me.BoxAS= True) Then ASValue = Chr(34) & "AS" & Chr(34) Else ASValue = """"""
    If (Me.BoxEH= True) Then EHValue = Chr(34) & "EH" & Chr(34) Else EHValue = """"""
End If

fonctionQryString = "(((tblF.f1)=" & IDValue & ") OR " + "((tblF.f1)=" & SCValue & ") OR " + "((tblF.f1)=" & ASSCValue & ") OR " + "(tblF.f1)=" & ASValue & ") OR " + "(tblF.f1)=" & EHValue & ")))"

fonctionQryString进入SQL Query的WHERE部分。

我知道我使用的方法效率不高，即使它有效。

我的问题是我不知道如何以另一种方式做到这一点。我希望我的代码能够运行，以便在未选中复选框时，它不会进入查询字符串。

非常感谢任何帮助。

Answer 1

这两个WHERE子句应该产生相同的结果。考虑切换到第二种形式。

WHERE tblF.f1 = "ID" OR tblF.f1 = "SC" OR tblF.f1 = "AS"
WHERE tblF.f1 IN ("ID","SC","AS")

根据我对您要实现的目标的理解，这是一个粗略且未经测试的代码示例，用于生成类似的WHERE子句。

Dim fonctionQryString As String
Dim lngLoopNum As Long
Dim strControlName As String
Dim strValueList As String
For lngLoopNum = 1 To 5
    Select Case lngLoopNum
    Case 1
        strControlName = "ID"
    Case 2
        strControlName = "SC"
    Case 3
        strControlName = "ASSC"
    Case 4
        strControlName = "AS"
    Case 5
        strControlName = "EH"
    End Select
    If Me.Controls("Box" & strControlName) = True Then
        strValueList = strValueList & "," & Chr(34) & _
            strControlName & Chr(34)
    End If
Next
If Len(strValueList) > 0 Then
    fonctionQryString = "tblF.f1 IN (" & Mid(strValueList, 2) & ")"
Else
    MsgBox "You must check a Fonction Checkbox"
End If

我假设你实际上并不想要包含条件WHERE tblF.f1 = ""（一个空字符串）。如果我猜错了，你还有更多的工作要做，但希望这仍然会指出你有用的东西。