Question

如果我想基本上grep存储库中的每一行，有没有办法做到这一点？我知道大型项目需要很长时间。

如果不是全部，至少只是当前分支及其整个源历史记录？

编辑：我应该更明确。 如果我无法直接访问CVS存储库所在的服务器，该怎么办？因此我无法直接 grep具有CVS存储库的文件系统。

Answer 1

没有访问存储库的标准CVS工具无法做到这一点。那里的第三方工具可能会这样做（我不知道一个，虽然CS-CVS似乎claim to），但是以编程方式进行，你必须在所有相关文件上做CVS日志，然后检索并搜索日志中cvs报告的每个版本（cvs log是CVS中的命令行选项，显示任何文件的修订历史记录，但它不会显示内容）。

Answer 2

这是我最近使用的，在我无法访问服务器的情况下。它似乎工作那个时间。从工作副本中调用它，在PATH中使用cvs。请注意，这不会搜索提交消息，但您可以简单地使用grep'cvs log'。

#!/usr/bin/perl

# Searches CVS diffs and first revisions behind the current working
# directory for an expression (perlre syntax).

# Synopsis: cvsgrep [-n] <search-expression> [<file_1> ... <file_n>]

# -n means that contents of matching files should not be printed to stdout.

use Getopt::Std;

my %options=();
getopts("n",\%options);
my $no_content_dump=$options{"n"};

my $search_term=shift
    or die "Error: usage is: cvsgrep [-n] <search-expression>".
    " [<file_1> ... <file_n>]";

sub quote_fn
{
    my $fn=shift;
    $fn =~ s/\'/\'\"\'\"\'/g;
    "'".$fn."'";
}

my $args_str;
while(@ARGV)
{
    my $arg=shift;
    $args_str.=' ' if $args_str;
    $args_str.=&quote_fn($arg);
}

print 
    "Searching for term: $search_term",
    ($args_str?" in: $args_str":""),
    "\n";

open CVSLOGH,"cvs log -N $args_str|" or die "Cannot execute cvs log: $!";

my @files_revisions=();

my $cur_file;
my $cur_revision;

while(<CVSLOGH>)
{
    chop;
    if(/^Working file\:\s*(.*)$/)
    {
        $cur_file=$1;
        $cur_revision='';
    }
    elsif(/^revision\s+(.*)$/)
    {
        $cur_revision=$1;
    }
    elsif((/^\=\=\=\=/ || /^\-\-\-\-/) && $cur_revision)
    {
        push @files_revisions,{file=>$cur_file,rev=>$cur_revision};
    }
}

close CVSLOGH;

my $matchcount=0;
my $count=0;
my $progress_msg="Scanned %d out of %d commit(s)\r";
my $erase_ln=(" " x (length($progress_msg)+20)) . "\r";

foreach my $file_revision(@files_revisions)
{
    printf($progress_msg,$count++,scalar(@files_revisions));

    my($file,$rev) = ($file_revision->{file},$file_revision->{rev});

    $rev =~ /^(.*\.)([0-9]+)/;
    my $revbase=$1;
    my $revlastdigit=$2;
    my $rev1=$revbase.($revlastdigit - 1);
    my $diffcommand = "cvs diff -N -r $rev1 -r $rev ".&quote_fn($file);
    open CVSDIFFH,"$diffcommand|" or die "Cannot execute cvs diff: $!";

    my $diffresult;
    while(<CVSDIFFH>)
    {
        if(/^[\<\>]/)
        {
            s/^.//;
            $diffresult.=$_;
        }
    }
    close CVSDIFFH;

    if($diffresult =~ /$search_term/s)
    {
        print "${erase_ln}FOUND: in diff for $file $rev1:$rev\n";
        $matchcount++;
        system($diffcommand) unless $no_content_dump;
    }
}

print "${erase_ln}Done ($matchcount match(es)).\n";

Answer 3

这取决于你在寻找什么。 CVS版本文件包含以明文形式发生在文件中的所有编辑。因此，如果您只是查找包含特定单词的所有文件，请在存储库中执行递归grep。

如果您正在寻找包含这些词的特定版本，那么您将不得不从存储库中提取版本，这很昂贵。但是，如果您可以通过grepping存储库来限制文件集，那么它就不那么糟了。

如何搜索整个CVS存储库（所有分支/历史/评论）？

3 个答案: