Question

假设我有一个这样的源示例文档：

<html>
  <b><i><u>TestBIU</u></i></b>
  <i><b><u>TestIBU</u></b></i>
  <i><u><b>TestIUB</b></u></i>
  <b><u><i>TestBUI</i></u></b>
  <u><i><b>TestUIB</b></i></u>
  <u><b><i>TestUBI</i></b></u>
  <u>TestU</u>
  <i>TestI</i>
  <b>TestB</b>
  <u><b>TestUB</b></u>
</html>

我需要一个产生这个的XSLT模板：

<html>
  <b><i>TestBIU</i></b>
  <i><b>TestIBU</b></i>
  <i><b>TestIUB</b></i>
  <b><i>TestBUI</i></b>
  <i><b>TestUIB</b></i>
  <b><i>TestUBI</i></b>
  <u>TestU</u>
  <i>TestI</i>
  <b>TestB</b>
  <b>TestUB</b>
</html>

因此，它应该在与斜体和/或粗体标签结合使用时删除下划线标记。只有下划线时，它应该保留。任何想法如何解决这个特殊问题？

这是我的尝试，但如果TestUIB和TestUBI失败：

<xsl:template match="/">
    <html>
    <xsl:apply-templates />
    </html>
</xsl:template>
<xsl:template match="b/u">
      <xsl:apply-templates />
</xsl:template>
<xsl:template match="i/u">    
      <xsl:apply-templates />
</xsl:template>
<xsl:template match="u/i">
  <i><xsl:apply-templates /></i>
</xsl:template> 
<xsl:template match="u/b">
    <b><xsl:apply-templates /></b>
</xsl:template>    
<xsl:template match="b | u | i">
    <xsl:copy>
        <xsl:apply-templates select="* | text()"/>
    </xsl:copy>
</xsl:template>

Answer 1

我认为

<xsl:stylesheet 
  version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:template match="@* | node()">
  <xsl:copy>
    <xsl:apply-templates select="@* | node()"/>
  </xsl:copy>
</xsl:template>

<xsl:template match="b//u | i//u | u[b] | u[i]">
  <xsl:apply-templates/>
</xsl:template>

</xsl:stylesheet>

就足够了。

Answer 2

试试这个：

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema">

<xsl:template match="@*|node()">
  <xsl:copy>
    <xsl:apply-templates select="@*|node()"/>
  </xsl:copy>
</xsl:template>

<xsl:template match="u[ancestor::b | ancestor::i | descendant::b | descendant::i]">
    <xsl:apply-templates />
</xsl:template>

</xsl:stylesheet>

它会为您的样本生成以下输出：

<html>
    <b><i>TestBIU</i></b>
    <i><b>TestIBU</b></i>
    <i><b>TestIUB</b></i>
    <b><i>TestBUI</i></b>
    <i><b>TestUIB</b></i>
    <b><i>TestUBI</i></b>
    <u>TestU</u>
    <i>TestI</i>
    <b>TestB</b>
    <b>TestUB</b>
</html>

说明：在我的解决方案中，我正在使用identity transform逐个节点和属性按属性复制所有内容。第二个模板拦截所有<u>个HTML标记，这些标记在其祖先或后代中具有<i>或<b>。出现这种情况时，我们不会复制标签，而只会调用apply-templates来处理其子项。

如何剥离标签依赖于上下文？

2 个答案: