Question

任何人都知道如何按长度排序数字？

Ex：（11,111,122,12,2,13,21,15,211,22,213,2004）

我希望排序的数组为：

Answer 1

所需的输出似乎表明您不仅要按数字排序，而是首先按第一个数字排序，然后按长度排序。

您显示的所需输出省略211，因此我只是根据我的理解将其放在所属的位置。

#!/usr/bin/env perl

use strict;
use warnings;

use Test::More;

my @source = (11, 111, 122, 12, 2, 13, 21, 15, 211, 22, 213, 2004);
my @desired = (11, 12, 13, 15, 111, 122, 2, 21, 22, 211, 213, 2004);

my @sorted =sort {
    substr($a, 0, 1) <=> substr($b, 0, 1) ||
    length($a) <=> length($b) || 
    $a <=> $b # thanks @ikegami
} @source;

is_deeply(\@sorted, \@desired, 'Sorted and desired are the same');

Answer 2

my @sorted =
   sort { substr($a,0,1) <=> substr($b,0,1) || $a <=> $b }
    @unsorted;

给出您请求的订单。或许你想要

my @sorted =
   sort {  substr($a,0,1) <=> substr($b,0,1)
        || length($a) <=> length($b)
        || $a <=> $b }
   @unsorted;

如果您提供的输出中没有遗漏211，我可以告诉您哪一个。

Answer 3

考虑一个所谓的Schwartzian transform，它可以通过暂时将它们与输入项相关联来避免重新计算排序键：

my @sorted =
    map { $_->[0] }
    sort { $a->[1] cmp $b->[1] or $a->[0] <=> $b->[0] }
    map { [ $_ => sprintf "%.1s%08x", $_, length ] }
    @source;

Answer 4

这是由List::UtilsBy::sort_by

提供的

use List::UtilsBy qw( sort_by );

my @sorted = sort_by { sprintf "%.1s%08x", $_, length } @source;

它与其他人建议的Schwartzian变换解决方案非常相似，但却包含在一个简洁的抽象中。

在Perl中按长度排序

4 个答案: