Question

我不确定使用Classic ASP（VBscript）是否可行，但我想做的是以下内容：

在HTML文本中搜索特定字符串（仅在p-tag，div-tags，li-tags，span-tags和忽略其他标记之间的文本，如a-tags之间），并将其替换为其他标记。例如：

原始HTML

<p>Some text with the keyword.</p>

经典ASP功能

仅在所有p-tag，div-tags，span-tags和li-tags之间搜索HTML文本中的关键字，但忽略其他标签（如a-tags）之间的文本。将关键字替换为其他内容。

输出HTML

<p>Some text with the <a href="someurl">keyword</a>.</p>

如果不可能，还有其他方法吗？有这方面经验的人吗？

要清楚。 “带有关键字的一些文本。” - 文本不是来自数据库，因为这太容易了:)不幸的是，它出现在.asp文件的HTML中。

Answer 1

这里需要字符串操作..因为我从来没有真正进入正则表达式我很久以前就用我自己的方法来以各种方式操作文本。非常难看，不是最好的效率，但它有效。

首先，将这些功能添加到您的代码中：

Function GetBetween(str, leftDelimeter, rightDelimeter)
    Dim tmpArr, result(), x
    tmpArr=Split(str, leftDelimeter)
    If UBound(tmpArr) < 1 Then
        GetBetween=Array() : Exit Function
    End If
    ReDim result(UBound(tmpArr)-1)
    For x=1 To UBound(tmpArr)
        result(x-1)=(Split(tmpArr(x), rightDelimeter))(0)
    Next
    Erase tmpArr
    GetBetween=result
End Function

Function ReplaceWholeWord(ByVal strText, strWord, strToReplaceWith)
    ReplaceWholeWord = strText
    If InStr(strText, strWord)<1 Then Exit Function

    'Text is only the word?
    If strText=strWord Then
        strText = Replace(strText, strWord, strToReplaceWith)
    Else  
        'Text starting with word?
        If InStr(strText, strWord & " ")=1 Then
            strText = strToReplaceWith & " " & Right(strText, Len(strText) - Len(strWord & " "))
        End If

        'Text ends with word?
        If Right(strText, Len(" " & strWord))=(" " & strWord) Then
            strText = Left(strText, Len(strText) - Len(" " & strWord)) & " " & strToReplaceWith
        End If

        'Text ends with word and a period?
        If Right(strText, Len(" " & strWord & "."))=(" " & strWord & ".") Then
            strText = Left(strText, Len(strText) - Len(" " & strWord & ".")) & " " & strToReplaceWith & "."
        End If

        'Replace between other words:
        strText = Replace(strText, " " & strWord & " ", " " & strToReplaceWith & " ")
    End If

    ReplaceWholeWord = strText
End Function

使用这些功能，以下是以您希望的方式替换关键字的示例代码：

Const KEYWORD = "keyword"
Dim strHTML, arrTagsToFind, x
Dim curItemsArray,  y, curItem
Dim curReplacedItem
arrTagsToFind = Array("p", "div")
strHTML = "<b>this keyword will not be replaced</b><p>Some text with the keyword.</p>keyword here won't be replaced too<p>Some other text with the keyword22 that is not whole word but end with keyword</p><div>keyword first</div>"
For x=0 To UBound(arrTagsToFind)
    curItemsArray = GetBetween(strHTML, "<" + arrTagsToFind(x) + ">", "</" + arrTagsToFind(x) + ">")
    For y=0 To UBound(curItemsArray)
        curItem = curItemsArray(y)
        curReplacedItem = ReplaceWholeWord(curItem, KEYWORD, "<a href=""#foo"">" & KEYWORD & "</a>")
        strHTML = Replace(strHTML, curItem, curReplacedItem)
    Next
Next
Response.Write(strHTML)

使用经典ASP替换HTML中的文本

1 个答案: