Question

我有一个这样的例子：

proc sql;
select dealno into :deal_no 
from deal_table;

现在我想遍历变量deal_no现在包含表deal_table中的所有dealno但我不知道该怎么做。

Answer 1

另一个选项是将“分隔”添加到sql代码，这将为值添加分隔符。然后，您可以在数据步骤中使用SCAN函数或在宏中使用％SCAN来循环遍历值并执行您想要的任何任务。示例如下。

proc sql noprint;
select age into :age separated by ','
from sashelp.class;
quit;

%put &age.;

data test;
do i=1 by 1 while(scan("&age.",i) ne '');
    age=scan("&age.",i);
    output;
end;
drop i;
run;

Answer 2

如果你这样做

%put &deal_no;

你可以看到它只包含dealno的第一个值，而不是所有值。为了避免这种情况，你可以这样做：

proc sql;
    create table counter as select dealno from deal_table;
    select dealno into :deal_no_1 - :deal_no_&sqlobs
    from deal_table;
quit;

%let N = &sqlobs;

%macro loop;
%do i = 1 %to &N;
    %put &&deal_no_&i;
%end;
%mend;

%loop; run;

Answer 3

这是另一种解决方案。

proc sql noprint;
  select age into :ageVals separated by ' '
  from ageData;
quit;  

%put &ageVals;

%macro loopAgeVals;   %let i = 1;   %let ageVal = %scan(&ageVals, &i);

  %do %while("&ageVal" ~= "");
    %put &ageVal;

    %let i = %eval(&i + 1);
    %let ageVal = %scan(&ageVals, &i);   
  %end; 

%mend;

%loopAgeVals;

如何在SAS中循环遍历宏变量

3 个答案: