Question

我有一个序言要做的事：有5个人坐在不同国籍的圆桌会议上（法语，英语，波兰语，意大利语，土耳其语）。他们每个人只知道自己以外的另一种语言。他们坐在圆桌旁，每个人都可以与他们的两个邻居交谈（一个邻居用他们的母语和另一个用他们所知道的单一外语交谈）。英国人知道意大利语，波兰人知道法语，土耳其人不懂英语。问题是土耳其人知道什么是外语？

我只使用了子句和谓词做了一些事情，但我走到了尽头，老师建议最简单的方法就是使用列表。

对该列表包含的内容或任何代码构思的任何想法？

UPDATE（弱逻辑代码）：

    predicates
knowTheLanguage(symbol,symbol)  
knowNotTheLanguage(symbol,symbol)
isNeighbor(symbol,symbol,symbol,symbol)

aTheory(symbol,symbol,symbol,symbol) 
anotherTheory(symbol,symbol,symbol,symbol)

    clauses
knowTheLanguage(englishman,italian).
knowTheLanguage(polishman,franch).

%native tongues
knowTheLanguage(englishman,english).
knowTheLanguage(frenchman,franch).
knowTheLanguage(polishman,polish).
knowTheLanguage(italianman,italian).
knowTheLanguage(turk,turkish).


knowNotTheLanguage(turk,english).

aTheory(centralPerson, languageCntrlPers, personOnOneSide,languagePrsnOnOneSide) if knowTheLanguage(personOnOneSide,languageCntrlPers)
                                                                            and not( knowTheLanguage(centralPerson,languagePrsnOnOneSide))
                                                                            and not(knowNotTheLanguage(centralPerson,languagePrsnOnOneSide)).
anotherTheory(centralPerson, languageCntrlPers, personOnOneSide,languagePrsnOnOneSide) if knowTheLanguage(centralPerson,languagePrsnOnOneSide) 
                                                                            and  not( knowTheLanguage(personOnOneSide,languageCntrlPers))
                                                                            and not(knowNotTheLanguage(centralPerson,languagePrsnOnOneSide)).

isNeighbor(centralPerson, languageCntrlPers, personOnOneSide,languagePrsnOnOneSide) if aTheory(centralPerson, languageCntrlPers, personOnOneSide,languagePrsnOnOneSide)
                                                                        or
                                                                        anotherTheory(centralPerson, languageCntrlPers, personOnOneSide,languagePrsnOnOneSide).

更新 - 编程环境：turland prolog 2.0 '86，'88 by Borland，我也是一个完整的prolog开头，所以...我至少会完整地描述该程序和解释之外的代码体。我处理的事情很慢：D

Answer 1

您可以使用循环列表，尝试使用此代码来理解。

t :-
    L = [1,2,3 | L],
    my_write(5, L).

my_write(0, _).
my_write(N, [H | T]) :-
    write(H), nl,
    N1 is N - 1,
    my_write(N1, T).

循环列表可能对您非常有用。

描述列表的元素是什么，然后是语言的约束

编辑：这是我的解决方案，适用于SWI-Prolog：

% @arg1 : list of nationalities around the table
% @arg2 : list of persons
dinner(Languages, Table) :-
    length(Languages, Len),
    length(Table, Len),

    % set Natianalities and languages
    init_1(Table, Languages, Languages),

    % create cyclic list
    % works with SWI-Prolog
    append(Table, L, L),

    % set languages constraint
    init_2(Len, L).

init_1([], [], []).

init_1([person(N, L) | T], Nations, Languages):-
    select(N, Nations, New_Nations),

    % problem specific
    (   N = english
    ->  L = italian
    ;   N = polish
    ->  L = french
    ;   true),

    select(L, Languages, New_Languages),

    % problem specific
    (   N = turkish
    ->  L \=  english
    ;   true),

    init_1(T, New_Nations, New_Languages).

% persons speaks with theirs two neighbors
init_2(Tr, [person(_N1, L1), person(N2, L2), person(N3, L3) | T]) :-
    Tr > 0,
    member(N2, [L1, L3]),
    Tr1 is Tr - 1,
    init_2(Tr1, [person(N2, L2), person(N3, L3) | T]).

init_2(0, _).

Answer 2

通常情况下，我会使用约束解决这样一个难题，但这可能对你的作业来说太高级了。因此，我们不必使用约束来限制搜索空间，而是使用测试来检查解决方案是否可行。

您需要使用两个列表，例如People和Languages。列表的每个元素对应于桌子上的一个座位。两个列表都可以具有相同的域[f,e,p,i,t]。域名的语义应该是清楚的。

要生成解决方案，首先要设置列表，然后实例化列表并检查实例化是否满足约束条件：

puzzle(People, Languages) :-
    Domain = [f,e,p,i,t],
    length(People, 5),
    length(Languages, 5),
    % symmetry break:
    People = [f|_],
    % instantiate People
    people(People, Domain),
    % instantiate languages and check constraints
    languages(Languages, People, Domain).

请注意，列表People的第一个元素设置为f。这是为了排除symmterical解决方案，否则将返回表，因为表是圆的。如果没有这个限制，每个解决方案都会有四个额外的对称解决方案。

在阅读之前尝试提出自己的解决方案......： - ）

首先实例化列表People。我们需要注意每个元素只出现一次：

people([], []) :- !.
people([P|RestP], Domain) :-
    delete(P, Domain, RestD),
    people(RestP, RestD).

你的Prolog方言可能有select/3而不是delete/3。

在实例化列表Languages时，我们还会检查是否违反了拼图约束：

languages(Languages, People, Domain) :-
    Term =.. [[]|People],
    languages0(Languages, People, Term, 1, Domain).
languages0([], _, _, _, _) :- !.
languages0([L|RestL], [P|RestP], Term, I, Domain) :-
    delete(L, Domain, RestD),
    L \= P, % language needs to be foreign
    check_l(P, L),
    check_n(L, I, Term),
    I1 is I+1,
    languages0(RestL, RestP, Term, I1, RestD).

同样，每个元素只能出现一次。

check_l检查有关外语的限制：

check_l(e, i).
check_l(p, f).
check_l(t, L) :- L \= e.
check_l(f, _).
check_l(i, _).

check_n确保左或右邻居的语言和国籍匹配：

check_n(L, I, Term) :-
    ( I == 1 -> NL = 5 ; NL is I-1 ),
    ( I == 5 -> NR = 1 ; NR is I+1 ),
    ( arg(NL, Term, L) ; arg(NR, Term, L) ).

有两种解决方案：

?- puzzle(P, L).
P = [f, e, i, t, p]
L = [e, i, t, p, f]
Yes (0.00s cpu, solution 1, maybe more)
P = [f, p, t, i, e]
L = [e, f, p, t, i]
Yes (0.01s cpu, solution 2, maybe more)
No (0.01s cpu)

Answer 3

通常，在对问题进行建模时，识别紧凑的表示非常重要，从而消除不相关的细节。例如，polishman和polish就没用了。我们同意polish代表男人和语言。

我草拟了解决方案，请填写省略号，添加约束：

puzzle(L) :-
    L = [P1,P2,P3,P4,P5],
    cadj(P5,P1,P2),
    ...
    member(p(english, italian), L),
    member(p(french,  _ ),      L),
    ...
    \+ member(p(turk, english), L).

% constrain adjacents
cadj(p(Pl, Ll), p(P, K), p(Pr, Lr)) :-
    P = Ll, K = Pr ; P = Lr, K = Pl.

p / 2代表他所知道的男人和语言。 cadj / 3说如果左边的人知道我的语言，我必须知道右边那个人的语言，或者反之。

要获得所需语言，请尝试

puzzle :-
    puzzle(L),
    memberchk(p(turk, T), L),
    writeln(T:L).

还有更多解决方案，但语言T始终受限于单个值......

一个prolog程序，反映了坐在圆桌旁的人

3 个答案: