Question

（可以在https://gist.github.com/4044467找到最小的非编译示例，请参阅下面的更多背景。）

我正在尝试实现Okasaki的纯功能数据结构第10章中介绍的 Bootstrapped Heaps 。以下是我的非编译代码的简化版本。

我们要实现一个具有以下签名的堆：

module type ORDERED =
sig
  type t
  val compare : t -> t -> int
end

module type HEAP =
sig
  module Elem : ORDERED

  type heap

  val empty : heap
  val insert : Elem.t -> heap -> heap
  val find_min : heap -> Elem.t
  val delete_min : heap -> heap
end

我们说数据结构 bootstrapped ，当它的实现依赖于同一种数据结构的另一种实现时。所以我们有这样的堆（实际的实现并不重要）：

module SomeHeap (Element : ORDERED) : (HEAP with module Elem = Element) =
struct
  module Elem = Element

  type heap

  let empty = failwith "skipped"
  let insert = failwith "skipped"
  let find_min = failwith "skipped"
  let delete_min = failwith "skipped"
end

然后，我们要实现的自举堆（可以依赖于任何堆实现）应该具有以下签名：

module BootstrappedHeap
  (MakeH : functor (Element : ORDERED) -> HEAP with module Elem = Element)
  (Element : ORDERED) : (HEAP with module Elem = Element)

所以我们可以像这样使用它：

module StringHeap = BootstrappedHeap(SomeHeap)(String)

根据Okasaki的说法，BootstrappedHeap的实现是这样的：

module BootstrappedHeap
  (MakeH : functor (Element : ORDERED) -> HEAP with module Elem = Element)
  (Element : ORDERED) : (HEAP with module Elem = Element) =
struct
  module Elem = Element

  module rec BootstrappedElem :
  sig
    type t =
      | E
      | H of Elem.t * PrimH.heap
    val compare : t -> t -> int
  end =
  struct
    type t =
      | E
      | H of Elem.t * PrimH.heap
    let compare t1 t2 = match t1, t2 with
      | H (x, _), H (y, _) -> Elem.compare x y
      | _ -> failwith "unreachable"
  end
  and PrimH : (HEAP with module Elem = BootstrappedElem) =
    MakeH(BootstrappedElem)

  type heap

  let empty = failwith "not implemented"
  let insert = failwith "not implemented"
  let find_min = failwith "not implemented"
  let delete_min = failwith "not implemented"
end

但这不是编译！错误消息是：

File "ordered.ml", line 52, characters 15-55:
Error: In this `with' constraint, the new definition of Elem
       does not match its original definition in the constrained signature:
       Modules do not match:
         sig type t = BootstrappedElem.t end
       is not included in
         ORDERED
       The field `compare' is required but not provided

第52行是

行

and PrimH : (HEAP with module Elem = BootstrappedElem) =

我认为BootstrappedElem确实实现了ORDERED，因为它同时包含t和compare，但我无法理解为什么编译器无法找到compare功能

将BootstrappedElem的签名更改为

module rec BootstrappedElem : ORDERED

将进行编译，但这会隐藏E中的类型构造函数T和BootstrappedElem，从而无法实现后面的部分。

可以在https://raw.github.com/gist/4044281/0ce0336c40b277e59cece43dbadb9b94ce6efdaf/ordered.ml

下载整个非编译代码

Answer 1

我相信这可能是类型检查器中的错误。我已将代码缩减为以下示例：

module type ORDERED =
sig
  type t
  val compare : t -> t -> int
end


module type CARRY = sig
  module M : ORDERED
end

(* works *)
module HigherOrderFunctor
  (Make : functor (X : ORDERED) -> (CARRY with module M = X))
= struct
  module rec Base
    : (ORDERED with type t = string)
    = String
  and Other
    : (CARRY with module M = Base)
    = Make(Base)
end

(* does not work *)
module HigherOrderFunctor
  (Make : functor (X : ORDERED) -> (CARRY with module M = X))
= struct
  module rec Base
    : sig
      (* 'compare' seems dropped from this signature *)
      type t = string
      val compare : t -> t -> int
    end
    = String
  and Other
    : (CARRY with module M = (Base : sig type t = string val compare : t -> t -> int end))
    = Make(Base)
end

我不明白为什么第一个代码有效，第二个代码（似乎等效）却没有。我建议你稍等一下，看看专家是否有解释（安德烈亚斯？），然后考虑发送a bug report。

在这种情况下，解决方案是首先绑定看似错误处理的签名：

(* works again *)
module HigherOrderFunctor
  (Make : functor (X : ORDERED) -> (CARRY with module M = X))
= struct
  (* bind the problematic signature first *)
  module type S = sig
    type t = string
    val compare : t -> t -> int
  end

  module rec Base : S = String
  and Other : (CARRY with module M = Base) = Make(Base)
end

但是，这在您的设置中是不可能的，因为BootstrappedElem的签名与BootstrappedHeap是相互递归的。

解决方法是避免使用看似精致的with module ...构造，并将其替换为简单类型等式with type Elem.t = ...：

module BootstrappedHeap
  (MakeH : functor (Element : ORDERED) -> HEAP with module Elem = Element)
  (Element : ORDERED) : (HEAP with module Elem = Element) =
struct
  module Elem = Element

  module rec BootstrappedElem :
  sig
    type t =
      | E
      | H of Elem.t * PrimH.heap
    val compare : t -> t -> int
  end =
  struct
    type t =
      | E
      | H of Elem.t * PrimH.heap
    let compare t1 t2 = match t1, t2 with
      | H (x, _), H (y, _) -> Elem.compare x y
      | _ -> failwith "unreachable"
  end
  and PrimH : (HEAP with type Elem.t = BootstrappedElem.t) =
    MakeH(BootstrappedElem)

  type heap

  let empty = failwith "not implemented"
  let insert = failwith "not implemented"
  let find_min = failwith "not implemented"
  let delete_min = failwith "not implemented"
end

您还可以通过在递归{{1}中定义<{1}} 里面的BootstrappedElem 来避免相互递归并在一个递归结中定义BootstrappedHeap和BootstrappedElem }。

BootstrappedHeap

此样式自然与您决定在module BootstrappedHeap (MakeH : functor (Element : ORDERED) -> HEAP with module Elem = Element) (Element : ORDERED) : (HEAP with module Elem = Element) = struct module rec BootstrappedHeap : sig module Elem : sig type t = E | H of Element.t * BootstrappedHeap.heap val compare : t -> t -> int end include (HEAP with module Elem := Elem) end = struct module Elem = struct type t = E | H of Element.t * BootstrappedHeap.heap let compare t1 t2 = match t1, t2 with | H (x, _), H (y, _) -> Element.compare x y | _ -> failwith "unreachable" end include (MakeH(Elem) : HEAP with module Elem := Elem) end module Elem = Element type heap let empty = failwith "not implemented" let insert = failwith "not implemented" let find_min = failwith "not implemented" let delete_min = failwith "not implemented" end签名中嵌入Elem并使用HEAP进行细化相对应。另一种解决方案是将with module ...定义为返回签名的仿函数，用作HEAP，我想可以选择一种不同的递归样式。并不是说这会更好：我认为“抽象模块”风格更方便。

在OCaml中实现Okasaki的bootstrapped堆，为什么不编译？

1 个答案: